[abhishek_deshkar]

This plugin blocks Friendlyfire but enables incendiary/molotove damage to teammates. You might want to use this plugin for retakes.

NOTE: You don't need to change/set cvars to enable this plugin.

Installation

1. Download and compile the latest source.
2. Place .smx in addons/sourcemod/plugins

After installation, teammates will take only molotov/incendiary damage.

[pandd]

C4 is harmless and unbalanced

[abhishek_deshkar]

Originally Posted by pandd C4 is harmless and unbalanced

Fixed C4 damage. Please let me know if you find any bug.

[Ilusion9]

Never send a command in OnPluginStart function.

PHP Code:


#include <sourcemod>
#include <sdkhooks>

public Plugin myinfo = {
    name = "Enable FF Molotov/Inc only Damage",
    author = "Abhishek Deshkar",
    description = "This plugin blocks Friendlyfire but enables incendiary/molotove damage to teammates.",
    version = "1.6",
    url = "https://www.facebook.com/abhi.pro"
};

ConVar g_Cvar_FriendlyFire;

public void OnPluginStart()
{
    g_Cvar_FriendlyFire = FindConVar("mp_friendlyfire");
}

public void OnConfigsExecured()
{
    g_Cvar_FriendlyFire.SetInt(1);
}

public OnClientPutInServer(client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3])
{
    if (attacker < 1 || attacker > MaxClients || attacker == victim || attacker == inflictor || weapon < 1)
    {
        return Plugin_Continue;
    }
    
    if (GetClientTeam(victim) == GetClientTeam(attacker))
    {
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


Try this, I've simplified your code.

[abhishek_deshkar]

Originally Posted by Ilusion9 Never send a command in OnPluginStart function. PHP Code: #include <sourcemod> #include <sdkhooks> public Plugin myinfo = {     name = "Enable FF Molotov/Inc only Damage",     author = "Abhishek Deshkar",     description = "This plugin blocks Friendlyfire but enables incendiary/molotove damage to teammates.",     version = "1.6",     url = "https://www.facebook.com/abhi.pro" }; ConVar g_Cvar_FriendlyFire; public void OnPluginStart() {     g_Cvar_FriendlyFire = FindConVar("mp_friendlyfire"); } public void OnConfigsExecured() {     g_Cvar_FriendlyFire.SetInt(1); } public OnClientPutInServer(client) {     SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage); } public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3]) {     if (attacker < 1 || attacker > MaxClients || attacker == victim || attacker == inflictor || weapon < 1)     {         return Plugin_Continue;     }          if (GetClientTeam(victim) == GetClientTeam(attacker))     {         return Plugin_Handled;     }          return Plugin_Continue; }  Try this, I've simplified your code.

Thanks for the optimizing plugin. I've updated it.

[GTAmama16]

weird, im still not taking dmg from a friendly molotov, do i need to set the mp_friendlyfire to 1 in the server.cfg?

[Ilusion9]

Originally Posted by GTAmama16 weird, im still not taking dmg from a friendly molotov, do i need to set the mp_friendlyfire to 1 in the server.cfg?

No.
I haven't tested this plugin, but maybe the condition (attacker == inflictor) it's not enough to check if the damage was done by a molotov.

[GTAmama16]

Originally Posted by Ilusion9 No. I haven't tested this plugin, but maybe the condition (attacker == inflictor) it's not enough to check if the damage was done by a molotov.

yeah i have tried both FF on 1 and 0, the plugin is not working, no error msg showed either

[Ejziponken]

Gah, this is the 3rd plugin I test for this and none of them working (I havent confirmed the one in this thread tho, just reading the comments).

[Ilusion9]

Even with friendlyfire on 1, you must set ff_ cvars right:

PHP Code:


mp_friendlyfire 1
ff_damage_reduction_bullets 0.33
ff_damage_reduction_grenade 0.85
ff_damage_reduction_grenade_self 1
ff_damage_reduction_other 0.4 


Plugin tested and works correctly:

PHP Code:

#include <sourcemod>
#include <sdkhooks>

public OnClientPutInServer(client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype, int &weapon, float damageForce[3], float damagePosition[3])
{
    // Invalid attacker or self damage
    if (attacker < 1 || attacker > MaxClients || attacker == victim || inflictor < 1)
    {
        return Plugin_Continue;
    }
    
    // Frienly fire
    if (GetClientTeam(attacker) == GetClientTeam(victim))
    {
        char inflictorClass[64];
        if (GetEdictClassname(inflictor, inflictorClass, sizeof(inflictorClass)))
        {
            // C4 damage
            if (StrEqual(inflictorClass, "planted_c4"))
            {
                return Plugin_Continue;
            }
            
            // Incendiary damage
            if (StrEqual(inflictorClass, "inferno"))
            {
                return Plugin_Continue;
            }
        }
        
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


Also, you should check mp_tkpunish and mp_autokick cvars.