[davidto1995]

I tried to hook ScreenFade messages and block some of them.

PHP Code:

register_message( get_user_msgid( "ScreenFade" ) , "msgScreenFade" ); // Hook ScreenFade messages 


PHP Code:

public msgScreenFade( msg_id , msg_dest , msg_entity )
{

    new bool: player_blinded = bool: get_xvar_num( XVar_IsAllHumanBlind );

    client_print( 0 , print_chat , "player_blinded: %i" , player_blinded );

    if( player_blinded )
    {

        return PLUGIN_HANDLED;

    }
    else
    {

        return PLUGIN_CONTINUE;

    }

} 


PHP Code:

stock fade_user_screen(id, Float:duration = 1.0, Float:fadetime = 1.0, ScreenFadeFlags:flags = ScreenFade_FadeIn, r = 0, g = 0, b = 255, a = 75, bool:reliable = true)
{
    if(id && !is_user_connected(id))
        return 0;

    static MSG_ScreenFade;

    if(!MSG_ScreenFade)
        MSG_ScreenFade = get_user_msgid("ScreenFade");

    message_begin(get_msg_destination(id, reliable), MSG_ScreenFade, .player = id);
    write_short(float_to_short(fadetime));
    write_short(float_to_short(duration));
    write_short(_:flags);
    write_byte(r);
    write_byte(g);
    write_byte(b);
    write_byte(a);
    message_end();

    return 1;
} 


However, except at the time when a player spawned ( client_print() called ), the ScreenFade message is not hooked at any time during the game ( no client_print() called ).

[Black Rose]

If you're trying to hook screenfade sent by other plugins they need to send it using emessage_*()/ewrite_*() natives.

/* These are the same as above, except that the messages sent
 *  are also sent to all other plugins and Metamod plugins.
 * This means that if you send one of these messages, other plugins will
 *  be notified, which was previously impossible.  
 * BE CAREFUL! Using these incorrectly, or not for their intended purpose,
 *  could cause infinite recursion or something just as bad. 
 * NOTE! These natives are experimental.
 */
native emessage_begin(dest, msg_type, const origin[3] = {0,0,0}, player = 0);
native emessage_end();
native ewrite_byte(x);
native ewrite_char(x);
native ewrite_short(x);
native ewrite_long(x);
native ewrite_entity(x);
native ewrite_angle(x);
native ewrite_coord(x);
native ewrite_string(const x[]);

[davidto1995]

Thanks it is solved.