[CluSt3r]

Thank you man,works perfect.

[Catastrophe]

Originally Posted by CluSt3r Thank you man,works perfect.

No problem, if u have any more problems post here (relating to this plugin) i'll do all i can

[anantthakor]

i want to disable few items form this, like nightvision etc. how to do that ?

[Catastrophe]

Name the items, i will disable and give u...

[anantthakor]

Bonuses:

1. Night vision
2. Glow like a survivor
3. Weapons: SG550, G3SG1, M249, AWP

remove above please !

[Catastrophe]

Try :-

PHP Code:

/*
Name: [ZP] Addon: Bonus Box
Author: PomanoB & STRELOK
Version 1.0

Based on [ZP] DM Item's by PomanoB
*/

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <fakemeta_util>
#include <zombieplague>
#include <hamsandwich>

#define PLUGIN "[ZP] Addon: Bonus Box"
#define VERSION "1.0"
#define AUTHOR "PomanoB & Accelerator"

#define OFFSET_FLASH_AMMO 387
#define OFFSET_HE_AMMO 388
#define OFFSET_SMOKE_AMMO 389

new const item_class_name[] = "dm_item"

new g_models[][] = {"models/zombie_plague/presents.mdl"}

public plugin_precache()
{
    for (new i = 0; i < sizeof g_models; i++)
        precache_model(g_models[i])    
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_forward(FM_Touch, "fwd_Touch")
    
    register_event("HLTV", "round_start", "a", "1=0", "2=0")
    
    RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")
    
    register_dictionary("bonus_box.txt")
}

public fwd_Touch(toucher, touched)
{
    if (!is_user_alive(toucher) || !pev_valid(touched))
        return FMRES_IGNORED
    
    new classname[32]    
    pev(touched, pev_classname, classname, 31)
    if (!equal(classname, item_class_name))
        return FMRES_IGNORED
    
    
    
    give_item(toucher)
    set_pev(touched, pev_effects, EF_NODRAW)
    set_pev(touched, pev_solid, SOLID_NOT)
    
    return FMRES_IGNORED
    
}

public fw_PlayerKilled(victim, attacker, shouldgib)
{
    if (!is_user_connected(attacker) || !is_user_connected(victim) || attacker == victim || !attacker)
        return HAM_IGNORED
    
    
    new random = random_num(0, 8)
    
    if (random == 1 || random == 4 || random == 6)
    {
        new origin[3]
        get_user_origin(victim, origin, 0)
        
        addItem(origin)
    }
    
    return HAM_IGNORED
}

public removeEntity(ent)
{
    if (pev_valid(ent))
        engfunc(EngFunc_RemoveEntity, ent)
}

public addItem(origin[3])
{
    new ent = fm_create_entity("info_target")
    set_pev(ent, pev_classname, item_class_name)
    
    engfunc(EngFunc_SetModel,ent, g_models[random_num(0, sizeof g_models - 1)])

    set_pev(ent,pev_mins,Float:{-10.0,-10.0,0.0})
    set_pev(ent,pev_maxs,Float:{10.0,10.0,25.0})
    set_pev(ent,pev_size,Float:{-10.0,-10.0,0.0,10.0,10.0,25.0})
    engfunc(EngFunc_SetSize,ent,Float:{-10.0,-10.0,0.0},Float:{10.0,10.0,25.0})

    set_pev(ent,pev_solid,SOLID_BBOX)
    set_pev(ent,pev_movetype,MOVETYPE_FLY)
    
    new Float:fOrigin[3]
    IVecFVec(origin, fOrigin)
    set_pev(ent, pev_origin, fOrigin)
    
    set_pev(ent,pev_renderfx,kRenderFxGlowShell)
    switch(random_num(1,4))
    {
        case 1: set_pev(ent,pev_rendercolor,Float:{0.0,0.0,255.0})
        case 2: set_pev(ent,pev_rendercolor,Float:{0.0,255.0,0.0})
        case 3: set_pev(ent,pev_rendercolor,Float:{255.0,0.0,0.0})
        case 4: set_pev(ent,pev_rendercolor,Float:{255.0,255.0,255.0})
    }
}

public give_item(id)
{
    new zombie 
    zombie = zp_get_user_zombie(id)
    
    new i = random_num(0, (zombie ? 5 : 7))
    switch (i)
    {
        case 0:
            if (zombie)
            {
                if (!zp_get_user_last_zombie(id) && !zp_is_survivor_round() && !zp_is_swarm_round())
                {
                    zp_disinfect_user(id)
                    ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_ANTIDOT")
                }
                else
                    ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_NO")    
            }
            else
            {
                if (!zp_get_user_last_human(id) && !zp_is_survivor_round() && !zp_is_swarm_round())
                {
                    zp_infect_user(id)
                    ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_INFECT")
                }
                else
                    ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_NO")
            }
            
        case 1:
        {
            fm_set_user_health(id, get_user_health(id) + (zombie ? 500 : 50))
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_HEALTH_UP")
        }
        case 2:
        {
            fm_set_user_health(id, get_user_health(id) - (zombie ? 250 : 25))
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_HEALTH_DOWN")
        }
        case 3:
        {
            zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + random_num(1, 5))
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_AMMOPACKS_UP")
        }
        case 4:
        {
            zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) - random_num(1, 5))
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_AMMOPACKS_DOWN")
        }
        case 5:
        {
            fm_set_user_gravity(id, 0.5)
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_GRAVITY")
        }
        
        case 6:
        {
            fm_set_user_armor(id, get_user_armor(id) + 100)
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_ARMOR_UP")
        }
        case 7:
        {
            fm_set_user_armor(id, get_user_armor(id) - 100)
            ChatColor(id, "!g[ZP]!y %L", LANG_PLAYER, "ITEM_DM_ARMOR_DOWN")
        }
        
    }
}

public round_start()
{
    new ent = FM_NULLENT
    static string_class[] = "classname"
    while ((ent = engfunc(EngFunc_FindEntityByString, ent, string_class, item_class_name))) 
        set_pev(ent, pev_flags, FL_KILLME)
}

// Stock: ChatColor!
stock ChatColor(const id, const input[], any:...)
{
    new count = 1, players[32]
    static msg[191]
    vformat(msg, 190, input, 3)
    
    replace_all(msg, 190, "!g", "^4") // Green Color
    replace_all(msg, 190, "!y", "^1") // Default Color
    replace_all(msg, 190, "!team", "^3") // Team Color
    replace_all(msg, 190, "!team2", "^0") // Team2 Color
    
    if (id) players[0] = id; else get_players(players, count, "ch")
    {
        for (new i = 0; i < count; i++)
        {
            if (is_user_connected(players[i]))
            {
                message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
                write_byte(players[i]);
                write_string(msg);
                message_end();
            }
        }
    }
} 


[anantthakor]

this error

L 08/10/2013 - 177:03: Info (map "zm_trakinax_tubo") (file "addons/amxmodx/logs/error_20130810.log")
L 08/10/2013 - 177:03: [AMXX] Plugin file open error (plugin "cj_zp_bonus_box.amxx")

[Catastrophe]

Type the name correctly -_-

[anantthakor]

oh yeah , ty

[Erdener]

Thnx for plugin

Turkish:

[tr]
ITEM_DM_ANTIDOT = Sanslisin, Panzehiri buldun
ITEM_DM_INFECT = T-Virusune Yakalandin
ITEM_DM_HEALTH_UP = Saglik Kazandin
ITEM_DM_HEALTH_DOWN = Saglik Kaybettin
ITEM_DM_AMMOPACKS_UP = Bir miktar ammo kazandin
ITEM_DM_AMMOPACKS_DOWN = Bir miktar ammo kaybettin
ITEM_DM_GRAVITY = Yercekimin Azaldi
ITEM_DM_NIGHTVISION = Gecegorus cihazi buldun
ITEM_DM_ARMOR_UP = Zombilerden korunmak icin Zirh buldun
ITEM_DM_ARMOR_DOWN = Zirh kaybettin.Artik savunmasizsin
ITEM_DM_BRIGHTLIGHT = Parlak isik buldun
ITEM_DM_GRENADES = Bomba seti buldun
ITEM_DM_SG550 = SG550 silahini buldun
ITEM_DM_G3SG1 = G3SG1 silahini buldun
ITEM_DM_M249 = M249 silahini buldun
ITEM_DM_AWP = AWP silahini buldun
ITEM_DM_NO = Sansina kutu bos cikti