[vardof]

Have a plugin that used the code below without issue to created a progress bar:

PHP Code:

SetEntPropFloat(client, Prop_Send, "m_flProgressBarStartTime", GetGameTime());
SetEntProp(client, Prop_Send, "m_iProgressBarDuration", takeTime); 


At some point it stopped working, has there ever been an alternative way to create the same bar or a plugin that I can look at that creates something similar?

[CrazyHackGUT]

komashchenko already pointed this "feature" on another forum for RU users.
Now, for creating progress bar, you need use SDKCall() and function CCSPlayer::SetProgressBarTime(). Example you can found here.

[quasemago]

As the CrazyHackGUT said.

Gamedata:

PHP Code:

"Games"
{
    "csgo"
    {
        "Signatures"
        {
            "CCSPlayer::SetProgressBarTime"
            {
                "library"    "server"
                "windows"    "\x55\x8B\xEC\x51\x53\x8B\xD9\x56\x57\x8B\x7D\x08\x39\xBB\xD0\x27\x00\x00"
                "linux"        "\x55\x89\xE5\x83\xEC\x48\x89\x5D\xF4\x8B\x5D\x08\x89\x75\xF8\x8B\x75\x0C\x89\x7D\xFC\x39\xB3\xE8\x27\x00\x00"
            }
        }
    }
} 


Example Code:

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

Handle g_hSetProgressBarTime = null;

public void OnPluginStart()
{
    Handle hGameConf = LoadGameConfigFile("progressbar.games");

    if (hGameConf == null)
    {
        SetFailState("Game config was not loaded right.");
        return;
    }

    // Starts the preparation of an SDK call
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(hGameConf, SDKConf_Signature, "CCSPlayer::SetProgressBarTime");
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);

    if (!(g_hSetProgressBarTime = EndPrepSDKCall()))
    {
        SetFailState("Failed to find \"CCSPlayer::SetProgressBarTime\".");
        return;
    }

    // Clear memory.
    delete hGameConf;

    // Test CMD.
    RegConsoleCmd("sm_testbar", Command_TestBar);
}

public Action Command_TestBar(int client, int args)
{
    if (args < 1)
    {
        ReplyToCommand(client, "[SM] Usage: sm_testbar <time>");
        return Plugin_Handled;
    }
    
    char arg1[16];
    GetCmdArg(1, arg1, sizeof(arg1));

    int time = StringToInt(arg1);
    if (time < 0) {
        time = 0;
    }

    SDKCall(g_hSetProgressBarTime, client, time);

    ReplyToCommand(client, "[SM] Bar changed to \x04%i", time);
    return Plugin_Handled;
} 


Set the time to 0 after the count is finished for close progress bar.

[SHUFEN]

Seems working fine.
Btw can we add custom text on progress bar hud?
Or is it hard-coded within client side?

[CrazyHackGUT]

Looks like hardcoded. I can't say with 100% guarantee. I work only with TF2, not CSGO. But read all threads.

[ttasdasda]

Could someone please update the sig?

[8guawong]

saw it in discord
this is for linux
try

\x55\x89\xE5\x83\xEC\x48\x89\x5D\xF4\x8B\x5D\x08\x89\x75\xF8\x8B\x75\x0C\x89\x7D\xFC\x39\xB3\x00\x28\x00\x00