[Electroo]

Bonsoirs ,
J'ai cherché un plugin , mais j'ai rien trouvé ! ^^
Un plugin qui change la map automatiquement ( à De_dust2 par default ) , Si y'a aucun T ou CT sur le serveur ( et non pas les Spec ! )
Le plugin commence a scanner a partir de 1 minute ( contrôlé par cvar c'est mieux ) du changement de map !

Quelqu'un peut m'aider svp ^^ ?
Merci !

[MiniBrackeur]

Peut-être ça:

PHP Code:

#include <amxmodx>

public plugin_init()
{
    register_plugin("Changemap", "1.0", "Daminou")
    
    new g_check
    g_check = register_cvar("amx_mapcheckplayer", "60.0")
    
    set_task(get_pcvar_float(g_check), "check_players", _, _, _, "b")
}

public check_players()
{
    new players[32], playerscount
    get_players(players, playerscount, "ch")
    if(playerscount == 0)
    {
        server_cmd("changelevel de_dust2")
    }
    return PLUGIN_HANDLED
} 


[Devil259]

PHP Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >

new g_pCvarCheck;

public plugin_init( )
{
    new szMapname[ 32 ];
    get_mapname( szMapname, 31 );
    
    if( !equal( szMapname, "de_dust2" ) )
    {
        g_pCvarCheck = register_cvar( "amx_check_time", "60" );
        
        new iEnt = create_entity( "info_target" );
        if( iEnt )
        {
            set_pev( iEnt, pev_classname, "check" )
            register_think( "check", "funcCheck" );
            set_pev( iEnt, pev_nextthink, get_gametime( ) + get_pcvar_float( g_pCvarCheck ) );
        }
    }
}

public funcCheck( iEnt )
{
    set_pev( iEnt, pev_nextthink, get_gametime( ) + get_pcvar_float( g_pCvarCheck ) );
    
    new iPlayers[ 32 ], iNum;
    get_players( iPlayers, iNum, "ch" );

    if( !iNum )
    {
        server_cmd( "changelevel de_dust2" );
        log_to_file( "changemap.log", "Changement de map. Raison : Aucun joueur connecté" );
    }
} 


Un peu plus optimisé.

[Electroo]

Merci à vous deux !

[Kidev]

Galileo fait ça.

[Electroo]

Possible d'ajouté un Log ? ( changemap.log)
Merci !

[Devil259]

Et tu veux mettre quoi en log ?

[Electroo]

Originally Posted by Devil259 Et tu veux mettre quoi en log ?

exemple :
[12:11:29] Changement de map , raison : No CT/T détecté

[Devil259]

J'ai édité mon code précédent.

log_to_file va automatiquement ajouté la date et l'heure avant le message.

[ConnorMcLeod]

PHP Code:

#include <amxmodx>

new const UBER_SUPER_MAP[] = "de_dust2"

#define VERSION "0.0.2"
#define PLUGIN "Change map on empty server"

new g_pCvarCheckTime

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    new mapName[10]
    get_mapname(mapName, charsmax(mapName))
    if( equali(mapName, UBER_SUPER_MAP) )
    {
        g_pCvarCheckTime = register_cvar("amx_mapcheckplayer", "60.0") 
        state CanCheckPlayers
    }
    else
    {
        state DontCheckPlayers
    }
}

public client_disconnect(id) <DontCheckPlayers> { /* do nothing */ }
public client_disconnect(id) <CanCheckPlayers>
{
    if( get_gametime() > get_pcvar_float(g_pCvarCheckTime) )
    {
        state CanChangeMap
        client_disconnect(id)
    }
}
public client_disconnect(id) <CanChangeMap>
{
    new players[32], num
    get_players(players, num, "ceh", "TERRORIST")
    if( !num || ( num == 1 && players[0] == id ) )
    {
        get_players(players, num, "ceh", "CT")
        if( !num || ( num == 1 && players[0] == id ) )
        {
            log_amx("Changement de map pour %s , pas de joueurs.", UBER_SUPER_MAP)
            server_cmd("changelevel %s", UBER_SUPER_MAP)
        }
    }
}