[Napoleon_be]

I have this code

PHP Code:

public GetFreePoints(id)
{
    new szName[32], szAuth[35];
    get_user_name(id, szName, charsmax(szName));
    get_user_authid(id, szAuth, charsmax(szAuth));

    if(!nvault_get(g_iVaultHandle, szAuth, szName, charsmax(szName)))
    {
        hnsxp_add_user_xp(id, get_pcvar_num(g_pPointsAmount));
        nvault_set(g_iVaultHandle, szAuth, szName);
        CC_SendMessage(id, "You succesfully received &x03%i &x04XP&x01.", get_pcvar_num(g_pPointsAmount));
    }
} 


No matter what, that check still passes every time. Can someone explain me why, cause i'm really not getting it right now.

[Natsheh]

Use nvault_lookup instead.


or you can do this, you don't have to save the name.

PHP Code:

public GetFreePoints(id)
{
    new szAuth[35];
    get_user_authid(id, szAuth, charsmax(szAuth));

    if(nvault_get(g_iVaultHandle, szAuth) != 1)
    {
        new szName[32];
        get_user_name(id, szName, charsmax(szName));
        hnsxp_add_user_xp(id, get_pcvar_num(g_pPointsAmount));
        nvault_set(g_iVaultHandle, szAuth, "1");
        CC_SendMessage(id, "You succesfully received &x03%i &x04XP&x01.", get_pcvar_num(g_pPointsAmount));
    }
} 


[Napoleon_be]

Thanks for the help, will try it.

Could u explain to me why it wasn't working as how i tried to do it?

My intention was to save the name according to the steam id. So everytime a player joins with the same steam id, but a different name, this check should still be passed.

The basic idea is to give someone points just once per name. Once their name is changed, i want the command to be available again. I don't wanna use booleans for this.

[Natsheh]

Then change the key to save by name instead of steamid if you desire to give points per name.

And about the explanation you can just do debugging and see what'sthe outputs.

[Shadows Adi]

Originally Posted by Napoleon_be I have this code No matter what, that check still passes every time. Can someone explain me why, cause i'm really not getting it right now.

http://www.amxmodx.org/api/nvault/nvault_get

Return
Result as integer if only the first two arguments
of the function are used.
1 if only the first three arguments are used.
String length if all four parameters are used.

[Napoleon_be]

Originally Posted by Shadows Adi http://www.amxmodx.org/api/nvault/nvault_get Return Result as integer if only the first two arguments of the function are used. 1 if only the first three arguments are used. String length if all four parameters are used.

However, my first example should return a string, as explained in the wiki.

nvault_get(vaultHandle, "myKey", myString, charsmax(myString));

Originally Posted by Natsheh Then change the key to save by name instead of steamid if you desire to give points per name. And about the explanation you can just do debugging and see what'sthe outputs.

Yea you're right, i'll just save by name, lmao my brain these days.

[Shadows Adi]

Originally Posted by Napoleon_be However, my first example should return a string, as explained in the wiki. nvault_get(vaultHandle, "myKey", myString, charsmax(myString));

No, in return you will get the string lenght, string is copied into the parameter passed.

[Napoleon_be]

Originally Posted by Shadows Adi No, in return you will get the string lenght, string is copied into the parameter passed.

You're right.

From what i've heard of the tester, this version should work.

PHP Code:

public GetFreePoints(id)
{
    new szName[MAX_NAME_LENGTH], szResult[MAX_NAME_LENGTH];
    get_user_name(id, szName, charsmax(szName));

    log_amx("DEBUG: Player current name: %s", szName);

    if(nvault_get(g_iVaultHandle, szName, szResult, charsmax(szResult)))
    {
        log_amx("DEBUG: Player name was already found: %s", szResult);
        return PLUGIN_HANDLED;
    }

    log_amx("DEBUG: Player name not found in nvault: %s, xp granted.", szName);

    nvault_set(g_iVaultHandle, szName, szName);

    hnsxp_add_user_xp(id, get_pcvar_num(g_pPointsAmount));

    CC_SendMessage(id, "You succesfully received &x03%i &x04XP&x01.", get_pcvar_num(g_pPointsAmount));

    return PLUGIN_HANDLED;
} 


If anyone has suggestions on how to do it "better", always welcome.

[bigdaddy424]

If this command can be used more than once, you can use the timestamp advantage nvault offers using nvault_lookup. Whenever you claim your points update its timestamp with nvault_touch.

[Napoleon_be]

Originally Posted by bigdaddy424 If this command can be used more than once, you can use the timestamp advantage nvault offers using nvault_lookup. Whenever you claim your points update its timestamp with nvault_touch.

Why would i do that when i only have to compare player name vs vault player name?

It's pretty simple: If name is not found in nvault, give XP. If name is found in nvault, don't give XP, cause he already got it earlier.