[Austin]

CSGO will play a death sound for about 1 in 50 deaths.
I wrote a plugin to play these same sounds more often and it is working,
but the sounds are not played exactly the same as CSGO plays them.

If the victim is far away it still sounds like it is close and since I am the only player on the server right now I am not sure everyone hears the sound.

Can someone show me the correct function and parms to use so the victim’s sound
1) originates from the victim
2) all players hear the sound
3) the sound is location specific to each player’s position
4) the sound volume is location specific to each player’s position.

PHP Code:

public void OnPluginStart()
{
    HookEvent("player_death",        Event_PlayerDeath,        EventHookMode_Post);
    AddNormalSoundHook(SoundHook2);
}

public Action:SoundHook2(clients[64], &numClients, String:sound[PLATFORM_MAX_PATH], &client, &channel, &Float:volume, &level, &pitch, &flags)
{
    if(StrContains(sound, "death") > -1)
        PrintToServer("Sound=%s Channel=%d Volume=%f Level=%f Pitch=%f Flags=%d", sound, channel, volume, level, pitch, flags);
    return Plugin_Continue;
}

public OnMapStart()
{
    PrecacheSound("player/death1.wav", true);
}

public Action Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    int victim   = GetClientOfUserId(event.GetInt("userid"));

    new Float:attackerLocation[3];
    new Float:victimLocation[3];

    GetClientAbsOrigin(attacker, attackerLocation);
    GetClientAbsOrigin(victim,   victimLocation);

    // this compiles but doesn't generate any sound
    EmitAmbientSoundAny("player/death1.wav", victimLocation,    victim);

    // this works but doesn't seem to have location and distance information
    EmitSoundToAll("player/death1.wav", attacker);

    return Plugin_Continue;
} 


[Marttt]

You can try using SoundHook to find the correct parameters.
(Output the values to the chat)

[Austin]

Originally Posted by Marttt You can try using SoundHook to find the correct parameters. (Output the values to the chat)

Very good to know about sound hooking, thanks!

I added a sound hook to print out the exact same death sounds I am using but
1) I still don’t know what sound function to call
Or
2) what parms to use

I updated my original post with the sound hook added and here is the output.

Sound=~player/death1.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death5.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death5.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death3.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death6.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death1.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death2.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death4.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024
Sound=~player/death6.wav Channel=2 Volume=0.699707 Level=0.000000 Pitch=0.000000 Flags=1024


And for the sound hooking I disabled my sound generation while testing...

[Bacardi]

What I tested, CS:GO use so called CHAR_HRTF '~' on death sounds.
This turn sound file to work... "Head Related Transfer Function, spatialization for non-owners", and it somehow suck.
Even soundlevel is over 300 but it won't work right like "older" HL2 games.

Here sample plugin to stop game own ~player/death sound.
On next frame Emitsound to all )player/death (I think you not need add char prefix at all).

https://sm.alliedmods.net/new-api/sdktools_sound/__raw
level = you can set range how far sound would hear
volume = use 1.0, if too loud in close range, set volume lower and increase level range. 511 is max level.

something

PHP Code:

char sampledeath[][] = {
    ")player/death1.wav",
    ")player/death2.wav",
    ")player/death3.wav",
    ")player/death4.wav",
    ")player/death5.wav",
    ")player/death6.wav"
}

#include <sdktools>

#define MAX_SNDLVL_BITS        9    // Used to encode 0-255 for regular soundlevel_t's and 256-511 for goldsrc-compatible ones.
#define MIN_SNDLVL_VALUE        0
#define MAX_SNDLVL_VALUE        ((1<<MAX_SNDLVL_BITS)-1)

#define CHAR_STREAM            '*'        // as one of 1st 2 chars in name, indicates streaming wav data
#define CHAR_USERVOX        '?'        // as one of 1st 2 chars in name, indicates user realtime voice data
#define CHAR_SENTENCE        '!'        // as one of 1st 2 chars in name, indicates sentence wav
#define CHAR_DRYMIX            '#'        // as one of 1st 2 chars in name, indicates wav bypasses dsp fx
#define CHAR_DOPPLER        '>'        // as one of 1st 2 chars in name, indicates doppler encoded stereo wav: left wav (incomming) and right wav (outgoing).
#define CHAR_DIRECTIONAL    '<'        // as one of 1st 2 chars in name, indicates stereo wav has direction cone: mix left wav (front facing) with right wav (rear facing) based on soundfacing direction
#define CHAR_DISTVARIANT    '^'        // as one of 1st 2 chars in name, indicates distance variant encoded stereo wav (left is close, right is far)
#define CHAR_OMNI            '@'        // as one of 1st 2 chars in name, indicates non-directional wav (default mono or stereo)
#define CHAR_HRTF            '~'        // as one of 1st 2 chars in name, indicates wav should use HRTF spatialization for non-owners.
#define CHAR_RADIO            '+'        // as one of 1st 2 chars in name, indicates a 'radio' sound -- should be played without spatialization
#define CHAR_SPATIALSTEREO    ')'        // as one of 1st 2 chars in name, indicates spatialized stereo wav
#define CHAR_DIRSTEREO        '('        // as one of 1st 2 chars in name, indicates directional stereo wav (like doppler)
#define CHAR_FAST_PITCH        '}'        // as one of 1st 2 chars in name, forces low quality, non-interpolated pitch shift
#define CHAR_SUBTITLED        '$'        // as one of 1st 2 chars in name, indicates the subtitles are forced

public void OnPluginStart()
{
    AddNormalSoundHook(deahtsound_hook);
}

public Action deahtsound_hook(int clients[MAXPLAYERS],
    int& numClients,
    char sample[PLATFORM_MAX_PATH],
    int& entity,
    int& channel,
    float& volume,
    int& level,
    int& pitch,
    int& flags,
    char soundEntry[PLATFORM_MAX_PATH],
    int& seed)
{
    //PrintToServer("%s volu %f, level %i", sample, volume, level);

    if(StrContains(sample, "~player/death", false) == 0
    || StrContains(sample, "~)player/headshot", false) == 0)
    {
        RequestFrame(delay, GetClientUserId(entity));
        return Plugin_Stop;
    }

    if(StrContains(sample, "~)player/bhit_helmet", false) == 0)
    {
        return Plugin_Stop;
    }
    
    return Plugin_Continue;
}

public void delay(any data)
{
    int client = GetClientOfUserId(data);
    
    if(!client || !IsClientInGame(client)) return;
    
    
    int random = GetRandomInt(0, sizeof(sampledeath)-1);
    PrecacheSound(sampledeath[random]);
    EmitSoundToAll(sampledeath[random], client, .level = SNDLEVEL_CONVO, .volume = 1.0);

} 


[Austin]

I tried everything and a lot more and still no joy…
I then decided to do a search for sound plugins,
which I did before and spent a lot of time on it with no joy.
https://www.sourcemod.net/plugins.ph...tion=&search=1

But THIS time after a lot of looking through plugin source I found this one.
https://forums.alliedmods.net/showthread.php?p=926914

And it had this cvar with an interesting comment.

PHP Code:

g_emit = CreateConVar("sm_deathsound_emit", "1", 
   "1 - Emits a sound at the position of the dead player\n0 - Plays the sound directly to the players", _, true, 0.0, true, 1.0); 


It plays the sound like csgo with direction and distance information!
(Thanks Keksmampfer)
!!!

My finished plugin is a bit more complicated and plays different sounds for normal, knife,
headshot, grenade, and fire grenade kill and uses all of the death sounds from the
vpk files and it cycles through them to give a sort of randomness to the sounds.

Here is the working simplest example on how to get the sound I was looking for.

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>
#pragma semicolon 1

public void OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath, EventHookMode_Post);
}

public OnMapStart()
{
    PrecacheSound("player/death1.wav", true);
}

public Action Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int victim = GetClientOfUserId(event.GetInt("userid"));
    new Float:victimLocation[3];
    GetClientAbsOrigin(victim, victimLocation);

    //  play the death sound to all alive humans with distance and direction information
    for (int client = 1; client <= MaxClients; client++)
        if (IsClientInGame(client) && !IsFakeClient(client) && IsPlayerAlive(client))
            EmitSoundToClient(client,"player/death1.wav",SOUND_FROM_WORLD, SNDCHAN_AUTO,SNDLEVEL_NORMAL, SND_NOFLAGS, SNDVOL_NORMAL, SNDPITCH_NORMAL, -1, victimLocation);
    return Plugin_Continue;
} 


Again, as always thanks guys for all the help.
I am still learning about many things in Sourcemod and I have been learning alot from everyone....

[Austin]

In case anyone wants to see the final plugin.
There are 4 cvars with values of 1 to 10
to set the chance of that death sound playing.
Default values are 10 = always play

sm_headshotSound
sm_grenadeSound
sm_knifeSound
sm_anySound

And I can upload inc files but the compile fails.
I had to stuff the sounds from the inc file into the sp file to properly upload it.

Does the web complier not support inc files?

[Marttt]

Web compiler doesn't support inc files at the moment.
Usually, people upload the .inc file aswell.