[Ark_Procession]

Hello

This is a code from @napoleon_be.

can anyone help me adding bot support? currently it only check for alive humans players at least ingame.

Also make it possible to show a DHUD message instead.

i'm using condition zero bots.


The code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

#define PLUGIN "Show Players"
#define VERSION "1.0"
#define AUTHOR "NapoleoN#"


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    set_task(0.5, "ShowPlayers")
}

public ShowPlayers() {
    new players[32], inum, tplayers, ctplayers, talive, ctalive
    get_players(players, inum)
    
    for(new i; i < inum; i++) {
        switch(cs_get_user_team(players[i])) {
            case CS_TEAM_CT: {
                ctplayers++
                if(is_user_alive(players[i]))
	      
		
		{
                    ctalive++
		    
                }
            }
            
            case CS_TEAM_T: {
                tplayers++
                
                if(is_user_alive(players[i])) {
                    talive++
                }
            }
        }
        set_hudmessage(random(255), random(255), random(255), -1.0, 0.0, 0, 0.0, 2.0, 0.1, 0.2, -1)
        show_hudmessage(players[i], "Terrorists: %i/%i | Counter-Terrorists: %i/%i", talive, tplayers, ctalive, ctplayers)
    }
    set_task(1.0, "ShowPlayers")
}  

Thanks people.

[Napoleon_be]

Where did u get this code from? And i can't see the problem why it's not showing the bots for you. This also might need to be rewritten though as this is not how it should be done by using get_players().

EDIT: In the meantime, i rewrote this code, but it's untested though.

PHP Code:

/* Sublime AMXX Editor v2.2 */

#pragma semicolon 1

#include <amxmodx>

#define PLUGIN  "Show Players"
#define VERSION "1.0"
#define AUTHOR  "NapoleoN#"

#define MSGID 81045

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

enum _:ePlayerInfo
{
    iTotalPlayers,
    iCtPlayers,
    iCtAlive,
    iTerPlayers,
    iTerAlive
};

new iInfo[ePlayerInfo];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
}

public client_putinserver(id)
{
    iInfo[iTotalPlayers]++;

    if(!task_exists(MSGID))
    {
        set_task(10.0, "displayMessage", MSGID);
    }
}


#if AMXX_VERSION_NUM < 183
public client_disconnect(id)
#else
public client_disconnected(id)
#endif
{
    iInfo[iTotalPlayers]--;

    if(iInfo[iTotalPlayers] == 0 && task_exists(MSGID))
    {
        remove_task(MSGID);
    }
}

public displayMessage()
{
    if(task_exists(MSGID))
    {
        new iPlayers[MAX_PLAYERS], iNum;

        get_players(iPlayers, iNum, "e", "TERRORIST");
        iInfo[iTerPlayers] = iNum;

        get_players(iPlayers, iNum, "ae", "TERRORIST");
        iInfo[iTerAlive] = iNum;

        get_players(iPlayers, iNum, "e", "CT");
        iInfo[iCtPlayers] = iNum;

        get_players(iPlayers, iNum, "ae", "CT");
        iInfo[iCtAlive] = iNum;

        get_players(iPlayers, iNum);

        for(new i; i < iNum; i++)
        {
            set_hudmessage(random(255), random(255), random(255), -1.0, 0.0, 0, 0.0, 1.1, 0.1, 0.2, -1);
            show_hudmessage(iPlayers[i], "Terrorists: %i/%i | Counter-Terrorists: %i/%i",
                              iInfo[iTerAlive], iInfo[iTerPlayers],
                              iInfo[iCtAlive], iInfo[iCtPlayers]);
        }
        set_task(1.0, "displayMessage", MSGID);
    }
} 


[Ark_Procession]

Originally Posted by Napoleon_be Where did u get this code from? And i can't see the problem why it's not showing the bots for you. This also might need to be rewritten though as this is not how it should be done by using get_players(). EDIT: In the meantime, i rewrote this code, but it's untested though. [/php]

I saw the code in some post i can't remember now, but you wrote it as far as i remember.

will test it! thanks

[Ark_Procession]

It works perfectly! thanks

[Napoleon_be]

Originally Posted by Ark_Procession It works perfectly! thanks

Lol i'm actually surprised by that.

Just one thing, if anyone has a suggestion on how to get rid of those multiple get_players() calls, please lmk. It's kind of ugly this way.

[iceeedr]

Originally Posted by Napoleon_be Lol i'm actually surprised by that. Just one thing, if anyone has a suggestion on how to get rid of those multiple get_players() calls, please lmk. It's kind of ugly this way.

Not tested.

PHP Code:

stock GetPlayersTeamNum(CsTeams:Team, bool:alive)
{
    new iPlayers[MAX_PLAYERS ], iNum;
    get_players(iPlayers, iNum, alive ? "ae" : "e", Team == CS_TEAM_CT ? "CT" : "TERRORIST");
    return iNum;
} 


/* Sublime AMXX Editor v2.2 */

#pragma semicolon 1

#include <amxmodx>

#define PLUGIN  "Show Players"
#define VERSION "1.0"
#define AUTHOR  "NapoleoN#"

#define MSGID 81045

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

enum _:ePlayerInfo
{
    iTotalPlayers,
    iCtPlayers,
    iCtAlive,
    iTerPlayers,
    iTerAlive
};

new iInfo[ePlayerInfo];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
}

public client_putinserver(id)
{
    iInfo[iTotalPlayers]++;

    if(!task_exists(MSGID))
    {
        set_task(10.0, "displayMessage", MSGID);
    }
}


#if AMXX_VERSION_NUM < 183
public client_disconnect(id)
#else
public client_disconnected(id)
#endif
{
    iInfo[iTotalPlayers]--;

    if(iInfo[iTotalPlayers] == 0 && task_exists(MSGID))
    {
        remove_task(MSGID);
    }
}

public displayMessage()
{
    if(task_exists(MSGID))
    {
        iInfo[iTerPlayers] = GetPlayersTeamNum(CS_TEAM_T, false);

        iInfo[iTerAlive] = GetPlayersTeamNum(CS_TEAM_T, true);

        iInfo[iCtPlayers] = GetPlayersTeamNum(CS_TEAM_CT, false);

        iInfo[iCtAlive] = GetPlayersTeamNum(CS_TEAM_CT, true);

        set_hudmessage(random(255), random(255), random(255), -1.0, 0.0, 0, 0.0, 1.1, 0.1, 0.2, -1);
        show_hudmessage(0, "Terrorists: %i/%i | Counter-Terrorists: %i/%i", iInfo[iTerAlive], iInfo[iTerPlayers], iInfo[iCtAlive], iInfo[iCtPlayers]);

        set_task(1.0, "displayMessage", MSGID);
    }
}

stock GetPlayersTeamNum(CsTeams:Team, bool:alive)
{
    new iPlayers[MAX_PLAYERS], iNum;
    get_players(iPlayers, iNum, alive ? "ae" : "e", Team == CS_TEAM_CT ? "CT" : "TERRORIST");
    return iNum;
}

[Napoleon_be]

thanks @ iceeedr, should work by the looks of it, thanks for the optimization.

[Ark_Procession]

Originally Posted by iceeedr Not tested. PHP Code: stock GetPlayersTeamNum(CsTeams:Team, bool:alive) {     new iPlayers[MAX_PLAYERS ], iNum;     get_players(iPlayers, iNum, alive ? "ae" : "e", Team == CS_TEAM_CT ? "CT" : "TERRORIST");     return iNum; }  /* Sublime AMXX Editor v2.2 */ #pragma semicolon 1 #include <amxmodx> #define PLUGIN "Show Players" #define VERSION "1.0" #define AUTHOR "NapoleoN#" #define MSGID 81045 #if !defined MAX_PLAYERS const MAX_PLAYERS = 32; #endif enum _:ePlayerInfo { iTotalPlayers, iCtPlayers, iCtAlive, iTerPlayers, iTerAlive }; new iInfo[ePlayerInfo]; public plugin_init() { register_plugin(PLUGIN, VERSION, AUTHOR); } public client_putinserver(id) { iInfo[iTotalPlayers]++; if(!task_exists(MSGID)) { set_task(10.0, "displayMessage", MSGID); } } #if AMXX_VERSION_NUM < 183 public client_disconnect(id) #else public client_disconnected(id) #endif { iInfo[iTotalPlayers]--; if(iInfo[iTotalPlayers] == 0 && task_exists(MSGID)) { remove_task(MSGID); } } public displayMessage() { if(task_exists(MSGID)) { iInfo[iTerPlayers] = GetPlayersTeamNum(CS_TEAM_T, false); iInfo[iTerAlive] = GetPlayersTeamNum(CS_TEAM_T, true); iInfo[iCtPlayers] = GetPlayersTeamNum(CS_TEAM_CT, false); iInfo[iCtAlive] = GetPlayersTeamNum(CS_TEAM_CT, true); set_hudmessage(random(255), random(255), random(255), -1.0, 0.0, 0, 0.0, 1.1, 0.1, 0.2, -1); show_hudmessage(0, "Terrorists: %i/%i | Counter-Terrorists: %i/%i", iInfo[iTerAlive], iInfo[iTerPlayers], iInfo[iCtAlive], iInfo[iCtPlayers]); set_task(1.0, "displayMessage", MSGID); } } stock GetPlayersTeamNum(CsTeams:Team, bool:alive) { new iPlayers[MAX_PLAYERS], iNum; get_players(iPlayers, iNum, alive ? "ae" : "e", Team == CS_TEAM_CT ? "CT" : "TERRORIST"); return iNum; }

Hi, appreciate the extra help! two wonderful modders! thanks to both.

you forgot to add

#include <cstrike>

for CS_TEAM_T/CT.

adding it compiles perfectly, without it throws 5 errors.

also works perfectly

[iceeedr]

You're right, I compiled on amxx 1.10 and it didn't show any warn or error so I didn't even notice the lack of the include, how strange!