[ColaSola]

Hello everybody take a look there please: I compiled the plugin, Running in console but is not doing anything.The plugin should work like that: After i change the map everybody will get a message like: We still waiting other players. And no one have the right to move.Only for 15 seconds after the round will restart. Thanks!

PHP Code:

#include <amxmodx>
#include <dhudmessage> 

new bool:g_firstround

new restart_seconds = 20;
new g_rounds = 0;

public plugin_init()
{
register_plugin("Waiting", "2.0", "")

register_event("HLTV", "new_round", "a", "1=0", "2=0");
register_logevent("end_round", 2, "1=Round_End");
register_logevent("round_start", 2, "1=Round_Start")

set_task(1.0, "first_round", _, _, _, "a", restart_seconds);
}

public new_round()
{
if(g_firstround) 
{
set_hudmessage(random(255), random(255), random(255), -1.0, 0.15, 1, 5.1, 5.0)
ShowSyncHudMsg(0, CreateHudSyncObj(), "We still wait other players.") 
return;
}
}




public first_round()
{
restart_seconds--
if(restart_seconds > 0)
g_firstround = true
else
{
server_cmd("sv_restart 1");
set_task(2.5, "restart_again_sorry");
g_firstround = false
return;
}
set_hudmessage(85, 255, 170, 0.0, 0.19, 1, 1.1, 1.0)
show_hudmessage(0, "We still wait other players.^n%d secund%s ramas%s.", restart_seconds, restart_seconds < 2 ? "a" : "e", restart_seconds < 2 ? "a" : "e")
}

public restart_again_sorry()
{
server_cmd("sv_restart 1");
}

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ ansicpg1252\\ deff0\\ deflang1033{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ f0\\ fs16 \n\\ par }
*/ 


[siriusmd99]

It should work like this :
After first round is triggered, you wont be able to move 15 seconds and you will se a hudmessage "We still wait other players.", after that round will restart and players will be able to move.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

new const Float:TIME = 15.0

new bool:g_firstround;
new bool:g_canMove;
new g_syncmsg;

public plugin_init()
{
register_plugin("Waiting For Players", "1.0", "Alliedmods")

register_event("HLTV", "new_round", "a", "1=0", "2=0");
RegisterHam( Ham_Spawn, "player", "Player_Freeze", 1 ); 
g_syncmsg = CreateHudSyncObj();
}

public new_round()
{
if(!g_firstround) 
{
set_task(TIME, "Restart_Round")
set_hudmessage(random(255), random(255), random(255), -1.0, 0.15, 1, 5.1, TIME)
ShowSyncHudMsg(0, g_syncmsg, "We still wait other players.")
g_firstround = true; 
}
}

public Player_Freeze(id){

 if(is_user_alive(id) && !g_canMove)
 {
    new iFlags = pev(id, pev_flags) 
    if( ~iFlags & FL_FROZEN ) 
    { 
     set_pev(id, pev_flags, iFlags | FL_FROZEN) 
    } 
 }
}

public Restart_Round(){
  g_canMove = true;
  server_cmd("sv_restartround 1") 
} 


[siriusmd99]

You said me in PM to make it with dhudmessage insead of synchudmsg, here we go :

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <dhudmessage>
#include <hamsandwich>

new const Float:TIME = 15.0

new bool:g_firstround;
new bool:g_canMove;

public plugin_init()
{
register_plugin("Waiting For Players", "1.0", "Alliedmods")

register_event("HLTV", "new_round", "a", "1=0", "2=0");
RegisterHam( Ham_Spawn, "player", "Player_Freeze", 1 ); 
}

public new_round()
{
if(!g_firstround) 
{
set_task(TIME, "Restart_Round")
set_dhudmessage(random(255), random(255), random(255), -1.0, 0.15, 1, 5.1, TIME)
show_dhudmessage(0, "We still wait other players.")
g_firstround = true; 
}
}

public Player_Freeze(id){

 if(is_user_alive(id) && !g_canMove)
 {
    new iFlags = pev(id, pev_flags) 
    if( ~iFlags & FL_FROZEN ) 
    { 
     set_pev(id, pev_flags, iFlags | FL_FROZEN) 
    } 
 }
}

public Restart_Round(){
  g_canMove = true;
  server_cmd("sv_restartround 1") 
} 


[ColaSola]

Thanks a lot!

[ColaSola]

Oh i forget something how can i add in this message a timer like "We still wait other players 15s/14s/13s"

[siriusmd99]

OK, you want the same colour message will be every second ?

For example I generate random colour just one time and after I set the same colour for every second to show timer or every second different colours?

[ColaSola]

the color like how is in the dhud.

PHP Code:

set_dhudmessage(random(255), random(255), random(255), -1.0, 0.15, 1, 5.1, TIME) 


[siriusmd99]

Try :
I made also a cvar to set time , amx_waiting_time , you can set it from amxx.cfg to what value do you want.
Also , blocked the message "Game will restart in...", because it will be printed onto the hud message and it will look bad.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <dhudmessage>
#include <hamsandwich>

new g_time;
new bool:g_firstround;
new bool:g_canMove;
new g_counter;

public plugin_init()
{
register_plugin("Waiting For Players", "1.0", "Alliedmods")
g_time = register_cvar("amx_waiting_time", "15")
register_message(get_user_msgid("TextMsg"), "hook_TextMsg")
register_event("HLTV", "new_round", "a", "1=0", "2=0");
RegisterHam( Ham_Spawn, "player", "Player_Freeze", 1 ); 
}

public new_round()
{
if(!g_firstround) 
{
g_counter = get_pcvar_num(g_time)
new colours[3];
for(new i; i < sizeof(colours); i++)
  colours[i] = random(255);
  
set_dhudmessage(colours[0], colours[1], colours[2], -1.0, 0.15, 1, 5.1, 0.9)
show_dhudmessage(0, "We are still waiting other players... ( %d seconds )", g_counter)
set_task(1.0, "Restart_Round", _, colours, 3,"a", g_counter)
g_counter--;
g_firstround = true; 
}
}

public hook_TextMsg(msgid, msgdest, msgargs) {
    new message[32]
    get_msg_arg_string(2, message, 31) 
    
    if (!g_canMove && equal(message, "#Game_will_restart_in"))
        return PLUGIN_HANDLED 
    
    return PLUGIN_CONTINUE 
}

public Player_Freeze(id){

 if(is_user_alive(id) && !g_canMove)
 {
    new iFlags = pev(id, pev_flags) 
    if( ~iFlags & FL_FROZEN ) 
    { 
     set_pev(id, pev_flags, iFlags | FL_FROZEN) 
    } 
 }
}

public Restart_Round(arg[]){
  if(g_counter == 1)
  {
  server_cmd("sv_restartround 1"); 
  }
  else
  {
  if(g_counter == 0){
  g_canMove = true;
  return;
  }
  }
  
  set_dhudmessage(arg[0], arg[1], arg[2], -1.0, 0.15, 1, 5.1, 0.9)
  show_dhudmessage(0, "We are still waiting other players... ( %d seconds )", g_counter)
  g_counter--;
} 


[ColaSola]

Perfectly working thanks!