[3D-GRAF]

Hello, i'm new at sourcemod scripting. I can't compile my plugin because of the erros.
Here is the source:

PHP Code:

#include <sourcemod>

new Handle:hDatabase = INVALID_HANDLE;

public Plugin:myinfo = 
{
    name = "CGC SteamID Check",
    author = "F1NAL",
    description = "CGC SteamID Check",
    url = ""
};

public OnPluginStart()
{
    HookEvent("player_connect", Event_Player_Connect);
    hDatabase = MySQL_Connect();
}

public Event_Player_Connect(Handle:event, const String:name[], bool:dontBroadcast) {
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    decl String:steam_id[32];
    GetClientAuthString(client, steam_id, 64);
    
    if (steam_id[0] == 0) {
        return;
    }
    
    if (hDatabase == INVALID_HANDLE) {
        return;
    }
    
    new String:query_str[1024];
    Format(query_str, sizeof(query_str), "SELECT pid FROM cgc_players WHERE steam_id LIKE '%s'", steam_id[0]);
    SQL_TQuery(hDatabase, TypoCallback, query_str);
}

Handle:MySQL_Connect() {
    new String:error[256];
    new Handle:db = INVALID_HANDLE;
    
    db = SQL_Connect("cgc", true, error, sizeof(error));
    
    return db;
}

public TypoCallback(Handle:owner, Handle:hDatabase, const String:error[], client)
{
    if(!SQL_GetRowCount(hDatabase))
    {
                KickClient(client, "Not regged");
                return;
    } 
    if(hDatabase == INVALID_HANDLE) {
            return;
    }
} 


During compiling i get errors:

cgcheck.sp<35> : error 100: function prototypes do not match
cgcheck.sp<47> : warning 219: local variable "hDatabase" shadows a variable at a preceding level

Can anyone tell me what do these errors mean or how to fix them?

[BAILOPAN]

You've declared two variables as "hDatabase" and the second is in an inner scope -- just use a different name in your TypoCallback parameter list.

And the final parameter must have the "any" tag. something like:

public TypoCallback(Handle:owner, Handle:hDatabase, const String:error[], any:client)

[3D-GRAF]

thank you, errors disappered, but plugin doesn't work though..
how can i know where plugin stops working?

[paegus]

// Enable debugging mode.
#define DEBUG 1
...
    // At various eventful locations, outputs current states and whatnot so you can see what the plugin is doing or if the plugin even reached this point.
    #if DEBUG
    PrintToServer("Things should look like %s and %d, etc", somestring, somenumber)
    #endif
...

go crazy

e: though at the moment i'd have to go with the fact that the player_connect event is too soon for steamid verification. try the OnClientAuthorized(client, const String:auth[]) forward instead of hooking player_connect etc..

e^2: also your GetClientAuthString's maxlen is 64 where as steam_id is only 32. not that that'll actually cause a problem since steam ids aren't that long...

[3D-GRAF]

Fixed these

New problem, sql query doesn't work.
Source:

PHP Code:

#include <sourcemod>
#define DEBUG 1

new Handle:hDatabase = INVALID_HANDLE;

public Plugin:myinfo = 
{
    name = "CGCSC",
    author = "F1NAL",
    description = "CGC SteamID Check",
    url = ""
};

public OnPluginStart()
{
    #if DEBUG
        PrintToServer("[CGCSC] Plugin loaded");
        #endif
}

public OnClientAuthorized(client, const String:auth[])
{
    decl String:steam_id[32];
    GetClientAuthString(client, steam_id, 32);
    
    if (steam_id[0] == 0) {
        return;
    }
    
    #if DEBUG
        PrintToServer("[CGCSC] %s Authorized", steam_id[0]);
        #endif
    
    hDatabase = MySQL_Connect(); 
    
    if (hDatabase == INVALID_HANDLE) {
        return;
    }
    
    new String:query_str[1024];
    Format(query_str, sizeof(query_str), "SELECT pid FROM cgc_players WHERE steam_id LIKE '%s'", steam_id[0]);
    SQL_TQuery(hDatabase, TypoCallback, query_str)
    
    #if DEBUG
        PrintToServer("SQL WORKS");
        #endif
}

Handle:MySQL_Connect() {
    new String:error[256]; 
    new Handle:db = INVALID_HANDLE;
    
    db = SQL_Connect("cgc", true, error, sizeof(error));
    
    return db;
} 

public TypoCallback(Handle:owner, Handle:hndl, const String:error[], any:client)
{
    if(!SQL_GetRowCount(hndl)) 
    {
                KickClient(client, "Not regged");
                return; 
    } 
    if(hndl == INVALID_HANDLE) {
        return;
    }
} 


Why can hDatabase == INVALID_HANDLE ?
Is there any sql debug info?

[MikeJS]

try:

PHP Code:

Format(query_str, sizeof(query_str), "SELECT pid FROM cgc_players WHERE steam_id='%s'", steam_id); 


[3D-GRAF]

Changed, but plugin stop after

if (hDatabase == INVALID_HANDLE) { return; }

Does this mean that plugin can't connect to db?

[MikeJS]

Try connecting to the database in OnPluginStart() and using a global handle for the database.

[3D-GRAF]

thx everybody, i've got it working

[3D-GRAF]

Last question

Is it possible not to make new handle and not to open new mysql connection in CheckSteamID()? I don't know how to use existing connection.

PHP Code:

#include <sourcemod>
#define DEBUG 1

new Handle:hDatabase = INVALID_HANDLE;

public Plugin:myinfo = 
{
    name = "CGC",
    author = "3D-GRAF",
    description = "CGC SteamID Check",
    url = "http://cgaming.ru/"
};

public OnPluginStart()
{
    hDatabase = MySQL_Connect();
    #if DEBUG
        PrintToServer("[CGC] Plugin loaded");
        #endif
}

public OnClientPostAdminCheck(client)
{
    decl String:steam_id[32];
    GetClientAuthString(client, steam_id, sizeof(steam_id));
    
    decl String:username[64];
    GetClientName(client, username, sizeof(username));
    
    if (StrEqual(steam_id[0], "BOT")) {
        return;
    }
    
    #if DEBUG
        PrintToServer("[CGC] %s - %s Authorized", username, steam_id[0]);
        #endif
    
    
    if (hDatabase == INVALID_HANDLE) {
        return;
    }
    
    PrintToChatAll("\x04[CGC]\x03 Checking [ \x04%s \x03- \x04%s \x03]", username, steam_id[0]);
    
    new String:query[255];
    Format(query, sizeof(query), "SELECT team FROM cgc_players WHERE steam_id = '%s'", steam_id[0]);
    SQL_TQuery(hDatabase, CheckSteamID, query, client);
}

Handle:MySQL_Connect() {
    new String:error[256]; 
    new Handle:db = INVALID_HANDLE;
    
    db = SQL_Connect("cgc", true, error, sizeof(error));
    
    if (db == INVALID_HANDLE) {
        #if DEBUG
            PrintToServer("[CGC] Can't connect MySQL: %s", error);
            #endif
        return db;
    } else {
        #if DEBUG
            PrintToServer("[CGC] MySQL Connected");
            #endif
        return db;
    }
}

public CheckSteamID(Handle:owner, Handle:hndl, const String:error[], any:client)
{
    if (hndl == INVALID_HANDLE)
    {
        KickClient(client, "Ошибка авторизации");
        #if DEBUG
            PrintToServer("[CGC] Query failed");
            #endif
        
        return true;
    }
    
    decl String:steam_id[32];
    GetClientAuthString(client, steam_id, sizeof(steam_id));
    
    decl String:username[64];
    GetClientName(client, username, sizeof(username));
    
    new String:teamid[255];
    new String:team[255];
    
    while (SQL_FetchRow(hndl))
    {
        SQL_FetchString(hndl, 0, teamid, sizeof(teamid));
        teamid[0] = teamid[0] - 48;
        
        if (teamid[0] != 0) {
            
            
            new String:queryt[255];
            Format(queryt, sizeof(queryt), "SELECT name FROM cgc_teams WHERE tid = %i", teamid[0]);
            
            new Handle:hQuery = INVALID_HANDLE;
            hQuery = MySQL_Connect();
            
            if ((hQuery = SQL_Query(hQuery, queryt)) == INVALID_HANDLE) {
                return true;
            }
            
            while (SQL_FetchRow(hQuery))
            {
                SQL_FetchString(hQuery, 0, team, sizeof(team));
            }
            CloseHandle(hQuery);
        } else {
            team = "Not in team";
        }
    }
    
    if (!SQL_GetRowCount(hndl)) {
        KickClient(client, "Вы не заявлены на участие");
        
        PrintToChatAll("\x04[CGC]\x03 Kicked [ \x04%s \x03- \x04%s \x03]", username, steam_id[0]);
        
        #if DEBUG
            PrintToServer("[CGC] %i not regged - kicked", client);
            #endif
    } else if (SQL_GetRowCount(hndl)) {
        PrintToChatAll("\x04[CGC]\x03 Authenticated: \x04%s \x03Team: \x04%s", username, team[0]);
        
        #if DEBUG
            PrintToServer("[CGC] %s - %s Authenticated", steam_id[0], team[0]);
            #endif
    }
    
    return true;
}