[lazarev]

PHP Code:

        new Float: vec2LOS[2];
        new Float: vecForward[3];
        new Float: vecForward2D[2];

        velocity_by_aim( iAttacker, 1, vecForward );
      
        xs_vec_make2d( vecForward, vec2LOS );
        xs_vec_normalize( vec2LOS, vec2LOS );
    
        pev( iVictim, pev_angles, vecForward );
        engfunc( EngFunc_MakeVectors, vecForward );
        global_get( glb_v_forward, vecForward );
        
        xs_vec_make2d( vecForward, vecForward2D );
        if( xs_vec_dot( vec2LOS, vecForward2D ) > 0.8 )
        {
           // iAttacker has backstabbed iVictim
        } 


Credits to: Arkshine for CS-SDK and micapat for CKnife::Stab fix in CS-SDK

[ConnorMcLeod]

You can optimize this :

PHP Code:

        pev( iAttacker, pev_v_angle, vecForward );
        engfunc( EngFunc_MakeVectors, vecForward );
        global_get( glb_v_forward, vecForward ); 


and this

PHP Code:

        pev( iVictim, pev_angles, vecForward );
        engfunc( EngFunc_MakeVectors, vecForward );
        global_get( glb_v_forward, vecForward ); 


Doing this :

PHP Code:

velocity_by_aim(iAttacker, 1, vecForward ); 


and this :

PHP Code:

velocity_by_aim(iVictim, 1, vecForward ); 


[lazarev]

@ConnorMcLeod - Are you sure that I can use velocity_by_aim() for victim since it grabs pev_v_angle parameter but not pev_angles? Thanks for the tip though

[ConnorMcLeod]

You are right, hadn't see this.

Anyway, rather than MakeAngle + global_get, you should use anglevectors

PHP Code:

angle_vector(vecForward, ANGLEVECTOR_FORWARD, vecForward); 


You save 1 native call.
Not sure if you can use same variable though, should be ok.


More generally, use angle_vector when you only need 1 dimension/axe/call how you want, and use EngFunc_AngleVectors when you need 2 or 3 dimensions, then you don't need to use global_get.

[Leon M.]

I'm using another solution to detect if someone got backstabbed and it worked proper. But take a look below. Keep in mind that I've created this solutions many months ago, so I can't remember on every single damage

Spoiler

Edit: Added server messages to check for other damage values.

PHP Code:

#include <amxmodx>
#include <hamsandwich>

public plugin_init(){
    RegisterHam(Ham_TakeDamage, "player", "ham_takedamage_player", 0)
}

public ham_takedamage_player(iVictim, iInflictor, iAttacker, Float:fDamage, iDmgBits){

    // Damage taken through a grenade or c4
    if (iInflictor != iAttacker) return HAM_IGNORED

    if (get_user_weapon(iAttacker) == CSW_KNIFE){
        switch(fDamage){

            // You deal always same damage. I can't remember at all but you can try it by yourself.
            // Also note that it depends on the hitzone. A backstab on enemies feet will return
            // another damage than on his back. A backstab in enemies 'back' will do 195 damage.
            // Suggested code by OP will be fine if you don't care about the hitzone otherwise you
            // could just add a simply check for the the hitzone to suggested code or just use this code.
            case 15.0: client_print(0, print_chat, "+attack: front, side, back")
            case 65.0: client_print(0, print_chat, "+attack2: front, side")
            case 195.0: client_print(0, print_chat, "+attack2: back")
            default: {

                new iHitZone, iTarget
                get_user_aiming(iAttacker, iTarget, iHitZone)
                if (iTarget == iVictim){
                    switch(iHitZone){
                        case HIT_GENERIC: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_GENERIC", fDamage)
                        case HIT_HEAD: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_HEAD", fDamage)
                        case HIT_CHEST: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_CHEST", fDamage)
                        case HIT_STOMACH: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_STOMACH", fDamage)
                        case HIT_LEFTARM: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_LEFTARM", fDamage)
                        case HIT_RIGHTARM: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_RIGHTARM", fDamage)
                        case HIT_LEFTLEG: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_LEFTLEG", fDamage)
                        case HIT_RIGHTLEG: client_print(0, print_chat, "Damage: %f, Hitzone: HIT_RIGHTLEG", fDamage)
                    }
                }
            }
        }
    }
    return HAM_IGNORED
} 


[Bos93]

if (g_iPlayerWeapon[iAttacker] == CSW_KNIFE)

may be get_user_weapon?

[Leon M.]

Oh yes, get_user_weapon will work too. I just needed a global var since I'm alter some things in client_PreThink(id) depending on the weapon ;)

Edited my suggestion and added server messages if you want to hook other events

[Backstabnoob]

get_user_aiming is bad to use, because the attacker doesn't need to aim at the hitbox (if you're really close to the enemy, you will hit them even when aiming next to them)

[Leon M.]

Doesn't matter much for testing purpose

[fl0werD]

PHP Code:

GetCenter(iEntity, vecSrc);
GetCenter(iPlayer, vecEnd);
    
xs_vec_sub(vecEnd, vecSrc, vecEnd);
xs_vec_normalize(vecEnd, vecEnd);

pev(iEntity, pev_angles, vecAngle);
engfunc(EngFunc_MakeVectors, vecAngle);

global_get(glb_v_forward, vecForward);
xs_vec_mul_scalar(vecEnd, -1.0, vecEnd);
               
if (xs_vec_dot(vecForward, vecEnd) > 0.3)
{
    flDamage = WEAPON_DAMAGE_BACK;
} 


PHP Code:

GetCenter(iEntity, Float: vecSrc[3])
{
    new Float: vecAbsMax[3], Float: vecAbsMin[3];

    pev(iEntity, pev_absmax, vecAbsMax)
    pev(iEntity, pev_absmin, vecAbsMin)

    xs_vec_add(vecAbsMax, vecAbsMin, vecSrc)
    xs_vec_mul_scalar(vecSrc, 0.5, vecSrc)
} 


By KORD_12.7