[AlexALX]

Released v0.2... Test this...

Arkshine - very thanks you.

[Arkshine]

A major problem with your plugin is it doesn't care about the others things. The purpose is to provide a fix, it means your plugin must have all the functionalities of entities. The code should be the same as the HLSDK with what you add.

[AlexALX]

Originally Posted by Arkshine A major problem with your plugin is it doesn't care about the others things. The purpose is to provide a fix, it means your plugin must have all the functionalities of entities. The code should be the same as the HLSDK with what you add.

void CGameTeamMaster::Use( CBaseEntity *pActivator, CBaseEntity *pCaller, USE_TYPE useType, float value )
{
    if ( !CanFireForActivator( pActivator ) )
        return;

    if ( useType == USE_SET )
    {
        if ( value < 0 )
        {
            m_teamIndex = -1;
        }
        else
        {
            m_teamIndex = g_pGameRules->GetTeamIndex( pActivator->TeamID() );
        }
        return;
    }

    if ( TeamMatch( pActivator ) )
    {
        SUB_UseTargets( pActivator, triggerType, value );
        if ( RemoveOnFire() )
            UTIL_Remove( this );
    }
}

How this? What is:

if ( !CanFireForActivator( pActivator ) )
        return;

And this

if ( TeamMatch( pActivator ) )
    {
        SUB_UseTargets( pActivator, triggerType, value );
        if ( RemoveOnFire() )
            UTIL_Remove( this );
    }

This is flag "remove on fire" but did not understand the previous condition (if ( TeamMatch( pActivator)))

if ( RemoveOnFire() )
            UTIL_Remove( this );

And what about game_team_set...

[Arkshine]

Something like that :

PHP Code:

    #include <amxmodx>
    #include <hamsandwich>
    #include <fakemeta>
    #include <cstrike>

    enum USE_TYPE { USE_OFF = 0, USE_ON = 1, USE_SET = 2, USE_TOGGLE = 3 };

    const m_iszMaster = 34;
    const m_teamIndex = 35;
    const triggerType = 36;
    
    #define RemoveOnFire(%0)     ( pev( %0, pev_spawnflags ) & SF_TEAMMASTER_FIREONCE )
    #define ShouldClearTeam(%0)  ( pev( %0, pev_spawnflags ) & SF_TEAMSET_CLEARTEAM   )
    #define AnyTeam(%0)          ( pev( %0, pev_spawnflags ) & SF_TEAMMASTER_ANYTEAM  )
    
    public plugin_init()
    {
        register_plugin( "", "", "" );

        RegisterHam( Ham_Use, "game_team_master", "CGameTeamMaster_Use" );
        RegisterHam( Ham_Use, "game_team_set"   , "CGameTeamSet_Use"    );
    }

    public CGameTeamMaster_Use( const gameTeamMaster, const activator, const caller, const USE_TYPE:useType, const Float:value )
    {
        if ( !CanFireForActivator( gameTeamMaster, activator ) )
        {
            return HAM_IGNORED;
        }

        if ( CGameTeamMaster_TeamMatch( gameTeamMaster, activator ) )
        {
            SUB_UseTargets( gameTeamMaster, activator, USE_TYPE:get_pdata_int( triggerType, 4 ), value );
            
            if ( RemoveOnFire( gameTeamMaster ) )
            {
                UTIL_Remove( gameTeamMaster );
            }
        }
        
        return HAM_SUPERCEDE;
    }

    public CGameTeamSet_Use( const gameTeamSet, const activator, const caller, const USE_TYPE:useType, const Float:value )
    {
        if ( !CanFireForActivator( gameTeamSet, activator ) )
        {
            return HAM_IGNORED;
        }
        
        new team = pev( gameTeamSet, pev_team );
        
        new target[ 32 ];
        pev( gameTeamSet, pev_target, target, charsmax( target ) );
            
        new master = engfunc( EngFunc_FindEntityByString, FM_NULLENT, "targetname", target );
        new value = team;
        
        if ( team < 0 || ShouldClearTeam( gameTeamSet ) )
        {
            value = -1;
        }
        else if ( !team )
        {
            value = _:cs_get_user_team( activator );
        }
        
        set_pdata_int( master, m_teamIndex, value );
        
        if ( RemoveOnFire( gameTeamSet ) )
        {
            UTIL_Remove( gameTeamSet );
        }
        
        return HAM_SUPERCEDE;
    }

    bool:CGameTeamMaster_TeamMatch( const entity, const activator )
    {
        new teamIndex = get_pdata_int( entity, m_teamIndex, 4 );
        
        if ( teamIndex < 0 || AnyTeam( entity ) )
        {
            return true;
        }

        if ( !activator )
        {
            return false;
        }

        return cs_get_user_team( activator ) == CsTeams:teamIndex;
    }
    
    bool:CanFireForActivator( const entity, const activator )
    {
        new master = get_pdata_int( entity, m_iszMaster, 4 );

        if ( master )
        {
            return UTIL_IsMasterTriggered( master, activator )
        }

        return true;
    }
    
    bool:UTIL_IsMasterTriggered( const master, const activator )
    {
        if ( master )
        {
            new stringMaster[ 32 ];
            engfunc( EngFunc_SzFromIndex, stringMaster, charsmax( stringMaster ) );

            new target = engfunc( EngFunc_FindEntityByString, FM_NULLENT, "targetname", stringMaster );

            if ( target && ( ExecuteHam( Ham_ObjectCaps, target ) & FCAP_MASTER ) )
            {
                return CGameTeamMaster_TeamMatch( target, activator );
            }
        }

        return true;
    }
    
    SUB_UseTargets( const entity, const activator, USE_TYPE:useType, Float:value )
    {
        new target[ 32 ];
        pev( entity, pev_target, target, charsmax( target ) );
    
        if ( target[ 0 ] )
        {
            FireTargets( target, activator, entity, useType, value );
        }
    }
    
    FireTargets( const targetName[], const activator, const caller, USE_TYPE:useType, Float:value )
    {
        if ( !targetName[ 0 ] )
        {
            return;
        }

        new target = FM_NULLENT;
        
        while ( ( target = engfunc( EngFunc_FindEntityByString, target, "targetname", targetName ) ) )
        {
            if ( target && ~pev( target, pev_flags ) & FL_KILLME )
            {
                ExecuteHam( Ham_Use, target, activator, caller, useType, value );
            }
        }
    }
    
    UTIL_Remove( const entity )
    {
        if ( entity )
        {   
            set_pev( entity, pev_flags, pev( entity, pev_flags ) | FL_KILLME );
            set_pev( entity, pev_targetname, 0 );
        }
    } 


Not much tested, but it should work like your "how yo use". This version can keep the original behavior, master and spawnflags supported, etc.. So, the complete version. Also, since we replace the original Use() functions, we must supercede all the times.

With orpheu, we could call directly the functions, maybe I will do it another day.

[AlexALX]

Arkshine - very thanks. I tested it tomorrow and try to do with his idea about game_team_set. In orpheu you need intercept function

int CGameRules::GetTeamIndex() { return -1; }

This in cs 1.6... So you need to replace it for normal) (info from Developers)

[Arkshine]

I know it returns -1, why are you talking about that, we don't need this function anyway.

[AlexALX]

Arkshine - i now tested you code and it do not work (always not activate). something wrong ... right now, try to understand.

[Arkshine]

When i've said "Not much tested" ; I have still tested enough to post. Otherwise I would not have post a not-working plugin. So far I remember I've tested on both team, all etc.. with a game_player_equip entity and it was working perfectly for all cases.

[AlexALX]

Originally Posted by Arkshine When i've said "Not much tested" ; I have still tested enough to post. Otherwise I would not have post a not-working plugin. So far I remember I've tested on both team, all etc.. with a game_player_equip entity and it was working perfectly for all cases.

Are you sure? And I say that your code wrong. And the mistake here:

SUB_UseTargets( gameTeamMaster, activator, USE_TYPE:get_pdata_int( triggerType, 4 ), value );

Must be:

SUB_UseTargets( gameTeamMaster, activator, USE_TYPE:get_pdata_int( gameTeamMaster, triggerType, 4 ), value );

And so - thank you very much. Still, you are mistaken in this...

And

    if ( !CanFireForActivator( gameTeamSet, activator ) )
    {
        return HAM_IGNORED;
    }

May be must be:

    if ( !CanFireForActivator( gameTeamSet, activator ) )
    {
        return HAM_SUPERCEDE;
    }

??? Or not?..

[Arkshine]

Yes I've tested it faslty like i've said, but you're talking about about a thing there is some time ago and I don't remember well. Maybe I've tested only game_team_set but I remember well i've spent many time on it and I've posted only when it was working fine. Maybe I've done some modifications when I've cleanup the code, because since I was using a game_player_equip entity I remember I could know if it was working or not if I get or not a gun. So, probably a typo when I wanted to release.

Anyway for the first you're right, obviously.

The second, you're wrong. We have changed nothing which need to be supercede, just a check.