[zipcore]

Many ppl. asked me for this so I decided to make this public.
There are already plugins on this forum which make use of this entity,
but there was no stock which supports all features,
my stock doesn't support ALL features, but all you'll need.

More details can be found here: https://developer.valvesoftware.com/...nstructor_hint

Supported Games: L4D2 and CS:GO

PHP Code:

/* Available icons
    "icon_bulb"
    "icon_caution"
    "icon_alert"
    "icon_alert_red"
    "icon_tip"
    "icon_skull"
    "icon_no"
    "icon_run"
    "icon_interact"
    "icon_button"
    "icon_door"
    "icon_arrow_plain"
    "icon_arrow_plain_white_dn"
    "icon_arrow_plain_white_up"
    "icon_arrow_up"
    "icon_arrow_right"
    "icon_fire"
    "icon_present"
    "use_binding"
*/

stock void DisplayInstructorHint(int iTargetEntity, float fTime, float fHeight, float fRange, bool bFollow, bool bShowOffScreen, char[] sIconOnScreen, char[] sIconOffScreen, char[] sCmd, bool bShowTextAlways, int iColor[3], char sText[100])
{
    int iEntity = CreateEntityByName("env_instructor_hint");
    
    if(iEntity <= 0)
        return;
        
    char sBuffer[32];
    FormatEx(sBuffer, sizeof(sBuffer), "%d", iTargetEntity);
    
    // Target
    DispatchKeyValue(iTargetEntity, "targetname", sBuffer);
    DispatchKeyValue(iEntity, "hint_target", sBuffer);
    
    // Static
    FormatEx(sBuffer, sizeof(sBuffer), "%d", !bFollow);
    DispatchKeyValue(iEntity, "hint_static", sBuffer);
    
    // Timeout
    FormatEx(sBuffer, sizeof(sBuffer), "%d", RoundToFloor(fTime));
    DispatchKeyValue(iEntity, "hint_timeout", sBuffer);
    if(fTime > 0.0)
        RemoveEntity(iEntity, fTime);
    
    // Height
    FormatEx(sBuffer, sizeof(sBuffer), "%d", RoundToFloor(fHeight));
    DispatchKeyValue(iEntity, "hint_icon_offset", sBuffer);
    
    // Range
    FormatEx(sBuffer, sizeof(sBuffer), "%d", RoundToFloor(fRange));
    DispatchKeyValue(iEntity, "hint_range", sBuffer);
    
    // Show off screen
    FormatEx(sBuffer, sizeof(sBuffer), "%d", !bShowOffScreen);
    DispatchKeyValue(iEntity, "hint_nooffscreen", sBuffer);
    
    // Icons
    DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOnScreen);
    DispatchKeyValue(iEntity, "hint_icon_offscreen", sIconOffScreen);
    
    // Command binding
    DispatchKeyValue(iEntity, "hint_binding", sCmd);
    
    // Show text behind walls
    FormatEx(sBuffer, sizeof(sBuffer), "%d", bShowTextAlways);
    DispatchKeyValue(iEntity, "hint_forcecaption", sBuffer);
    
    // Text color
    FormatEx(sBuffer, sizeof(sBuffer), "%d %d %d", iColor[0], iColor[1], iColor[2]);
    DispatchKeyValue(iEntity, "hint_color", sBuffer);
    
    //Text
    ReplaceString(sText, sizeof(sText), "\n", " ");
    DispatchKeyValue(iEntity, "hint_caption", sText);
    
    DispatchSpawn(iEntity);
    AcceptEntityInput(iEntity, "ShowHint");
}

stock void RemoveEntity(entity, float time = 0.0)
{
    if (time == 0.0)
    {
        if (IsValidEntity(entity))
        {
            char edictname[32];
            GetEdictClassname(entity, edictname, 32);

            if (!StrEqual(edictname, "player"))
                AcceptEntityInput(entity, "kill");
        }
    }
    else if(time > 0.0)
        CreateTimer(time, RemoveEntityTimer, EntIndexToEntRef(entity), TIMER_FLAG_NO_MAPCHANGE);
}

public Action RemoveEntityTimer(Handle Timer, any entityRef)
{
    int entity = EntRefToEntIndex(entityRef);
    if (entity != INVALID_ENT_REFERENCE)
        RemoveEntity(entity); // RemoveEntity(...) is capable of handling references
    
    return (Plugin_Stop);
} 


[Franc1sco]

Looks amazing http://steamcommunity.com/sharedfile.../?id=605710852

This can be extremly useful!

But I am testing it but I cant make for work with the gameinstructor disabled in my client "gameinstructor_enable 1". I need to enable it in my client, if not, dont work for me. Someone can test it with "gameinstructor_enable 0" for check if it works?

Also exist this cvar for servers "sv_gameinstructor_disable" but I think that only force to have gameinstructor disabled, no force to have it enabled.


I am waiting for feedback about this. Because no idea if is only me, but seems that it dont work well


btw, this works too in CS:GO https://forums.alliedmods.net/showth...16#post1533616 (but with "gameinstructor_enable 1")

[8guawong]

hopefully we can find a way to enable it even when user have instruction turned off

[Powerlord]

Probably a good idea to mention that it only works in L4D2 and CS:GO.

[th7nder]

You have an error in your stock:

DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOnScreen); 
DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOffScreen);

change to:

DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOnScreen); 
DispatchKeyValue(iEntity, "hint_icon_offscreen", sIconOffScreen);

[zipcore]

Originally Posted by 8guawong hopefully we can find a way to enable it even when user have instruction turned off

Most ppl have the instructor enabled, cuz there is no need to disable it since it's disabled server-side by default, furthermore at least you can announce the setting to players when they have it disabled.

Originally Posted by Powerlord Probably a good idea to mention that it only works in L4D2 and CS:GO.

...done

Originally Posted by th7nder You have an error in your stock: DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOnScreen); DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOffScreen); change to: DispatchKeyValue(iEntity, "hint_icon_onscreen", sIconOnScreen); DispatchKeyValue(iEntity, "hint_icon_offscreen", sIconOffScreen);

thanks, I've updated the first posting

[8guawong]

Originally Posted by zipcore Most ppl have the instructor enabled, cuz there is no need to disable it since it's disabled server-side by default, furthermore at least you can announce the setting to players when they have it disabled. ...done thanks, I've updated the first posting

i have it disabled...
most people who play competitive have it disabled as well probably

[KissLick]

Originally Posted by 8guawong i have it disabled... most people who play competitive have it disabled as well probably

+1

[zipcore]

Originally Posted by 8guawong i have it disabled... most people who play competitive have it disabled as well probably

Which is not needed, since it's disabled by default serverside ;) even on a MM server

[th7nder]

I think that best solution is what zipcore told before, query client convar if he has it disabled, change display type to PrintHintText, or tell him by chat to enable hints (;