[Colex]

How to block permanent ban on amxmodx?

Allow only ban with times.

[Sreaper]

So they can do 999999999999999 for a duration instead? You would be better off having a separate ban command that has a fixed duration set.

[fysiks]

Originally Posted by Sreaper So they can do 999999999999999 for a duration instead? You would be better off having a separate ban command that has a fixed duration set.

That ban will only be active while the server is running. As soon as the server stops or crashes, it will be removed.

[Colex]

I want to remove permanent ban from the server.
Allow only bans per minute.

[fysiks]

What commands do you need to be restricted?

[Colex]

amx_ban = 0 (permanent)

[fysiks]

To block people from using amx_ban for a permanent ban, you should add this:

	if( str_to_num(minutes) == 0 )
	{
		client_print(id, print_chat, "You cannot ban permanently.");
		return PLUGIN_HANDLED
	}

after this

	if (!player)
		return PLUGIN_HANDLED

in under "public cmdBan(id, level, cid)" in admincmd.sma, then recompile and upload the new .amxx file to your server.

[Colex]

Not work....

PHP Code:

public cmdBan(id, level, cid)
{
    if (!cmd_access(id, level, cid, 3))
        return PLUGIN_HANDLED

    new target[32], minutes[8], reason[64]
    
    read_argv(1, target, 31)
    read_argv(2, minutes, 7)
    read_argv(3, reason, 63)
    
    new player = cmd_target(id, target, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_NO_BOTS | CMDTARGET_ALLOW_SELF)
    
    if (!player)
        return PLUGIN_HANDLED
        
    if( str_to_num(minutes) == 0 )
    {
        client_print(id, print_chat, "Ban permanente, bloqueado!");
        return PLUGIN_HANDLED
    }

    new authid[32], name2[32], authid2[32], name[32]
    new userid2 = get_user_userid(player)

    get_user_authid(player, authid2, 31)
    get_user_authid(id, authid, 31)
    get_user_name(player, name2, 31)
    get_user_name(id, name, 31)
    
    log_amx("Ban: ^"%s<%d><%s><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%s^") (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, minutes, reason)
    
    new temp[64], banned[16], nNum = str_to_num(minutes)
    if (nNum)
        format(temp, 63, "%L", player, "FOR_MIN", minutes)
    else
        format(temp, 63, "%L", player, "PERM")

    format(banned, 15, "%L", player, "BANNED")

    if (reason[0])
        server_cmd("kick #%d ^"%s (%s %s)^";wait;banid %s %s;wait;writeid", userid2, reason, banned, temp, minutes, authid2)
    else
        server_cmd("kick #%d ^"%s %s^";wait;banid %s %s;wait;writeid", userid2, banned, temp, minutes, authid2)

    
    // Display the message to all clients

    new msg[256];
    new len;
    new maxpl = get_maxplayers();
    for (new i = 1; i <= maxpl; i++)
    {
        if (is_user_connected(i) && !is_user_bot(i))
        {
            len = formatex(msg, charsmax(msg), "%L", i, "BAN");
            len += formatex(msg[len], charsmax(msg) - len, " %s ", name2);
            if (nNum)
            {
                len += formatex(msg[len], charsmax(msg) - len, "%L", i, "FOR_MIN", minutes);
            }
            else
            {
                len += formatex(msg[len], charsmax(msg) - len, "%L", i, "PERM");
            }
            if (strlen(reason) > 0)
            {
                formatex(msg[len], charsmax(msg) - len, " (%L: %s)", i, "REASON", reason);
            }
            show_activity_id(i, id, name, msg);
        }
    }
    
    console_print(id, "[AMXX] %L", id, "CLIENT_BANNED", name2)
    
    return PLUGIN_HANDLED
} 


[fysiks]

Were you able to get it to compile? Are you sure you replaced the original .amxx file on your server (and restarted)?

[Colex]

Yes, but it still did not work.

I tried the ban on amxmodmenu.

i got:

In actionBanMenu (plmenu.sma)

after:

PHP Code:

new userid2 = get_user_userid(player) 


put:

PHP Code:

if( str_to_num(g_menuSettings[id]) == 0 )
{
    client_print(id, print_chat, "You cannot ban permanently.");
    return PLUGIN_HANDLED
}