[LiveAndLetDie]

Hey, I want to check if client has at least one of the required flags set by cvar. Below is an example code which apparently only works with the first flag in the cvar string because if I give myself only 'o' flag then I don't have access.

#include <sourcemod>

ConVar g_cFlags;
int g_iFlags;

public void OnPluginStart()
{
    g_cFlags = CreateConVar("sm_test_flags", "bo");
    RegConsoleCmd("sm_test", OnTest);
}

public void OnConfigsExecuted()
{
    char Buffer[8];
    GetConVarString(g_cFlags, Buffer, sizeof(Buffer));
    g_iFlags = ReadFlagString(Buffer);
}

public Action OnTest(int client, int args)
{
    HasFlag(client) ? PrintToChat(client, "Access!") : PrintToChat(client, "No access!");
    return Plugin_Handled;
}

bool HasFlag(int client)
{
    return(CheckCommandAccess(client, "", g_iFlags, true));
}

How to modify it to meet the requirements? Any help would be appreciated.

[Psyk0tik]

Try checking for the flags like this:

PHP Code:

bool HasFlag(int client)
{
    int iUserFlags = GetUserFlagBits(client);
    return (g_iFlags != 0 && (iUserFlags & g_iFlags)) || (iUserFlags & ADMFLAG_ROOT);
} 


[SSheriFF]

Originally Posted by LiveAndLetDie Hey, I want to check if client has at least one of the required flags set by cvar. Below is an example code which apparently only works with the first flag in the cvar string because if I give myself only 'o' flag then I don't have access. #include <sourcemod> ConVar g_cFlags; int g_iFlags; public void OnPluginStart() { g_cFlags = CreateConVar("sm_test_flags", "bo"); RegConsoleCmd("sm_test", OnTest); } public void OnConfigsExecuted() { char Buffer[8]; GetConVarString(g_cFlags, Buffer, sizeof(Buffer)); g_iFlags = ReadFlagString(Buffer); } public Action OnTest(int client, int args) { HasFlag(client) ? PrintToChat(client, "Access!") : PrintToChat(client, "No access!"); return Plugin_Handled; } bool HasFlag(int client) { return(CheckCommandAccess(client, "", g_iFlags, true)); } How to modify it to meet the requirements? Any help would be appreciated.

Found this.
With a small modification it can get you what you want.

PHP Code:

stock bool CheckAdminFlagsByString(int client, const char[] flagString)
{
    AdminId admin = view_as<AdminId>(GetUserAdmin(client));
    if (admin != INVALID_ADMIN_ID)
    {
        int flags = ReadFlagString(flagString);
        for (int i = 0; i <= 20; i++)
        {
            if (flags & (1<<i))
            {
                if(GetAdminFlag(admin, view_as<AdminFlag>(i)))
                    return true;
              }
          }
    }
    return false;
} 


[LiveAndLetDie]

Both of these do the job. Thanks a lot!