[Dr.Mohammad]

hi guys,
how i can create vote menu and only show for CT or T team??
for example vote menu for pause the game

sorry for bad speak english

[adma]

1. Build your Menu
2. Create array with only CT/T
3. Use VoteMenu to send vote to only the clients in the array

PHP Code:

#define CS_TEAM_NONE        0    /**< No team yet. */
#define CS_TEAM_SPECTATOR    1    /**< Spectators. */
#define CS_TEAM_T             2    /**< Terrorists. */
#define CS_TEAM_CT            3    /**< Counter-Terrorists. */

// Build your menu
Menu hMenu = new Menu(MenuHandler_Callback);
hMenu.SetTitle("Title");
hMenu.AddItem("item1", "Item 1");
hMenu.AddItem("item2", "Item 2");

// Build array of CT/T clients
int iNumClients;
int[] iClients = new int[MaxClients];

for (int i = 1; i <= MaxClients; ++i) {
  if (!IsClientInGame(i)) continue;
  
  if (GetClientTeam(i) == CS_TEAM_T) {
    iClients[iNumClients++] = i;
  }
}

// Send vote menu to the clients in the array we just built
VoteMenu(hMenu, iClients, iNumClients, MENU_TIME_FOREVER);

// Callback
public int MenuHandler_Callback(Menu hMenu, MenuAction action, int iParam1, int iParam2) {
  if (action == MenuAction_End) delete hMenu;

  // Your own logic

  return 0;
} 


[Dr.Mohammad]

Originally Posted by adma 1. Build your Menu 2. Create array with only CT/T 3. Use VoteMenu to send vote to only the clients in the array PHP Code: #define CS_TEAM_NONE        0    /**< No team yet. */ #define CS_TEAM_SPECTATOR    1    /**< Spectators. */ #define CS_TEAM_T             2    /**< Terrorists. */ #define CS_TEAM_CT            3    /**< Counter-Terrorists. */ // Build your menu Menu hMenu = new Menu(MenuHandler_Callback); hMenu.SetTitle("Title"); hMenu.AddItem("item1", "Item 1"); hMenu.AddItem("item2", "Item 2"); // Build array of CT/T clients int iNumClients; int[] iClients = new int[MaxClients]; for (int i = 1; i <= MaxClients; ++i) {   if (!IsClientInGame(i)) continue;      if (GetClientTeam(i) == CS_TEAM_T) {     iClients[iNumClients++] = i;   } } // Send vote menu to the clients in the array we just built VoteMenu(hMenu, iClients, iNumClients, MENU_TIME_FOREVER); // Callback public int MenuHandler_Callback(Menu hMenu, MenuAction action, int iParam1, int iParam2) {   if (action == MenuAction_End) delete hMenu;   // Your own logic   return 0; }

thank you for help.

this code true??

PHP Code:

void VoteMenuPause(int clinet)
{
    Menu hMenu = new Menu(VoteMenuPauseHandler_Callback);
    char Char_BufferText[32], Char_RequesterName[64] = GetClientName(client);
    int Int_Team = GetClientTeam(client);
    Format(Char_BufferText, sizeof(Char_BufferText), "%s Requested for pause [2 minutes]?", Char_RequesterName);
    hMenu.SetTitle(Char_BufferText);
    hMenu.AddItem("y", "Yes");
    hMenu.AddItem("n", "No");
    
    int iNumClients;
    int[] iClients = new int[MaxClients];
    for(int i = 1; i <= MaxClients; ++i)
    {
        if (!IsClientInGame(i)) continue;
        if (GetClientTeam(i) == Int_Team)
        {
            iClients[iNumClients++] = i;
        }
    }
    
    Bool_VotePause = true;
    VoteMenu(hMenu, iClients, iNumClients, MENU_TIME_FOREVER);
}

public int VoteMenuPauseHandler_Callback(Menu hMenu, MenuAction action, int iParam1, int iParam2)
{
    if(action == MenuAction_End)
    {
        /* This is called after VoteEnd */
        delete hMenu;
    }
    else if(action == MenuAction_VoteEnd)
    {
        Bool_VotePause = false;
        
        /* 0=yes, 1=no */
        if(param1 == 0)
        {
            ServerCommand("mp_pause_match");
        }
    }
} 


[adma]

This line is wrong:

PHP Code:

char Char_BufferText[32], Char_RequesterName[64] = GetClientName(client); 


"Strings" are just arrays of characters with a 0 as the last element. For example, "hello" is the same as {'h', 'e', 'l', 'l', 'o', 0}. Therefore, functions like GetClientName cannot actual return a "string", because you cannot return arrays in Sourcepawn. Instead, Sourcepawn alters arrays that are passed to the function. So instead of your code, you would do:

PHP Code:

char Char_BufferText[32], Char_RequesterName[32];
GetClientName(client, Char_RequesterName, sizeof(Char_RequesterName)); 


You are passing the char array Char_RequesterName into GetClientName() which then gets modified, much like Char_BufferText when you use Format().

[Dr.Mohammad]

Originally Posted by adma This line is wrong: PHP Code: char Char_BufferText[32], Char_RequesterName[64] = GetClientName(client);  "Strings" are just arrays of characters with a 0 as the last element. For example, "hello" is the same as {'h', 'e', 'l', 'l', 'o', 0}. Therefore, functions like GetClientName cannot actual return a "string", because you cannot return arrays in Sourcepawn. Instead, Sourcepawn alters arrays that are passed to the function. So instead of your code, you would do: PHP Code: char Char_BufferText[32], Char_RequesterName[32]; GetClientName(client, Char_RequesterName, sizeof(Char_RequesterName));  You are passing the char array Char_RequesterName into GetClientName() which then gets modified, much like Char_BufferText when you use Format().

thank you, nice help :X

other lines is true??