Search Plugin: Random Start Weapons

ProjectDefconTeam · **Author**

Hallo,
wir suchen ein Plugin für unseren Fun Server.
es handelt sich hier bei um dein Random Give Weapons Give plugin.
wir haben zwar schon paar gefunden aber die sprechen uns leider nicht so an.

das plugin sollte beinhalten:
-Kaufen blocken
-waffen aufnehmen blocken
-waffen fallen lassen blocken
-jede runde neue funwaffe. (keine Rifles, m4 ak usw. only shotguns and miniguns)
-die alten dafür wegnehmen.

hoffen das uns wer weiterhelfen könnte.

mfg Porject Defcon

master4life · 08-21-2010 , 14:54 Re: Search Plugin: Random Start Weapons

Mir war gerade langwelig und hab dir das mal zusammen gewürfelt, ich wusste zwar nicht was du mit minigun meintest aber dafür hab ich die m249 genommen.

sag mir bescheid wenn was nicht funktioniert.

PHP Code:


			
#include < amxmodx >
#include < fun >
#include < engine >
#include < hamsandwich >

public plugin_init( ) {
    register_plugin( "Funwar: XYZ", "0.1", "master4life" );

    register_clcmd( "buy", "CmdBlock" );
    register_clcmd( "drop", "CmdBlock" );
    
    RegisterHam( Ham_Spawn, "player", "FwdHamSpawnPlayerPost", true );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPickupWeaponPre", false );
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPickupWeaponPre", false );
    
    server_cmd( "sv_restart 1" );
    server_exec( );
}

public plugin_precache( ) {
    new iEntity = create_entity( "info_map_parameters" );
    DispatchKeyValue( iEntity, "buying", "3" );
    DispatchSpawn( iEntity );
}

public CmdBlock( )
    return PLUGIN_HANDLED;

public FwdHamPickupWeaponPre( const iEntity, const id )
    return HAM_SUPERCEDE;

public FwdHamSpawnPlayerPost( const id ) {
    if( !is_user_alive( id ) )
        return;
    
    strip_user_weapons( id );
    give_item( id, "weapon_knife" );
    
    switch( random_num( 0, 2 ) ) {
        case 0: give_item( id, "weapon_m3" );
        case 1: give_item( id, "weapon_xm1014" );
        case 2: give_item( id, "weapon_m249" );
    }
}

ProjectDefconTeam · 08-21-2010 , 15:06 Re: Search Plugin: Random Start Weapons

ganz nett danke.

aber mit den miniguns meinte ich mehrere ^^
die ganzen kleineren.
wie:
m3
xm1014
tmp
mp5
mac10
ump45
p90
scout

eine frage hätte ich denn noch bei dem plugin gibt er auch dem entsprechend volles magazin? =)

platzpatrone · 08-21-2010 , 15:10 Re: Search Plugin: Random Start Weapons

Minigun ist eigentlich m249 bzw. mit andern Features.
Was du meinst sind die mediums.

Und nein er gibt keine volle Munition, da du nix von erwähnt hast
hat auch master das nicht reingetan ^^

ProjectDefconTeam · 08-21-2010 , 15:26 Re: Search Plugin: Random Start Weapons

hmmz wäre nett wenn das plugin das acuh täte da buymenü ja geblockt werden sollte ^^

achso naja ich kenn sie nur unter miniguns

aber macht ja nix

ProjectDefconTeam · *Last edited by ProjectDefconTeam; 08-21-2010 at 16:44.*

Also ich hab mich jetzt mal selber ein wenig dran probiert und wenns richtig ist ist es gut ^^ weil ich kann das eigentlich garnicht.

aber naja.

Code:

#include < amxmodx >
#include < fun >
#include < engine >
#include < hamsandwich >

public plugin_init( ) {
    register_plugin( "Funwar: pd_rpwg", "0.1", "master4life" );

    register_clcmd( "buy", "CmdBlock" );
    register_clcmd( "drop", "CmdBlock" );
    
    RegisterHam( Ham_Spawn, "player", "FwdHamSpawnPlayerPost", true );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPickupWeaponPre", false );
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPickupWeaponPre", false );
    
    server_cmd( "sv_restart 1" );
    server_exec( );
}

public plugin_precache( ) {
    new iEntity = create_entity( "info_map_parameters" );
    DispatchKeyValue( iEntity, "buying", "3" );
    DispatchSpawn( iEntity );
}

public CmdBlock( )
    return PLUGIN_HANDLED;

public FwdHamPickupWeaponPre( const iEntity, const id )
    return HAM_SUPERCEDE;

public FwdHamSpawnPlayerPost( const id ) {
    if( !is_user_alive( id ) )
        return;
    
    strip_user_weapons( id );
    give_item( id, "weapon_knife" );
    give_item( id, "weapon_usp" );
    cs_set_user_bpammo(id, CSW_usp, 100);
    
    switch( random_num( 0, 7 ) ) {
        case 0: give_item( id, "weapon_m3" ); cs_set_user_bpammo(id, CSW_m3, 32);
        case 1: give_item( id, "weapon_xm1014" ); cs_set_user_bpammo(id, CSW_xm1014, 32);
        case 2: give_item( id, "weapon_p90" ); cs_set_user_bpammo(id, CSW_p90, 100);
        case 3: give_item( id, "weapon_ump45" ); cs_set_user_bpammo(id, CSW_ump45, 60);
        case 4: give_item( id, "weapon_mp5" ); cs_set_user_bpammo(id, CSW_mp5, 90);
        case 5: give_item( id, "weapon_mac10" ); cs_set_user_bpammo(id, CSW_mac10, 60);
        case 6: give_item( id, "weapon_tmp" ); cs_set_user_bpammo(id, CSW_tmp, 90);
        case 7: give_item( id, "weapon_scout" ); cs_set_user_bpammo(id, CSW_scout, 60);
    }
}

Das rote habe ich jetzt dazugefügt

platzpatrone · 08-21-2010 , 17:25 Re: Search Plugin: Random Start Weapons

naja naja, hier mal gefixt und ungetestet, compilen geht aber nun.

PHP Code:


			
#include < amxmodx >
#include < fun >
#include < engine >
#include < cstrike >
#include < hamsandwich >

public plugin_init( ) {
    register_plugin( "Funwar: pd_rpwg", "0.1", "master4life" );

    register_clcmd( "buy", "CmdBlock" );
    register_clcmd( "drop", "CmdBlock" );
    
    RegisterHam( Ham_Spawn, "player", "FwdHamSpawnPlayerPost", true );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPickupWeaponPre", false );
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPickupWeaponPre", false );
    
    server_cmd( "sv_restart 1" );
    server_exec( );
}

public plugin_precache( ) {
    new iEntity = create_entity( "info_map_parameters" );
    DispatchKeyValue( iEntity, "buying", "3" );
    DispatchSpawn( iEntity );
}

public CmdBlock( )
    return PLUGIN_HANDLED;

public FwdHamPickupWeaponPre( const iEntity, const id )
    return HAM_SUPERCEDE;

public FwdHamSpawnPlayerPost( const id ) {
    if( !is_user_alive( id ) )
        return;
    
    strip_user_weapons( id );
    give_item( id, "weapon_knife" );
    give_item( id, "weapon_usp" );
    cs_set_user_bpammo(id, CSW_USP, 100);
    
    switch( random_num( 0, 7 ) ) {
        case 0: { give_item( id, "weapon_m3" ); cs_set_user_bpammo(id, CSW_M3, 32); }
        case 1: { give_item( id, "weapon_xm1014" ); cs_set_user_bpammo(id, CSW_XM1014, 32); }
        case 2: { give_item( id, "weapon_p90" ); cs_set_user_bpammo(id, CSW_P90, 100); }
        case 3: { give_item( id, "weapon_ump45" ); cs_set_user_bpammo(id, CSW_UMP45, 60); }
        case 4: { give_item( id, "weapon_mp5navy" ); cs_set_user_bpammo(id, CSW_MP5NAVY, 90); }
        case 5: { give_item( id, "weapon_mac10" ); cs_set_user_bpammo(id, CSW_MAC10, 60); }
        case 6: { give_item( id, "weapon_tmp" ); cs_set_user_bpammo(id, CSW_TMP, 90); }
        case 7: { give_item( id, "weapon_scout" ); cs_set_user_bpammo(id, CSW_SCOUT, 60); }
    }
}