[Liverwiz]

I'm looking for a wallhang plugin that i can scavenge for a plugin of mine. I'm too lazy to develop it myself. I need it so you jump at a wall, hit e, and you stick to that point. Then you jump and come off and fall to the ground.

Has anyone already made this? or would be willing to make it for me? I'd be much appreciative.

[MokeN]

I think this is already made in mTc Jailbreak in a game called Nightcrawler.

Xalus made it.

[ConnorMcLeod]

Not the better code, but you can get an idea :

PHP Code:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#include "furien.inc"
#include "furien_shop.inc"

#define VERSION "0.0.2"

#define XTRA_OFS_PLAYER            5
#define m_Activity                73
#define m_IdealActivity            74
#define m_flNextAttack            83
#define m_afButtonPressed        246

#define FIRST_PLAYER_ID    1
#define MAX_PLAYERS        32

#define PLAYER_JUMP        6

#define ACT_HOP 7

//#define FBitSet(%1,%2)        (%1 & %2)

new g_iMaxPlayers
#define IsPlayer(%1)    ( FIRST_PLAYER_ID <= %1 <= g_iMaxPlayers )

#define IsHidden(%1)    IsPlayer(%1)

#define KNIFE_DRAW            3

new g_bHasWallHang
#define SetUserWallHang(%1)        g_bHasWallHang |=    1<<(%1&31)
#define RemoveUserWallHang(%1)    g_bHasWallHang &=    ~(1<<(%1&31))
#define HasUserWallHang(%1)        g_bHasWallHang &    1<<(%1&31)

new g_bHanged
#define SetUserHanged(%1)    g_bHanged |=    1<<(%1&31)
#define RemoveUserHanged(%1)    g_bHanged &=    ~(1<<(%1&31))
#define IsUserHanged(%1)        g_bHanged &    1<<(%1&31)

new Float:g_fVecMins[MAX_PLAYERS+1][3]
new Float:g_fVecMaxs[MAX_PLAYERS+1][3]
new Float:g_fVecOrigin[MAX_PLAYERS+1][3]

new g_iCost[2]

new bool:g_bRoundEnd

public plugin_init()
{
    register_plugin("Furien WallHang", VERSION, "ConnorMcLeod")

    new szConfigFile[128]
    get_localinfo("amxx_configsdir", szConfigFile, charsmax(szConfigFile))
    format(szConfigFile, charsmax(szConfigFile), "%s/furien/items/wallhang.ini", szConfigFile);

    new fp = fopen(szConfigFile, "rt")
    if( !fp )
    {
        return
    }

    new szFurienName[32], szAntiName[32]

    new szDatas[64], szKey[16], szValue[32]
    while( !feof(fp) )
    {
        fgets(fp, szDatas, charsmax(szDatas))
        trim(szDatas)
        if(!szDatas[0] || szDatas[0] == ';' || szDatas[0] == '#' || (szDatas[0] == '/' && szDatas[1] == '/'))
        {
            continue
        }

        parse(szDatas, szKey, charsmax(szKey), szValue, charsmax(szValue))

        switch( szKey[0] )
        {
            case 'A':
            {
                switch( szKey[7] )
                {
                    case 'M':
                    {
                        if( equal(szKey, "ANTI_NAME" ) )
                        {
                            copy(szAntiName, charsmax(szAntiName), szValue)
                        }
                    }
                    case 'S':
                    {
                        if( equal(szKey, "ANTI_COST" ) )
                        {
                            g_iCost[AntiFurien] = str_to_num(szValue)
                        }
                    }
                }
            }
            case 'F':
            {
                switch( szKey[9] )
                {
                    case 'M':
                    {
                        if( equal(szKey, "FURIEN_NAME" ) )
                        {
                            copy(szFurienName, charsmax(szAntiName), szValue)
                        }
                    }
                    case 'S':
                    {
                        if( equal(szKey, "FURIEN_COST" ) )
                        {
                            g_iCost[Furien] = str_to_num(szValue)
                        }
                    }
                }
            }
        }
    }
    fclose( fp )

    if( g_iCost[Furien] || g_iCost[AntiFurien] )
    {
        furien_register_item(szFurienName, g_iCost[Furien], szAntiName, g_iCost[AntiFurien], "furien_buy_wallhang")

        RegisterHam(Ham_Player_Jump, "player", "Player_Jump")

        RegisterHam(Ham_Touch, "func_wall", "World_Touch")
        RegisterHam(Ham_Touch, "func_breakable", "World_Touch")
        RegisterHam(Ham_Touch, "worldspawn", "World_Touch")

        g_iMaxPlayers = get_maxplayers()    

        register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
        register_logevent("Logevent_Round_End", 2, "1=Round_End")
    }
}

public Event_HLTV_New_Round()
{
    g_bRoundEnd = false
}

public Logevent_Round_End()
{
    g_bRoundEnd = true
    g_bHanged = 0
}

public client_putinserver( id )
{
    RemoveUserWallHang( id )
    RemoveUserHanged( id )
}

public furien_team_change( /*iFurien */ )
{
    if( !g_iCost[Furien] || !g_iCost[AntiFurien] )
    {
        g_bHasWallHang = 0
        g_bHanged = 0
    }
}

public furien_round_restart()
{
    g_bHasWallHang = 0
    g_bHanged = 0
}

public furien_buy_wallhang( id )
{
    new iTeam = furien_get_user_team(id)
    if( iTeam == -1 )
    {
        return ShopCloseMenu
    }

    new iItemCost = g_iCost[iTeam]
    if( iItemCost <= 0 )
    {
        return ShopTeamNotAvail
    }

    if( ~HasUserWallHang(id) )
    {
        if( furien_try_buy(id, iItemCost) )
        {
            SetUserWallHang( id )
            return ShopBought
        }
        else
        {
            return ShopNotEnoughMoney
        }
    }
    return ShopAlreadyHaveOne
}

public Player_Jump(id)
{
    if(    g_bRoundEnd
    ||    ~HasUserWallHang(id)
    ||    ~IsUserHanged(id)
    ||    !is_user_alive(id)    )
    {
        return HAM_IGNORED
    }

    if( (pev(id, pev_flags) & FL_WATERJUMP) || pev(id, pev_waterlevel) >= 2 )
    {
        return HAM_IGNORED
    }

    static afButtonPressed ; afButtonPressed = get_pdata_int(id, m_afButtonPressed)

    if( ~afButtonPressed & IN_JUMP )
    {
        return HAM_IGNORED
    }

    RemoveUserHanged(id)

    new Float:fVecVelocity[3]

    velocity_by_aim(id, 600, fVecVelocity)
    set_pev(id, pev_velocity, fVecVelocity)

    set_pdata_int(id, m_Activity, ACT_HOP)
    set_pdata_int(id, m_IdealActivity, ACT_HOP)
    set_pev(id, pev_gaitsequence, PLAYER_JUMP)
    set_pev(id, pev_frame, 0.0)
    set_pdata_int(id, m_afButtonPressed, afButtonPressed & ~IN_JUMP)

    return HAM_SUPERCEDE
}


public client_PostThink(id)
{
    if( HasUserWallHang(id) && IsUserHanged(id) )
    {
        engfunc(EngFunc_SetSize, id, g_fVecMins[ id ], g_fVecMaxs[ id ])
        engfunc(EngFunc_SetOrigin, id, g_fVecOrigin[ id ])
        set_pev(id, pev_velocity, 0)
        set_pdata_float(id, m_flNextAttack, 1.0, XTRA_OFS_PLAYER)
    }
}

public World_Touch(iEnt, id)
{
    if(    !g_bRoundEnd
    &&    IsPlayer(id)
    &&    HasUserWallHang(id)
    &&    ~IsUserHanged(id)
    &&    is_user_alive(id)
    &&    pev(id, pev_button) & IN_USE
    &&    ~pev(id, pev_flags) & FL_ONGROUND    )
    {
        SetUserHanged(id)
        pev(id, pev_mins, g_fVecMins[id])
        pev(id, pev_maxs, g_fVecMaxs[id])
        pev(id, pev_origin, g_fVecOrigin[id])
    }
} 


[Liverwiz]

Much thanks, connor!

i lol @ "IsUserHanged"
Probably a translation error. But that just tickles me. Mostly because if that were true is_user_alive would probably return false.

[ConnorMcLeod]

Not a translation error, only the suckage of my english.
IsUserHanging would be better ?

[Liverwiz]

Agreed. IsUserHanging would be "better." But i'm keeping it. Cause it makes me giggle.

Not sure you understand the humor, though. Hanged = passed tense of "Hang till death" by a noose. (yes, hung is typical...but blah blah blah blah blah i'm not here to teach english)

[SplinteX]

should we bind e for a key or just +use ?

[Liverwiz]

Originally Posted by SplinteX should we bind e for a key or just +use ?

IN_USE is the "action" button. defaulted to 'e'

EDIT: just did some extensive testing and it works wonderfully, connor! Thanks very much.

[Liverwiz]

Connor, there is an issue with this. Not sure if its an avoidable problem, but it makes it rather unfair.

When a user is stuck to the wall its very difficult for other players to register shots on them. I don't know of a way to fix it. Any ideas?

[quilhos]

"register shots on them" sorry but I dont understand what you need