[r14170]

Hi there.

I searched for some revive plugins but all of them are very different from what Im looking for.

Im looking for a plugin which gives everyone 5% chance to be revived after they type "!reviveme" or "/reviveme" or "reviveme"

It can be only used by dead players and only once per round.

I would be very grateful if someone can help.

Thank you!

[AePT]

Try it

PHP Code:

#include <cstrike>

#pragma newdecls required
#pragma semicolon 1

public Plugin myinfo =
{
    name                = "[Any] Lucky Respawn",
    author            = "AePT",
    description = "Gives players a chance to respawn.",
    version            = "1.0.0"
};

#define RESPAWN_CHANCE 5

bool g_already_used[MAXPLAYERS + 1] = { false, ... };

public void OnPluginStart()
{
    RegConsoleCmd("sm_reviveme", CMD_LuckyRespawn);
    HookEvent("round_start", Hook_RoundStart);
}

public void Hook_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientInGame(i))
        {
            continue;
        }

        g_already_used[i] = false;
    }
}

public Action CMD_LuckyRespawn(int client, int args)
{
    if (IsPlayerAlive(client))
    {
        PrintToChat(client, "Only dead players can use this command.");
        return Plugin_Handled;
    }

    if (g_already_used[client])
    {
        PrintToChat(client, "You already tried lucky respawning this round.");
        return Plugin_Handled;
    }

    g_already_used[client] = true;

    if (GetRandomInt(0, 100) <= RESPAWN_CHANCE)
    {
        CS_RespawnPlayer(client);
        PrintToChat(client, "You have revived with a %d%% chance!", RESPAWN_CHANCE);
    }
    else
    {
        PrintToChat(client, "No luck, try the next round. :(");
    }

    return Plugin_Handled;
} 


[r14170]

Hey! Thanks for the quick reply!

Works like a charm!

I really appreciate your help!

Is it possible to also check if the round has ended and if it has, the function would not be available? Like, lets say all people die and the round ends - when somebody types /reviveme - it wouldnt be possible to be respawned.

[AePT]

Originally Posted by r14170 Hey! Thanks for the quick reply! Works like a charm! I really appreciate your help! Is it possible to also check if the round has ended and if it has, the function would not be available? Like, lets say all people die and the round ends - when somebody types /reviveme - it wouldnt be possible to be respawned.

PHP Code:

#include <cstrike>

#pragma newdecls required
#pragma semicolon 1

public Plugin myinfo =
{
    name                = "[Any] Lucky Respawn",
    author            = "AePT",
    description = "Gives players a chance to respawn.",
    version            = "1.0.1"
};

#define RESPAWN_CHANCE 5

bool g_round_ended                                    = false;
bool g_already_used[MAXPLAYERS + 1] = { false, ... };

public void OnPluginStart()
{
    RegConsoleCmd("sm_reviveme", CMD_LuckyRespawn);
    HookEvent("round_start", Hook_RoundStart);
    HookEvent("round_end", Hook_RoundEnd);
}

public void Hook_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    g_round_ended = false;

    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientInGame(i))
        {
            continue;
        }

        g_already_used[i] = false;
    }
}

public void Hook_RoundEnd(Event event, const char[] name, bool dontBroadcast)
{
    g_round_ended = true;
}

public Action CMD_LuckyRespawn(int client, int args)
{
    if (IsPlayerAlive(client))
    {
        PrintToChat(client, "Only dead players can use this command.");
        return Plugin_Handled;
    }

    if (g_round_ended)
    {
        PrintToChat(client, "The round is over, you can't use this command.");
        return Plugin_Handled;
    }

    if (g_already_used[client])
    {
        PrintToChat(client, "You already tried lucky respawning this round.");
        return Plugin_Handled;
    }

    g_already_used[client] = true;

    if (GetRandomInt(0, 100) <= RESPAWN_CHANCE)
    {
        CS_RespawnPlayer(client);
        PrintToChat(client, "You have revived with a %d%% chance!", RESPAWN_CHANCE);
    }
    else
    {
        PrintToChat(client, "No luck, try the next round. :(");
    }

    return Plugin_Handled;
} 


[r14170]

You are awesome!

I really really appreciate your help!

[Grey83]

AePT, in this form it will be a little better:

PHP Code:

#pragma newdecls required
#pragma semicolon 1

#include <cstrike>

#define RESPAWN_CHANCE    5

public Plugin myinfo =
{
    name        = "[Any] Lucky Respawn",
    author        = "AePT",
    description = "Gives players a chance to respawn.",
    version        = "1.0.1_fix"
}

bool
    g_round_ended,
    g_already_used[MAXPLAYERS + 1];

public void OnPluginStart()
{
    HookEvent("round_freeze_end", Event_Round, EventHookMode_PostNoCopy);
    HookEvent("round_end", Event_Round, EventHookMode_PostNoCopy);

    RegConsoleCmd("sm_reviveme", CMD_LuckyRespawn);
}

public void Event_Round(Event event, const char[] name, bool dontBroadcast)
{
    if((g_round_ended = name[6] == 'e')) for(int i = 1; i <= MaxClients; i++) g_already_used[i] = false;
}

public Action CMD_LuckyRespawn(int client, int args)
{
    if(!client || GetClientTeam(client) < CS_TEAM_T)    // neither server nor spectators are allowed
        return Plugin_Handled;

    if(IsPlayerAlive(client))
    {
        PrintToChat(client, "Only dead players can use this command.");
        return Plugin_Handled;
    }

    if(g_round_ended)
    {
        PrintToChat(client, "The round is over, you can't use this command.");
        return Plugin_Handled;
    }

    if(g_already_used[client])
    {
        PrintToChat(client, "You already tried lucky respawning this round.");
        return Plugin_Handled;
    }

    g_already_used[client] = true;

    if(GetRandomInt(1, 100) <= RESPAWN_CHANCE)
    {
        CS_RespawnPlayer(client);
        PrintToChat(client, "You have revived with a %d%% chance!", RESPAWN_CHANCE);
    }
    else PrintToChat(client, "No luck, try the next round. :(");

    return Plugin_Handled;
} 


[r14170]

Hey! Thanks for the update.

I believe it fixes a potential problem where only 1 player was able to use the revive me and it disables it for everyone?

Havent tested it yet, will do in a bit!

[Grey83]

Originally Posted by r14170 I believe it fixes a potential problem where only 1 player was able to use the revive me and it disables it for everyone?

I have no idea about this

[AePT]

Originally Posted by Grey83 AePT, in this form it will be a little better:

Thank you for the update, I appreciate it

[r14170]

Im struggling to undestand how does this line work exactly:

    if(!client || GetClientTeam(client) < CS_TEAM_T)    // neither server nor spectators are allowed
        return Plugin_Handled;

Does this mean that CS_TEAM_NONE and CS_TEAM_SPECTATOR are ignored?

also I think there is a mistype here:

 HookEvent("round_freze_end", Event_Round, EventHookMode_PostNoCopy);

I changed it to round_freeze_end so it can work.

Either way, thank you very much for this, really appreciate it!