[ThatKidWhoGames]

Just want to make sure my code here won't cause any memory leaks:

PHP Code:

#pragma semicolon 1
#define PLUGIN_VERSION "1.0"

#include <shop>
#include <sourcemod>
#include <morecolors>

Handle hAnswerTimer;
int iAnswer, iPoints;
bool bActive;

public Plugin myinfo = {
    name         = "[TF2] Shop! - Math Module",
    author         = "Sgt. Gremulock",
    description = "Shop/store math module.",
    version     = PLUGIN_VERSION,
    url         = "sourcemod.net"
};

public void OnPluginStart()
{
    CreateTimer(90.0, Timer_Problem, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);

    AddCommandListener(Command_Say, "say");
    AddCommandListener(Command_Say, "say_team");
}

public Action Command_Say(int client, const char[] command, int argc)
{
    if (bActive && argc == 1)
    {
        char arg1[32];
        GetCmdArg(1, arg1, sizeof(arg1));

        if (StringToInt(arg1) == iAnswer)
        {
            CPrintToChatAll("%s {lightgreen}%N{default} answered the question correctly. The answer was {lightgreen}%i{default}.", CTAG, client, iAnswer);
            Shop_AddPoints(client, iPoints);

            if (hAnswerTimer != null)
            {
                KillTimer(hAnswerTimer);
                hAnswerTimer = null;
            }

            ResetValues();
        }
    }
}

public Action Timer_Problem(Handle timer, any data)
{
    bActive = true;
    iPoints = GetRandomInt(1, 10);
    int one = GetRandomInt(1, 100), two = GetRandomInt(1, 100), operation = GetRandomInt(1, 2);

    char buffer[256];

    switch (operation)
    {
        case 1:
        {
            buffer     = "+";
            iAnswer = one + two;
        }

        case 2:
        {
            buffer     = "-";
            iAnswer = one - two;
        }
    }

    Format(buffer, sizeof(buffer), "%s Math problem for {lightgreen}%i {default}point(s): What is {lightgreen}%i {red}%s {lightgreen}%i{default}?", CTAG, iPoints, one, buffer, two);
    CPrintToChatAll(buffer);

    hAnswerTimer = CreateTimer(15.0, Timer_AnswerTimer, _, TIMER_FLAG_NO_MAPCHANGE);
}

public Action Timer_AnswerTimer(Handle timer, any data)
{
    CPrintToChatAll("%s Time is up! The correct answer was {lightgreen}%i{default}.", CTAG, iAnswer);
    ResetValues();
    hAnswerTimer = null;
}

void ResetValues()
{
    bActive         = false;
    iAnswer         = 0;
    iPoints         = 0;
} 


Thanks,
Grant

EDIT: Out of curiosity, is setting an array = null the same as closing its handle or deleting it?

[Fyren]

Originally Posted by ThatKidWhoGames Just want to make sure my code here won't cause any memory leaks:

Make sure every time you create a handle, it will get closed. You have to consider every code path.

You can use sm_dump_handles as a rough way to check. Run your plugin for a long time, see if the number of handles is the expected value or if it's ballooning.

Originally Posted by ThatKidWhoGames Out of curiosity, is setting an array = null the same as closing its handle or deleting it?

No.

[ThatKidWhoGames]

Originally Posted by Fyren Make sure every time you create a handle, it will get closed. You have to consider every code path. You can use sm_dump_handles as a rough way to check. Run your plugin for a long time, see if the number of handles is the expected value or if it's ballooning. No.

Thank you very much,
Grant

[cravenge]

Originally Posted by ThatKidWhoGames EDIT: Out of curiosity, is setting an array = null the same as closing its handle or deleting it?

Clearing arrays is much better.

[pride95]

why are you setting TIMER_FLAG_NO_MAPCHANGE on a timer in OnPluginStart?
use delete hAnswerTimer; instead of killtimer and hAnswerTimer = null;
also check in OnMapEnd if hAnswerTimer != null;

[Visual77]

I'd reset hAnswerTimer to null on public void OnMapStart()

Because TIMER_FLAG_NO_MAPCHANGE will kill the timer, but it will not reset the timer handle back to null.

edit: pride95 beat me to it.

[pride95]

Originally Posted by Visual77 I'd reset hAnswerTimer to null on public void OnMapStart() Because TIMER_FLAG_NO_MAPCHANGE will kill the timer, but it will not reset the timer handle back to null. edit: pride95 beat me to it.

TIMER_FLAG_NO_MAPCHANGE its useless in OnPluginStart();
if the plugin is unloaded, the timer is cleared automatically. so you dont need this flag.
OnPluginStart is called once, not like OnMapStart() which is called on every map.

delete the timer OnMapEnd, don't send more memory when the map is changed.

[Visual77]

Originally Posted by pride95 TIMER_FLAG_NO_MAPCHANGE its useless in OnPluginStart(); if the plugin is unloaded, the timer is cleared automatically. so you dont need this flag. OnPluginStart is called once, not like OnMapStart() which is called on every map. delete the timer OnMapEnd, don't send more memory when the map is changed.

We are talking about different timers. Yes, there's clearly a mistake in OnPluginStart() too. (TIMER_FLAG_NOMAPCHANGE is not suitable there), however on the other timer, it is but he will
then have to set both the timer handle to null and call ResetValues() in OnMapStart() for those rare cases where the timer is destroyed automaticly when the map changes.

[ThatKidWhoGames]

Thanks for the help. So by my understanding, this should fix all the stuff you guys talked about?

PHP Code:

#pragma semicolon 1
#define PLUGIN_VERSION "1.0"

#include <shop>
#include <sourcemod>
#include <morecolors>

Handle hAnswerTimer;
int iAnswer, iPoints;
bool bActive;

public Plugin myinfo = {
    name         = "[TF2] Shop! - Math Module",
    author         = "Sgt. Gremulock",
    description = "Shop/store math module.",
    version     = PLUGIN_VERSION,
    url         = "grem-co.com"
};

public void OnPluginStart()
{
    CreateTimer(90.0, Timer_Problem, _, TIMER_REPEAT);

    AddCommandListener(Command_Say, "say");
    AddCommandListener(Command_Say, "say_team");
}

public void OnMapStart()
{
    ResetValues();
    hAnswerTimer = null;
}

public Action Command_Say(int client, const char[] command, int argc)
{
    if (bActive && argc == 1)
    {
        char arg1[32];
        GetCmdArg(1, arg1, sizeof(arg1));

        if (StringToInt(arg1) == iAnswer)
        {
            CPrintToChatAll("%s {lightgreen}%N{default} answered the question correctly. The answer was {lightgreen}%i{default}.", CTAG, client, iAnswer);
            Shop_AddPoints(client, iPoints);

            if (hAnswerTimer != null)
                        {
                               KillTimer(hAnswerTimer);
                               hAnswerTimer = null;
                        }

            ResetValues();
        }
    }
}

public Action Timer_Problem(Handle timer, any data)
{
    bActive = true;
    iPoints = GetRandomInt(1, 10);
    int one = GetRandomInt(1, 100), two = GetRandomInt(1, 100), operation = GetRandomInt(1, 2);

    char buffer[256];

    switch (operation)
    {
        case 1:
        {
            buffer     = "+";
            iAnswer = one + two;
        }

        case 2:
        {
            buffer     = "-";
            iAnswer = one - two;
        }
    }

    Format(buffer, sizeof(buffer), "%s Math problem for {lightgreen}%i {default}point(s): What is {lightgreen}%i {red}%s {lightgreen}%i{default}?", CTAG, iPoints, one, buffer, two);
    CPrintToChatAll(buffer);

    hAnswerTimer = CreateTimer(15.0, Timer_AnswerTimer, _, TIMER_FLAG_NO_MAPCHANGE);
}

public Action Timer_AnswerTimer(Handle timer, any data)
{
    CPrintToChatAll("%s Time is up! The correct answer was {lightgreen}%i{default}.", CTAG, iAnswer);
    ResetValues();
    hAnswerTimer = null;
}

void ResetValues()
{
    bActive         = false;
    iAnswer         = 0;
    iPoints         = 0;
} 


Thanks,
Grant