[NgBUCKWANGS]

Hello,

I'm using z_spawn_old to spawn specials but I can't do that while in ghost mode because that would put me into the body of the new special (not in ghost mode). How do I stop that? I'm trying to remain a ghost but use z_spawn to spawn in specials. Any help is appreciated here.

The code I am working with is located here https://forums.alliedmods.net/showthread.php?t=291562 and the main functions behind the logic is line 652 (AddInfected) and line 1202 (State_TransitionSig) if you're curious.

Thank you for your time

[cravenge]

Does the task you wanted but may change your zombie class:

PHP Code:

public void OnPluginStart()
{
    RegAdminCmd("sm_z_spawn", SpawnSI, ADMFLAG_ROOT, "Spawns a special infected");
    // Usage: !z_spawn <SI name> (i.e !z_spawn hunter)
}

public Action SpawnSI(int client, int args)
{
    if (client == 0 || !IsClientInGame(client) || GetClientTeam(client) != 3)
    {
        return Plugin_Handled;
    }
    
    char givenSI[52];
    GetCmdArgString(givenSI, sizeof(givenSI));
    
    ChangeClientTeam(client, 1); // avoid survivors team 'cause it unnecessarily spawns an infected survivor bot (invincible and invisible)
    CommandExecuter(client, "z_spawn_old", givenSI, "auto");
    ChangeClientTeam(client, 3); // go back to the infected team.
    
    return Plugin_Handled;
}

stock void CommandExecuter(int client, char[] command, char[] argument1, char[] argument2)
{
    int flags = GetCommandFlags(command);
    SetCommandFlags(command, flags & ~FCVAR_CHEAT);
    FakeClientCommand(client, "%s %s %s", command, argument1, argument2);
    SetCommandFlags(command, flags|FCVAR_CHEAT);
} 


[Timocop]

Changed cravenge's code a bit. Just disable ghost-mode before you spawn special infected and activate after spawn.

PHP Code:

public void OnPluginStart()
{
    RegAdminCmd("sm_z_spawn_ghost", SpawnSI, ADMFLAG_ROOT, "Spawns a special infected");
    // Usage: !z_spawn_ghost <SI name> (i.e !z_spawn hunter)
}

public Action SpawnSI(int client, int args)
{
    if (client < 1
        || !IsClientInGame(client) 
        || GetClientTeam(client) != 3 
        || GetEntProp(client, Prop_Send, "m_isGhost", 1) < 1)
    {
        return Plugin_Handled;
    }
    
    char givenSI[52];
    GetCmdArgString(givenSI, sizeof(givenSI));
    
    SetEntProp(client, Prop_Send, "m_isGhost", 0);
    CommandExecuter(client, "z_spawn_old", givenSI, "auto");
    SetEntProp(client, Prop_Send, "m_isGhost", 1);
    
    return Plugin_Handled;
}

stock void CommandExecuter(int client, char[] command, char[] argument1, char[] argument2)
{
    int flags = GetCommandFlags(command);
    SetCommandFlags(command, flags & ~FCVAR_CHEAT);
    FakeClientCommand(client, "%s %s %s", command, argument1, argument2);
    SetCommandFlags(command, flags|FCVAR_CHEAT);
} 


[NgBUCKWANGS]

Using the ChangeClientTeam did in fact change my special infected every time a new one spawned in but using the SetEntProp(client, Prop_Send, "m_isGhost", ...) protected it. This was one of those problems I played with every solution I could come up with and come up wrong every time. Damn, I love you guys! Thank you cravenge, thank you Timocop!

You guys rock!