[4LiveTV]

Sorry for bad english :/
Hi! I just wanted to trun the player's model and his weapon invisible. Player's model is easy to hide but i have a problem with hiding weapons.
I use this for hiding weapons on my serv:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
public Plugin:myinfo = 
{
    name = "InvisFix",
    author = "~",
    description = "",
    version = "1.0",
    url = "<- URL ->"
}
public OnPluginStart()
{
    HookEvent("player_spawn", onPlayerSpawn);
}
public Action:onPlayerSpawn(Handle:event,const String:name[],bool:dontBroadcast)
{
    ServerCommand("ent_fire env_cascade_light kill");
    forceinvis();
    forcevisible();
}
forceinvis()
{
    for(new client = 1; client <= MaxClients; client++)
    {
        if(IsClientInGame(client) && IsValidClient(client))
        {
            SDKHookEx(client, SDKHook_PostThinkPost, OnPostThinkPost);
            SetEntProp(client, Prop_Send, "m_nRenderFX", RENDERFX_NONE);
            SetEntProp(client, Prop_Send, "m_nRenderMode", RENDER_NONE);
        }
    }
    
    
    
    new entity = MaxClients+1;
    
 while( (entity = FindEntityByClassname(entity, "weaponworldmodel")) != -1 )
    {
        if(IsValidEntity(entity))
            SetEntProp(entity, Prop_Send, "m_nModelIndex", 0);
    }
forcevisible()
{
    for(new client = 1; client <= MaxClients; client++)
    {
        if(IsClientInGame(client)  && IsValidClient(client))
        {
            SetEntityRenderMode(client, RENDER_TRANSCOLOR);
            SetEntityRenderColor(client, 255, 255, 255, 255); 
        }
    }
}
public OnPostThinkPost(client)
{
    SetEntProp(client, Prop_Send, "m_iAddonBits", 0);
}  
public IsValidClient( client ) 
{ 
    if ( !( 1 <= client <= MaxClients ) || !IsClientInGame(client) ) 
        return false; 
    
    return true; 
}

I also tryied this

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
public Plugin:myinfo = 
{
    name = "InvisFix",
    author = "~",
    description = "",
    version = "1.0",
    url = "<- URL ->"
}
public OnPluginStart()
{
    HookEvent("player_spawn", onPlayerSpawn);
}
public Action:onPlayerSpawn(Handle:event,const String:name[],bool:dontBroadcast)
{
    ServerCommand("ent_fire env_cascade_light kill");
    forceinvis();
    forcevisible();
}
forceinvis()
{
    for(new client = 1; client <= MaxClients; client++)
    {
        if(IsClientInGame(client) && IsValidClient(client))
        {
            SDKHookEx(client, SDKHook_PostThinkPost, OnPostThinkPost);
            SetEntProp(client, Prop_Send, "m_nRenderFX", RENDERFX_NONE);
            SetEntProp(client, Prop_Send, "m_nRenderMode", RENDER_NONE);
        }
    }
    
    
    
    new entity = MaxClients+1;
    
    while( (entity = FindEntityByClassname(entity, "weaponworldmodel")) != -1 )
    {
        SetEntProp(entity, Prop_Send, "m_nModelIndex", 0);
    }
}
forcevisible()
{
    for(new client = 1; client <= MaxClients; client++)
    {
        if(IsClientInGame(client)  && IsValidClient(client))
        {
            SetEntityRenderMode(client, RENDER_TRANSCOLOR);
            SetEntityRenderColor(client, 255, 255, 255, 255); 
        }
    }
}
public OnPostThinkPost(client)
{
    SetEntProp(client, Prop_Send, "m_iAddonBits", 0);
}  
public IsValidClient( client ) 
{ 
    if ( !( 1 <= client <= MaxClients ) || !IsClientInGame(client) ) 
        return false; 
    
    return true; 
}

These plugins works perfectly but almost every minute random players are disconecting form server with "No user logon" reason.

What I made wrong?

[Bacardi]

...don't sdkhook ALL players everytime when somebody spawn.
You create multiple hooks on players.

[4LiveTV]

Can You explain me how to do this?
I'm beginer :p Thanks

Originally Posted by Bacardi ...don't sdkhook ALL players everytime when somebody spawn. You create multiple hooks on players.

[8guawong]

Hook onclientputinserver

[Bacardi]

I try explain, english is unfortunally not my native language.

Spoiler

About SDKHook(ing), you should do this once on entity per sdkhook type.
UnHooking works automatically when entity not exist anymore.

You can also SDKUnHook manually but you need to know and keep track is that specific entity currently hooked.
Otherwise you get errors when failing unhooking. That would be another story.

That very bad example of yours, you SDKHook multiple times on same entity.
This will call same Callback function many times per code sequence.

And if we look how SDKHook_PostThinkPost works, this will call callback function as often as server tickrate.

If server tickrate 64 -> SDKHook_PostThinkPost callback function works 64 times per second.
In tickrate 128 -> callback function works 128 times per sec.

It would be good if you build own test server in your own computer rather than test on hosted server where are other players playing.

But...

Lets created code what SDKHook players and once.

PHP Code:

/*
 * Hide player weapons from body, this will work all the time.
*/

#include <sdkhooks>

// SM plugin loaded. 
public void OnPluginStart()
{

    // Loop all players who are currently on server.

    for(int i = 1; i <= MaxClients; i++)
    {
        // found player, forward client index to one of callbacks.
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}


// When player joined server
public void OnClientPutInServer(int client)
{
    // use sdkhook to this player
    SDKHookEx(client, SDKHook_PostThinkPost, PostThinkPost); 
}

// ...this will called as often as server tickrate
public void PostThinkPost(client)
{
    SetEntProp(client, Prop_Send, "m_iAddonBits",0); // Hide attached weapons from player body
} 


ok, we don't want this work 24/7.
Lets create admin command for enable and disable this weapon hide by using boolean variable.

#include <sdkhooks>

// global variable - boolean 1/0
bool my_toggle_onoff;

// SM plugin loaded. 
public void OnPluginStart()
{

	// Loop all players who are currently on server.

	for(int i = 1; i <= MaxClients; i++)
	{
		// found player, forward client index to one of callbacks.
		if(IsClientInGame(i)) OnClientPutInServer(i);
	}

	// Admin command
	RegAdminCmd("sm_test", test, ADMFLAG_GENERIC);
}


// Admin command callback
public Action test(int client, int args)
{
	// Toggle on/off variable
	my_toggle_onoff = !my_toggle_onoff;


	// Print in chat when player in game use admin command.
	if(client != 0) PrintToChat(client, "[SM] You turned this %s", my_toggle_onoff ? "ON":"OFF");

	// Print in server console when command used through server input
	if(client == 0) PrintToServer("[SM] You turned this %s", my_toggle_onoff ? "ON":"OFF");

	return Plugin_Handled;
}


// When player joined server
public void OnClientPutInServer(int client)
{
	// use sdkhook to this player
	SDKHookEx(client, SDKHook_PostThinkPost, PostThinkPost); 
}

// 
public void PostThinkPost(client)
{
	// When variable is false, don't continue code further
	if(!my_toggle_onoff) return;



	SetEntProp(client, Prop_Send, "m_iAddonBits",0); // Hide attached weapons from player body
}

Here rest of code

#include <sdkhooks>

// global variable - boolean 1/0
bool my_toggle_onoff;

// SM plugin loaded. 
public void OnPluginStart()
{

	// Loop all players who are currently on server.

	for(int i = 1; i <= MaxClients; i++)
	{
		// found player, forward client index to one of callbacks.
		if(IsClientInGame(i)) OnClientPutInServer(i);
	}


	// Admin command
	RegAdminCmd("sm_test", test, ADMFLAG_GENERIC);
}


// Admin command callback
public Action test(int client, int args)
{
	// Toggle on/off variable
	my_toggle_onoff = !my_toggle_onoff;


	// Print in chat when player in game use admin command.
	if(client != 0) PrintToChat(client, "[SM] You turned this %s", my_toggle_onoff ? "ON":"OFF");

	// Print in server console when command used through server input
	if(client == 0) PrintToServer("[SM] You turned this %s", my_toggle_onoff ? "ON":"OFF");

	UpdatePlayers();

	return Plugin_Handled;
}

void UpdatePlayers()
{

	for(int i = 1; i <= MaxClients; i++)
	{
		// skip client index which not have player
		if(!IsClientInGame(i)) continue;

		// Set visibility
		SetEntProp(i, Prop_Send, "m_nRenderMode", my_toggle_onoff ? RENDER_NONE:RENDER_NORMAL);
	}

}

// When player joined server
public void OnClientPutInServer(int client)
{
	// use sdkhook to this player
	SDKHookEx(client, SDKHook_PostThinkPost, PostThinkPost); 

	UpdatePlayers();
}

// 
public void PostThinkPost(client)
{
	// When variable is false, don't continue code further
	if(!my_toggle_onoff) return;



	SetEntProp(client, Prop_Send, "m_iAddonBits",0); // Hide attached weapons from player body
}

[Bacardi]

btw, if players game still crash or disconnect from server for this...

There could be some kind bug happen.
[CSGO] Client crash when m_iAddonBits used

I haven't occur to this...

[4LiveTV]

Very good work!
But there is a knife still visible. Can you make it invisible?

[Bacardi]

What game you are using ?

[supertimor]

Its a CS:GO, so we need to remember about weapon,knife / weapon, bayonet after sh1tty volvo update..

[Bacardi]

hm... when they have removed null/world model , doesn't exist anymore.
Now it will crash players game when set modelindex to 0.


Btw, how old your csgo game is ?

Because that example what I gave hide all weapons...