[tepegoz]

I have this code but sometimes sort order is mixing for public displayasdls(id).
Example:

Nick1 - 10
Nick2 - 9
Nick3 - 8
Nick4 - 7
Nick5 - 6

But sometime showing this type:
Nick5 - 6
Nick4 - 7
Nick1 - 10
Nick3 - 8
Nick2 - 9

can you fix this problem or can you convert this script ?

PHP Code:

public displayasdls(id)
{
        new teals[1025];
        new len = 0, i, x;
        new temp_name[64];
        new tealrecord[33];
        new namerecord[64][64];
        tealrecord[0]=0;
        for(i=1;i<=maxplayers;i++)
        {
            if(!is_user_bot(i) &&  !is_user_hltv(i) && is_user_connected(i)){        
                tealrecord[i]=MaleRecord[i][TEAL];
                get_user_name(i, namerecord[i], 13)
            }
        }
        
            for(i=1;i<=maxplayers;i++)
            {
                if(tealrecord[i]>tealrecord[i-1])
                {
                    x=tealrecord[i];
                    tealrecord[i]=tealrecord[i-1];
                    tealrecord[i-1]=x;
                    temp_name=namerecord[i];
                    namerecord[i]=namerecord[i-1];
                    namerecord[i-1]=temp_name;
                }

        }
        len += format(steals[len], 512-len, "TOP TEAL^n^n")
        len += format(steals[len], 512-len, "%s  -  %i^n",namerecord[0], tealrecord[0])
        len += format(steals[len], 512-len, "%s  -  %i^n",namerecord[1], tealrecord[1])
        len += format(steals[len], 512-len, "%s  -  %i^n",namerecord[2], tealrecord[2])
        len += format(steals[len], 512-len, "%s  -  %i^n",namerecord[3], tealrecord[3])
        len += format(steals[len], 512-len, "%s  -  %i",namerecord[4], tealrecord[4])
        
        set_dhudmessage(0, 255, 0,  0.38, 0.0, 0, 0.2, 3.0, 0.2, 0.1)
        show_dhudmessage(id, "%s", teals)
} 


PHP Code:

new MaleRecord[MAX_PLAYER + 1][RECORDS+1] 


[Bugsy]

Your sort logic is bad, I would use SortCustom2D(). Untested and might need some tweaks.

PHP Code:

public displayasdls(id)
{
    enum _:RankData
    {
        RankID,
        RankValue
    }
    
    const MaxToRank = 5;
    
    new steals[ 1025 ] , len;
    new rdData[ MAX_PLAYERS + 1] [ RankData ];
    new iPlayers[ 32 ] , iNum , iPlayer , i , szName[ 32 ] , iNumRanked;
    
    get_players( iPlayers , iNum , "ch" );
    for ( i = 0 ; i < iNum ; i++ )
    {    
        iPlayer = iPlayers[ i ];
        
        rdData[ i ][ RankID ] = iPlayer;
        rdData[ i ][ RankValue ] = MadeRecord[ iPlayer ][ STEAL ];
    }
    
    SortCustom2D( _:rdData , iNum , "SortCompare" );
    
    iNumRanked = min( iNum , MaxToRank );

    len = copy(steals, charsmax( steals ) , "TOP STEAL^n^n")
    
    for ( i = 0 ; i < iNumRanked ; i++ ) 
    {
        get_user_name( rdData[ i ][ RankID ] , szName , charsmax( szName ) );
        len += formatex( steals[ len ] , charsmax( steals )-len, "%s  -  %i^n" , szName , rdData[ i ][ RankValue ] )
    }
    
    set_dhudmessage(0, 255, 0,  0.38, 0.0, 0, 0.2, 3.0, 0.2, 0.1)
    show_dhudmessage(id, steals)
}

public SortCompare( elem1[] , elem2[] ) 
{ 
    if ( elem1[ 1 ] > elem2[ 1 ] ) 
        return -1; 
    else if(elem1[ 1 ] < elem2[ 1 ] ) 
        return 1; 
    else
        return 0; 
} 


[tepegoz]

thank you very much.