[MAJESTIC_SZ]

Still need this, please.

[Supremache]

Originally Posted by MAJESTIC_SZ Still need this, please.

Try, untested:

PHP Code:

#include <amxmodx>

#define PLUGIN "Every X Round/Kill get vip"
#define VERSION "1.1"
#define AUTHOR "Supremache"

#define VIP_FLAG ADMIN_LEVEL_H

new eRoundNum = 0;
new g_pCvarRounds
new bool:g_VipRound[33]
new szPlayerName[33][33]

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event("DeathMsg", "eDeath", "a")
    register_event("HLTV", "OnNewRound", "a", "1=0", "2=0");
    register_logevent( "eRoundEnd", 2, "1=Round_End" );
    
    g_pCvarRounds = register_cvar("vip_rounds", "2")
}    

public OnNewRound()
{
    if(eRoundNum == get_pcvar_num(g_pCvarRounds))
    {
        new iPlayers[32], iNum;
        get_players( iPlayers, iNum , "a");
        
        for( new i; i < iNum; i++ )
        {
            new iPlayer = GetRandomAlive(random_num(1, iPlayers[i]))
            
            if (g_VipRound[iPlayer])
            {
                set_user_flags(iPlayer, VIP_FLAG)
                client_print(iPlayer, print_chat, "[VIP Reward] Congratulations, You got free vip for one round.")
                client_print(0, print_chat, "[VIP Reward] %s got free vip for one round.", szPlayerName[iPlayer])
            }
        }
    }
    
    eRoundNum++
}

public eRoundEnd()
{
    new iPlayers[32], iNum;
    get_players( iPlayers, iNum);
        
    for( new i; i < iNum; i++ )
    {
        remove_user_flags(iPlayers[i], VIP_FLAG)
    }
}

public eDeath()
{
    new Attacker = read_data(1)
    new Victim = read_data(2)
        
    if(!is_user_connected(Attacker))
        return
        
    if(Victim != Attacker)
    {
        set_user_flags(Attacker, VIP_FLAG)
        client_print(0, print_chat, "[VIP Reward] Player %s got vip for killing %s", szPlayerName[Attacker], szPlayerName[Victim])
    }
    else if (!g_VipRound[Attacker])
    {
        remove_user_flags(Attacker, VIP_FLAG)
        client_print(0, print_chat, "[VIP Reward] Player %s lost his vip because killed by %s", szPlayerName[Attacker], szPlayerName[Victim])
    }
}
 
public client_putinserver(id)
{
    get_user_name( id, szPlayerName[id], charsmax(szPlayerName[]));
    
    // When player connecting to the server will get remove from vip access
    remove_user_flags(id, VIP_FLAG)
}

public client_disconnect(id)
{
    g_VipRound[id] = false;
}

GetRandomAlive(iPlayer)
{
    static iAlive
    iAlive = 0
    
    for (new i = 1; i <= get_maxplayers(); i++)
    {
        if (is_user_alive(i))
        iAlive++
        
        if (iAlive == iPlayer)
        return i;
    }
    
    return -1;
} 


[MAJESTIC_SZ]

Thanks for answering Supremache, but it does not work. It prints a message saying player X got vip for killing player Y everytime someone kills another player, but nothing hapens.
I just want the VIP status to change to another CT player every 2 or 3 rounds or when he gets killed.
The VIP player is a special character only playable on AS maps (assassin mode), the objective is to CTs get him to an escape zone and Ts must prevent him to reach it.
I remember playing it years ago with no problems, but now the VIP sticks on the same player the entire map and i dont know why. Maybe because some update valve did.

[Supremache]

Originally Posted by MAJESTIC_SZ Thanks for answering Supremache, but it does not work. It prints a message saying player X got vip for killing player Y everytime someone kills another player, but nothing hapens. I just want the VIP status to change to another CT player every 2 or 3 rounds or when he gets killed. The VIP player is a special character only playable on AS maps (assassin mode), the objective is to CTs get him to an escape zone and Ts must prevent him to reach it. I remember playing it years ago with no problems, but now the VIP sticks on the same player the entire map and i dont know why. Maybe because some update valve did.

Check #12

[HamletEagle]

Originally Posted by Supremache Check #12

He isn't talking about "vip" as in admin. He is talking about the vip that spawns in the as map, the one CT's have to protect or they lose.

[Supremache]

Originally Posted by HamletEagle He isn't talking about "vip" as in admin. He is talking about the vip that spawns in the as map, the one CT's have to protect or they lose.

Ooh, i understood

[MAJESTIC_SZ]

Originally Posted by Supremache Ooh, i understood

Aleluia
So, can you do it?
I warn you, i use REHLDS +amx 1.9

Originally Posted by HamletEagle He isn't talking about "vip" as in admin. He is talking about the vip that spawns in the as map, the one CT's have to protect or they lose.

Cmon Hamlet, help me out please

[HamletEagle]

Please follow the rules and don't double post or bump your topic. If someone wants to help then they will help. Spamming isn't going to accomplish anything.

[Celena Luna]

PHP Code:

#include <amxmodx>
#include <reapi>

new bool:g_AlreadyVIP[33]

public plugin_init()
{
    register_plugin("Random VIP", "1.0", "Celena Luna")
    RegisterHookChain(RG_CBasePlayer_MakeVIP, "CBasePlayer_MakeVIP")
}

public client_disconnect(id)
{
    g_AlreadyVIP[id] = false
}

public CBasePlayer_MakeVIP(id)
{
    new vip = GetRandomPlayer() //Get random player that haven't been being VIP once

    if(is_user_connected(vip))
    {
        //Set him as VIP
        rg_set_user_model(vip, "vip");
        set_member(vip, m_iTeam, TEAM_CT);
        set_member(vip, m_bIsVIP, true);
        set_member_game(m_pVIP, vip)
        set_member_game(m_iConsecutiveVIP, 1);
        g_AlreadyVIP[vip] = true;
    }
    return HC_SUPERCEDE;
}

public GetRandomPlayer()
{
    new players[32], num, iPlayer 
    new RandomList[33], j = 0
    new SelectedPlayer

    //Get all player from alive CT 
    get_players(players, num, "ae", "CT")

    for(new i=0; i < num; i++)
    {
        iPlayer = players[i]
        if(!g_AlreadyVIP[iPlayer]) //if he/she haven't been being VIP once
        {
            RandomList[j] = iPlayer //Put in RandomList
            j++
        }    
    }

    if(j <= 0) //If all CT have been VIP once
    {
        SelectedPlayer = players[random_num(0, num)] //Select 1 random player in CT to become vip

        //Then reset all player VIP counter
        for(new i=0; i < num; i++)
        {
            iPlayer = players[i]
            g_AlreadyVIP[iPlayer] = false 
        }
    }
    else //If there is more than 1 player haven't been VIP once
    {
        SelectedPlayer = RandomList[random_num(0, j)] //Select Random player from the list to become VIP
    }

    return SelectedPlayer    
} 


I found this one on Dev-CS
It basically block the original MakeVIP functions and do it is own.
Edit: find_player_ex is not random, I will make an edit later with get_players
Edit2: Code updated.

[Celena Luna]

I updated the code above. I also add to make every player from CT side can be VIP at least one.
If you don't want it, just replace this GetRandomPlayer() part:

Spoiler

PHP Code:

public GetRandomPlayer()
{
    new players[32], num
    new SelectedPlayer

    //Get all player from alive CT 
    get_players(players, num, "ae", "CT")

    SelectedPlayer = players[random_num(0, num)] //Select 1 random player in CT to become vip


    return SelectedPlayer    
}