[Deidara]

Hello, I have this.
It's a hud message who appears left or right depends of the players team.
I put the up-down possition random but ocasionally they overwrite, I don't know how to explain it so I'll attach a screenshot.

The first image - 1 is what happend when two or more huds are displayed - look at the left side, up. [ http://steamcommunity.com/id/eliara/...74420292407965 ]
The second image is how I want them to be, when two or more messages are generated I want them under each other to look nice. [ http://steamcommunity.com/id/eliara/...74420292407965 ]

Screens are on steam cloud images gallery because I can't upload them, they are too large.

Code:

PHP Code:

announce(killer, level)
{
    new streak = get_streak()

    if (streak&1)
    {
        new name[32];
        new PositionYforCT = random_num(0.15,0.70)
        new PositionXforT = random_num(0.15,0.70)

           get_user_name(killer, name, 32);
          if ( cs_get_user_team(killer) == CS_TEAM_CT )
            {
                set_dhudmessage(0, 80, 150, 0.03, PositionYforCT, 2, 0.02, 6.0, 0.01, 0.1, 2);
                show_dhudmessage(0, stkmessages[level], name);
            }
        else
            {
                set_dhudmessage(205, 92, 92, 0.80, PositionXforT, 2, 0.02, 6.0, 0.01, 0.1, 2);
                show_dhudmessage(0, stkmessages[level], name);
            }
    }

    if (streak&2)
    {
            client_cmd(0, "spk %s", stksounds[level]);
    }
} 


Sorry if this topic doesn't look attractive but I'm not english and I don't know it very well.
I hope there's the right section to ask help.

[Bugsy]

You can use sync huds and clear it before you show

PHP Code:

//plugin_init()
g_HUDSyncObj = CreateHudSyncObj();

//Show HUD
ClearSyncHud( 0 , g_HUDSyncObj );
set_hudmessage( 255 , 255 , 0 , -1.0 , 0.25 , .holdtime=1.0 );
ShowSyncHudMsg( 0 , g_HUDSyncObj , "Test" ); 


[Deidara]

Hello.
Thanks for reply.
Is there a way to make them all show but one after each other instead of making them disappear? I want all of the to show but in order, I don't want to erase them when another is pop up.

[Bugsy]

If you want them all there but not overwriting each other, change the X/Y coordinates in set_hudmessage().

[Deidara]

How can I put the conditions to not overwrite but in the same time the up-down possition to be random? Or manually set it to be under each other?

[Bugsy]

If you want random without one overlapping another you will need to do work to make sure one is not over another, whether partially or totaly.

Instead of random, I would define an array of 5-10 origins and loop through it. Make this set ones that you know will be ok if used one after the other.

[Deidara]

Can you show me an example of this array please? I'm gonna try it.

[Bugsy]

You can make them go down in a line, a circle, random, or anything you want. You just need to fill the array with the X,Y coords.

PHP Code:

#include <amxmodx>

enum HUDPos
{
    Float:HUD_X,
    Float:HUD_Y
}

new const Float:HUDCoords[][ HUDPos ] = 
{
    { 0.05 , 0.24 },
    { 0.05 , 0.28 },
    { 0.05 , 0.32 },
    { 0.05 , 0.36 },
    { 0.05 , 0.40 },                
    { 0.05 , 0.44 },                
    { 0.05 , 0.48 },    
    { 0.05 , 0.52 }
}
    
public plugin_init()
{
    register_clcmd( "say test" , "TestCmd" );
}

public TestCmd( id )
{
    set_task( 1.0 , "ShowHUD" , .flags="b" );
}

public ShowHUD()
{
    static iHUDIndex;

    set_hudmessage( 255 , 255 , 255 , HUDCoords[ iHUDIndex ][ HUD_X ] , HUDCoords[ iHUDIndex ][ HUD_Y ] , .holdtime=1.0 );
    show_hudmessage( 0 , "Test hud #%d" , iHUDIndex );
    
    if ( ++iHUDIndex == sizeof( HUDCoords ) )
        iHUDIndex = 0;
} 


[Deidara]

Thanks for you time. That really helps me and I managed to make it work.