[Peace-Maker]

There were some changes to the weapon reloading in the past css updates, which broke the GiveAmmo method as used by now. The weapon_reload event isn't fired for automatic reloads on empty clips either.

That's why players don't get their ammo refilled after blasting some enemies, which gets them out of ammo pretty fast.

Here's a quick and dirty fix to the dm_basics.sp replacing that GiveAmmo call and giving ammo after automatic reloads. This just sets the ammo to 200 instead of obeying the max clip size as before.

Primary changes:
Replaced

PHP Code:

DM_GiveClientAmmo(client, ammoType, 30, false); 


with

PHP Code:

SetEntData(client, (g_AmmoOffs + (ammoType*4)), 200, 4, true); 


(and got the offset in OnPluginStart)

and required sdktools now

PHP Code:

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{
    if(!g_AmmoHooks)
        return Plugin_Continue;
    
    new entity = GetEntDataEnt2(client, g_ActiveWepOffs);
    if (entity < 1)
    {
        g_bHasNoAmmoInClip1[client] = false;
        return Plugin_Continue;
    }
    
    // He's out of ammo -> reloading
    new iClip1 = GetEntProp(entity, Prop_Send, "m_iClip1");
    if(iClip1 == 0)
    {
        g_bHasNoAmmoInClip1[client] = true;
    }
    // He got ammo in clip1 again but hadn't before -> reloaded.
    else if(g_bHasNoAmmoInClip1[client])
    {
        g_bHasNoAmmoInClip1[client] = false;
        
        new ammoType = GetEntProp(entity, Prop_Send, "m_iPrimaryAmmoType");
        
        if(ammoType < 0)
        {
            return Plugin_Continue;
        }
        
        // Give some ammo.
        SetEntData(client, (g_AmmoOffs + (ammoType*4)), 200, 4, true);
    }
    
    return Plugin_Continue;
} 


[.ice]

Thank you ! Good shit.

[GoD-Tony]

Nice fix. You should submit it as a patch so it makes it into official builds.

[Peace-Maker]

Ok, there's no problem with GiveAmmo - my fault, it's just not fired at all for automatic reloads.

This is a better patch obeying the maxammo of that ammotype again.

PHP Code:

new bool:g_bHasNoAmmoInClip1[MAXPLAYERS+1] = {false,...};

public OnClientPutInServer(client)
{
    g_DeathTimes[client] = 0.0;
    CreateTimer(10.0, Timer_Welcome, GetClientUserId(client));
    
    g_bHasNoAmmoInClip1[client] = false;
}

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{
    if(!g_AmmoHooks)
        return Plugin_Continue;
    
    new entity = GetEntDataEnt2(client, g_ActiveWepOffs);
    if (entity < 1)
    {
        g_bHasNoAmmoInClip1[client] = false;
        return Plugin_Continue;
    }
    
    // He's out of ammo -> reloading
    new iClip1 = GetEntProp(entity, Prop_Send, "m_iClip1");
    if(iClip1 == 0)
    {
        g_bHasNoAmmoInClip1[client] = true;
    }
    // He got ammo in clip1 again but hadn't before -> reloaded.
    else if(g_bHasNoAmmoInClip1[client])
    {
        g_bHasNoAmmoInClip1[client] = false;
        
        new ammoType = GetEntProp(entity, Prop_Send, "m_iPrimaryAmmoType");
        
        if(ammoType < 0)
        {
            return Plugin_Continue;
        }
        
        // Give some ammo.
        DM_GiveClientAmmo(client, ammoType, 30, false);
    }
    
    return Plugin_Continue;
} 


[Peace-Maker]

Originally Posted by GoD-Tony Nice fix. You should submit it as a patch so it makes it into official builds.

I did.

[-=Leb=-]

The dead bodies are not disappearing

[-=Leb=-]

peace maker, would you plz find a solution for ragdoll?