[Hellkong]

Good evening,

I request a code that hooks the event of something touchs the water, let's say a player or a bullet hits water surface so i can emit a sound (like jump in wave sound) or spawn an entity or something only in our water surface.

+ want hook of bullet alone, I want to spawn a sprite.

Thank you.

[JusTGo]

check https://forums.alliedmods.net/showthread.php?t=69835

[Hellkong]

Not what i want, this is a think func calling it many times while player in water.
I'll reform my words
I want to hook the the event only when he touchs the surface only (1 event , one possible event not consistent ), and I want another through TraceAttack (bullet event) if possible (to spawn streak splash)

[JusTGo]

As far as I know, there isn't an event that you can easily hook to detect players entering the water, but with some work in the think func you can create a variable to save player state and check if the player is actually entering the water and do your work there.

[JusTGo]

Something like this should work for players:

PHP Code:

#include amxmodx
#include fakemeta

new gInWater[MAX_PLAYERS+1]

public plugin_init()
{
    register_plugin("Water check", "1.0", "JustGo")
    register_forward(FM_PlayerPreThink, "playerPreThink");
}

public playerPreThink(id)
{
    if(!is_user_alive(id)) return FMRES_IGNORED

    if(isInWater(id))
    {
        if(!gInWater[id])
        {
            gInWater[id] = 1
            playerEnterWater(id)
        }
    }
    else
    {
        if(gInWater[id])
        {
            gInWater[id] = 0
        }
    }

    return FMRES_IGNORED
}

// Do your work here
playerEnterWater(id)
{
    client_print(id, print_chat, "* You entered water.")
}

isInWater(id)
{
    return (pev(id,pev_flags) & FL_INWATER)
} 


[Natsheh]

pev_waterlevel


// waterlevel 0 - not in water
// waterlevel 1 - feet in water
// waterlevel 2 - waist in water
// waterlevel 3 - head in water


About checking if a bullet hit the water surface you need to check if the weapon trace line penetrated the water box.

[+ARUKARI-]

There's also this water check.

PHP Code:

new Float:vOrigin[3];
pev(id, pev_origin, vOrigin);

if(engfunc(EngFunc_PointContents, vOrigin) == CONTENTS_WATER) {
// In water
} else {
// otherwise
} 


[Hellkong]

Originally Posted by JusTGo Something like this should work for players:

I thought there should be a special event for such cases but I guess not, your code should work fine in emiting sounds, but not spawning something precisely on the surface. I'll try something familiar.

Originally Posted by Natsheh pev_waterlevel // waterlevel 0 - not in water // waterlevel 1 - feet in water // waterlevel 2 - waist in water // waterlevel 3 - head in water About checking if a bullet hit the water surface you need to check if the weapon trace line penetrated the water box.

Something like?

PHP Code:

public plugin_init()
{
    RegisterHam(Ham_TraceAttack, "func_water", "Fw_TraceAttack") // We use "func_water" for more precising.
}
public Fw_TraceAttack(Entity, Attacker, Float:Damage, Float:Direction[3], Ptr, Damagetype)
{
    if(!is_user_connected(Attacker))
        return FMRES_IGNORED

    new Float:fEnd[3]
    get_tr2(Ptr, TR_vecEndPos, fEnd)

    if(engfunc(EngFunc_PointContents, fEnd) == CONTENTS_WATER) {
    // etc
    }
} 


Originally Posted by +ARUKARI- There's also this water check.

Check the mini code above if it is correct?

[JusTGo]

Originally Posted by Hellkong I thought there should be a special event for such cases but I guess not, your code should work fine in emitting sounds, but not spawning something precisely on the surface. I'll try something familiar.

I guess to do it precisely on the surface you might try changing the InWater function in the code I posted to something like this:

PHP Code:

isInWater(id)
{
    new watertype = pev(id, pev_watertype)
    return (watertype <= CONTENTS_WATER && watertype > CONTENTS_TRANSLUCENT)
} 


[Natsheh]

Originally Posted by Hellkong I thought there should be a special event for such cases but I guess not, your code should work fine in emiting sounds, but not spawning something precisely on the surface. I'll try something familiar. Something like? PHP Code: public plugin_init() {     RegisterHam(Ham_TraceAttack, "func_water", "Fw_TraceAttack") // We use "func_water" for more precising. } public Fw_TraceAttack(Entity, Attacker, Float:Damage, Float:Direction[3], Ptr, Damagetype) {     if(!is_user_connected(Attacker))         return FMRES_IGNORED     new Float:fEnd[3]     get_tr2(Ptr, TR_vecEndPos, fEnd)     if(engfunc(EngFunc_PointContents, fEnd) == CONTENTS_WATER) {     // etc     } }  Check the mini code above if it is correct?

No, you need to hook FM_Traceline and check if the weapon traceline attack passes through the water.