[Drak]

I'm sure this is alot simpler then how I'm thinking of it. But I have:

new const g_Symbols[][1] =
{
    'A',
    'B',
    'C',
    'D',
    'E'
}
new g_UserSymbols[3][33][1]

Foo()
{
    copy(g_UserSymbols[0][id],1,g_Symbols[random(sizeof(g_Symbols)]);
    copy(g_UserSymbols[1][id],1,g_Symbols[random(sizeof(g_Symbols)]);
    copy(g_UserSymbols[2][id],1,g_Symbols[random(sizeof(g_Symbols)]);
}

And I want to know if "g_UserSymbols" contains 2/3 of the same letters.
IE:

g_UserSymbols[0] = A
g_UserSymbols[1] = B
g_UserSymbols[2] = A

I want to know that it contains two A's or B's or C's etc.

[Exolent[jNr]]

First, g_UserSymbols third dimension should be 2.
Otherwise a string won't fit.

Also, since you're assigning random values, this tut may help you:
https://forums.alliedmods.net/showthread.php?t=74666

[Bugsy]

If you are only working with only a single character then you can eliminate the third dimension all together. If you want, explain what you are attempting to do and we can maybe recommend a better way.

Try this:

PHP Code:

#include <amxmodx>

new const g_Symbols[] =
{
    'A',
    'B',
    'C',
    'D',
    'E'
};
new g_UserSymbols[ 3 ][ 33 ];

public plugin_init() 
{
    register_concmd( "test" , "Foo" );
}

public Foo( id )
{
    g_UserSymbols[ 0 ][ id ] = g_Symbols[ random( sizeof( g_Symbols ) ) ];
    g_UserSymbols[ 1 ][ id ] = g_Symbols[ random( sizeof( g_Symbols ) ) ];
    g_UserSymbols[ 2 ][ id ] = g_Symbols[ random( sizeof( g_Symbols ) ) ];

    server_print( "Symbols=%c%c%c - Double? %d" , g_UserSymbols[ 0 ][ id ] , g_UserSymbols[ 1 ][ id ] , g_UserSymbols[ 2 ][ id ] , CheckDouble( id ) );
}

public bool:CheckDouble( id )
{    
    new iChecked;
    
    for ( new i = 0 ; i < sizeof( g_UserSymbols ) ; i++ )
    {
        if ( iChecked & ( 1 << ( g_UserSymbols[ i ][ id ] - 'A' ) ) )
            return true;
        
        iChecked |= ( 1 << ( g_UserSymbols[ i ][ id ] - 'A' ) );
    }
    
    return false;
} 


[Exolent[jNr]]

@Bugsy
That doesn't work as a string anymore then.
Symbols=%s%s%s

Symbols=%c%c%c

[Bugsy]

Originally Posted by Exolent[jNr] @Bugsy That doesn't work as a string anymore then. Symbols=%s%s%s Symbols=%c%c%c

True, though they will print the same. I'll change to %c for the sake of correctness