[ReeZey]

how can i print the current speed of a player into a SPEED counter in a custom hud

[KiLLeR.]

With vector_length and pass the player's velocity as parameter.

[Bugsy]

PHP Code:

#include <amxmodx>
#include <fakemeta>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

new bool:g_bTaskSet , Float:fPrevOrigin[ MAX_PLAYERS + 1 ][ 3 ];

public plugin_init() 
{
    register_plugin( "Units per Second" , Version , "bugsy" );
    
    register_logevent( "RoundStart" , 2 , "1=Round_Start" ); 
}


public RoundStart()
{
    new iPlayers[ 32 ] , iNum;
    
    get_players( iPlayers , iNum , "ach" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            arrayset( _:fPrevOrigin[ iPlayers[ i ] ] , 0 , 3 );
        }
        
        if ( !g_bTaskSet )
        {
            set_task( 1.0 , "GetUPS" , 0b11101011011 , .flags="b" );
            g_bTaskSet = true;
        }
    }
    else if ( g_bTaskSet )
    {
        remove_task( 0b11101011011 );
        g_bTaskSet = false;
    }
}

public GetUPS()
{
    new iPlayers[ 32 ] , iNum , id , Float:fCurOrigin[ 3 ];
    
    get_players( iPlayers , iNum , "ach" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            id = iPlayers[ i ];
            
            pev( id , pev_origin , fCurOrigin );
                
            if ( fPrevOrigin[ id ][ 0 ] )
            {    
                client_print( id , print_chat , "* You are traveling %d units per second" , floatround( get_distance_f( fPrevOrigin[ id ] , fCurOrigin ) ) ); 
            }
            
            fPrevOrigin[ id ][ 0 ] = fCurOrigin[ 0 ];
            fPrevOrigin[ id ][ 1 ] = fCurOrigin[ 1 ];
            fPrevOrigin[ id ][ 2 ] = fCurOrigin[ 2 ];
        }
    }
} 


[PRoSToTeM@]

@Bugsy, why not just use 0 as task id? (default param value)

[Bugsy]

Originally Posted by PRoSToTeM@ @Bugsy, why not just use 0 as task id? (default param value)

Because idk, lol. Does it really matter 0 vs non-zero?

Also, OP, I realized this is only giving you how far he has traveled in the past 1 second which is probably not what you want. Are you looking for an overall average distance per second?

Here's average units per second, with HUD.

PHP Code:


#include <amxmodx>
#include <fakemeta>

new const Version[] = "0.2";

#define MAX_PLAYERS 32

enum DistanceData
{
    DistanceTraveled,
    ReadingsTaken
}

new bool:g_bTaskSet , Float:fPrevOrigin[ MAX_PLAYERS + 1 ][ 3 ];
new g_PlayerData[ MAX_PLAYERS + 1 ][ DistanceData ];

public plugin_init() 
{
    register_plugin( "Average Units per Second" , Version , "bugsy" );
    
    register_logevent( "RoundStart" , 2 , "1=Round_Start" ); 
}


public RoundStart()
{
    new iPlayers[ 32 ] , iNum , id;
    
    get_players( iPlayers , iNum , "ach" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            id = iPlayers[ i ];
            
            g_PlayerData[ id ][ DistanceTraveled ] = 0;
            g_PlayerData[ id ][ ReadingsTaken ] = 0;
            arrayset( _:fPrevOrigin[ id ] , 0 , sizeof( fPrevOrigin[] ) );
        }
        
        if ( !g_bTaskSet )
        {
            set_task( 1.0 , "GetUPS" , 0b11101011011 , .flags="b" );
            g_bTaskSet = true;
        }
    }
    else if ( g_bTaskSet )
    {
        remove_task( 0b11101011011 );
        g_bTaskSet = false;
    }
}

public GetUPS()
{
    new iPlayers[ 32 ] , iNum , id , Float:fCurOrigin[ 3 ];
    
    get_players( iPlayers , iNum , "ach" );
    
    if ( iNum )
    {
        for ( new i = 0 ; i < iNum ; i++ )
        {
            id = iPlayers[ i ];
            
            pev( id , pev_origin , fCurOrigin );
            
            if ( fPrevOrigin[ id ][ 0 ] )
            {    
                g_PlayerData[ id ][ DistanceTraveled ] += floatround( get_distance_f( fPrevOrigin[ id ] , fCurOrigin ) );
                g_PlayerData[ id ][ ReadingsTaken ]++;
                
                set_hudmessage( 255 , 0 , 0 , -1.0 , 0.4 , 0 , 0.0 , 0.9 );
                show_hudmessage( id , "%d units/sec" , g_PlayerData[ id ][ DistanceTraveled ] / g_PlayerData[ id ][ ReadingsTaken ] );
                
                //client_print( id , print_chat , "* You are traveling approximately %d units per second. [%d,%d]" , g_PlayerData[ id ][ DistanceTraveled ] / g_PlayerData[ id ][ ReadingsTaken ] , g_PlayerData[ id ][ ReadingsTaken ] , g_PlayerData[ id ][ DistanceTraveled ] ); 
            }
            
            fPrevOrigin[ id ][ 0 ] = fCurOrigin[ 0 ];
            fPrevOrigin[ id ][ 1 ] = fCurOrigin[ 1 ];
            fPrevOrigin[ id ][ 2 ] = fCurOrigin[ 2 ];
        }
    }
}