[DavidLin]

When entity is tossed up ( above player ) the server crashes without any errors, when I changed entity solid type to _TRIGGER it works fine but I can't pick it up or do damage to it.

PHP Code:

public throwstick( id ) {
        new Float:Origin[ 3 ], Float:Velocity[ 3 ], Float:Angles[ 3 ], Float:FAngles[ 3 ];
        entity_get_vector( id, EV_VEC_origin, Origin );
        velocity_by_aim( id, 64, Angles )
        vector_to_angle( Angles, FAngles );

        FAngles[ 0 ] = 0.0;
        Origin[ 0 ] += Angles[ 0 ];
        Origin[ 1 ] += Angles[ 1 ];
        Origin[ 2 ] += Angles[ 2 ];

        new entity_stick = create_entity( "info_target" );
        entity_set_string( entity_stick, EV_SZ_classname, entity_name );
        entity_set_vector( entity_stick, EV_VEC_angles, FAngles );
        entity_set_int( entity_stick, EV_INT_solid, SOLID_BBOX );
        entity_set_int( entity_stick, EV_INT_movetype, MOVETYPE_TOSS );
        entity_set_origin( entity_stick, Origin );
        entity_set_model( entity_stick, gModel );
        entity_set_size( entity_stick, minModel, maxModel );
        entity_set_float( entity_stick, EV_FL_takedamage, 1.0 );
        entity_set_float( entity_stick, EV_FL_gravity, 0.8 ); 
        entity_set_float( entity_stick, EV_FL_health, get_pcvar_float( stick_health ) );
        set_pev( entity_stick, pev_iuser2, id );

        entity_set_int( entity_stick, EV_INT_renderfx, kRenderFxGlowShell );
        entity_set_vector( entity_stick, EV_VEC_rendercolor, Float:{ 221.0, 173.0, 237.0 } );

        velocity_by_aim( id, 600, Velocity );
        entity_set_vector( entity_stick, EV_VEC_velocity, Velocity );
        has_stick[ id ] = false;
} 


[DavidLin]

So I discovered if an entity was thrown above it takes damage when it falls and this crashes server because of fall damage, is it possible to disable fall damage for an entity ?

EDIT: it crashes from knife kill too

[Hunter4all]

ok so i have the same problem too..

Server crashes when an entity is killed with a knife.
but with any other weapons it doesnt crash.
Can someone explain me why ?

[Whitez]

Register TakeDamage and check for entity class name
The code to disable damage from falling can be found somewhere around the forum

[SpannerSpammer]

The problem when you create a custom entity in goldsrc and enable takedamage is
that the engine will automatically kill the entity when it's health is less than zero.

You DO NOT want this to happen, you want to fully control when your
custom entity gets removed. To do this you need to set a health mask with
a high enough value that no weapon/explosive in-game can easily destroy it.

#define HEALTH_MASK  1000000.0
.
.
entity_set_float( entity_stick, EV_FL_health, HEALTH_MASK );

Then, check the health in some function, usually it's think function or a hooked
Takedamage function and then evaluate whether or not you need to kill the entity.
If you do, then perform whatever code cleanup required and then kill the entity.

public StickThink( ent )
{
    static Float:flHealth;
    flHealth = get_pcvar_float( stick_health );
    if ( flHealth < 1.0 ) flHealth = 1.0;       // idiot proof your HP value
    if ( flHealth > 500.0 ) flHealth = 500.0;

    if ( entity_get_float( ent, EV_FL_health ) <= (HEALTH_MASK - flHealth) )
    {
        // do any code cleanup here
        //
        // new id = entity_get_int( ent, EV_INT_iuser2 );
        // if ( SomeIsValidPlayerIDFunction(id) )   
        //        client_print( id, print_chat, "Your stick was destroyed" );

        remove_entity( ent );
        return PLUGIN_CONTINUE;
    }
    .
    .
    .
    return PLUGIN_CONTINUE;
}

One last thing: If you use CVARs or load settings from a configuration file, don't
plug these values directly into your code. You need to idiot proof these values
before plugging them in, because an invalid setting can sometimes have unpredictable
results, like crashing the server.