[zerbbi]

Hello, i need help. I want to make plugin to give flashbang randomly to only one player with ADMIN_LEVEL_H flag every round. Now, i have this condition:
if random(3) = 1 then give(flashbang)
but it is unfair, sometimes every VIP have flash, sometimes nobody have flash. Can you help? Thanks

[anakin_cstrike]

sometimes = random, you never know. If you want to make sure he gets a weapon then it wouldn't be random, right?

[Devil259]

You can do something like that :

new iRandom = random_num( 1 , 3 )

switch( iRandom )
{
    case 1:give_item( id , "weapon_flashbang" );
    case 2://...
    case 3://...
}

[RoaR]

PHP Code:

#include <amxmodx>
#include <fun>


new iRandom = random_num(1,3);

if(get_user_flags(id) && ADMIN_LEVEL_H) {
    switch (iRandom): {
        case 1: { give_item(id,"weapon_flashbang") }
        case 2: { // smth here 
        }
            case 3: { // smth here 
            }
        }
    }
} 


I may declared more } then i should.

This uses fun and amxmodx module.

[Exolent[jNr]]

Would be better to do this:

#include <amxmodx>
#include <fun>
#include <hamsandwich>

new gPlayerToGetFlashBang;

public plugin_init() {
    register_event("HLTV", "EventNewRound", "a", "1=0", "2=0");
    
    RegisterHam(Ham_Spawn, "player", "FwdPlayerSpawnPost", 1);
}

public client_disconnect(id) {
    if(id == gPlayerToGetFlashBang) {
        gPlayerToGetFlashBang = 0;
    }
}

public EventNewRound() {
    new players[32], pnum;
    get_players(players, pnum, "a");
    
    for(new i = 0; i < pnum; i++) {
        if(~get_user_flags(players[i]) & ADMIN_LEVEL_H) {
            players[i--] = players[--pnum];
        }
    }
    
    gPlayerToGetFlashBang = pnum ? players[(pnum > 1) ? random(pnum) : 0] : 0;
}

public FwdPlayerSpawnPost(id) {
    if(id == gPlayerToGetFlashBang && is_user_alive(id)) {
        give_item(id, "weapon_flashbang");
    }
}

[zerbbi]

Thank you very much, i'll try.

[zerbbi]

Thank you very much exolent! It's woking pefectly and giving flash is fair. Thanks again

[lucas_7_94]

Exolent sorry ,but you can explain please why you use ~ in the if statement ?

[Devil259]

if(~get_user_flags(players[i]) & ADMIN_LEVEL_H)

is the same as

if(!(get_user_flags(players[i]) & ADMIN_LEVEL_H))

[RoaR]

Originally Posted by Devil259 if(~get_user_flags(players[i]) & ADMIN_LEVEL_H) is the same as if(!(get_user_flags(players[i]) & ADMIN_LEVEL_H))

Thanks.