[Obbin]

I know allmost the same quesion has been asked before (aiming direction and that stuff) but i couldn't figure out how to do this.

Here it is:
I want to get the position (x, y, z) that is 1500 units forward in the aiming direction of the player.

Thx.

[Kraugh]

posted in this topic:

public find_origin_passed(Float:origin[3],Float:angles[3],Float:dist,Float:output[3]) {
    output[0] = origin[0] + dist * floatcos(angles[1],degrees) * floatabs(floatcos(angles[0],degrees));
    output[1] = origin[1] + dist * floatsin(angles[1],degrees) * floatabs(floatcos(angles[0],degrees));
    output[2] = origin[2] + dist * floatsin(angles[0],degrees);
 }

[Obbin]

I do really not understand
Could you make a function that stored the new position in a global var?

[VEN]

You can't understand this if you are unfamiliar with trigonometry.

[KoST]

there is a way doing this without the need to calculate angles to vectors with floatcos and/or floatsin, since VelocityByAim does it already.. look at this code. it will show you the x,y and z coordinate (that is 1500 units forward in the aiming direction of the player) if you say "test" in game chat..

#nclude <amxmodx>
#include <amxmisc>
#include <engine>

public plugin_init(){ 
   register_plugin("Test","0.1","KoST") 
   register_clcmd("say test", "test", ADMIN_KICK,"test function") 
} 

public test(id,level,cid){ 
   if(!cmd_access(id,level,cid,1)){ 
      return PLUGIN_HANDLED 
   } 
    
   new distance=1500 // here you can adjust the distance 
   new Float:originalSpot[3],Float:aimVec[3] 

   // get user's origin
   entity_get_vector(id,EV_VEC_origin,originalSpot) 
    
   // get a vector in the direction the player is looking 
   VelocityByAim(id,distance,aimVec) 

   // add offset to origin
   originalSpot[0] += aimVec[0] // is the same as originalSpot[0] = originalSpot[0] + aimVec[0] 
   originalSpot[1] += aimVec[1]
   originalSpot[2] += aimVec[2] 

   new Float:x=originalSpot[0] // here is your x
   new Float:y=originalSpot[1] // here is your y
   new Float:z=originalSpot[2] // here is your z

   // output x,y and z coordinate
   client_print(id,print_chat,"x=%f y=%f z=%f",x,y,z)

   // uncomment the following line to teleport the player to that point
   // entity_set_vector(id,EV_VEC_origin,originalSpot) 

   return PLUGIN_HANDLED 
}

[k007]

how far is 1500 units? and how many units is the distance between 2 boxes like in the bomb site in dust

[VEN]

From statsx.sma

// Distance formula (metric) Float:distance(iDistance) { return float(iDistance) * 0.0254 }