[Depresie]

Is there any way to detect when a player joins to spectator via cs_set_user_team native?
This won't hook it =d

PHP Code:

register_event( "TeamInfo" , "fw_EvTeamInfo" , "a" ); 


[klippy]

I don't know how did you plan to detect a team change by setting someone's team. I guess you meant cs_get_user_team.

Here's a solution using Okapi. Tested and works on Windows.

PHP Code:

#include <amxmodx>
#include <okapi>

#define PLUGIN  "Detect Team Change"
#define VERSION "1.0"
#define AUTHOR  "KliPPy"


public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);

    new methodAddress;
    if(is_linux_server())
    {
        static const symbol[] = "_Z21HandleMenu_ChooseTeamP11CBasePlayeri";
        methodAddress = okapi_mod_get_symbol_ptr(symbol);
    }
    else
    {
        static const signature[] = {0x83,0xEC,0xDEF,0x8B,0x0D,0xDEF,0xDEF,0xDEF,0xDEF,0x53,0x55,0x56,0x8B,0x74};
        methodAddress = okapi_mod_find_sig(signature, sizeof(signature));
    }

    if(methodAddress == 0)
    {
        set_fail_state("Couldn't find HandleMenu_ChooseTeam.");
        return;
    }

    new okapi_func:func_HandleMenu_ChooseTeam = okapi_build_function(methodAddress, arg_int, arg_cbase, arg_int);
    okapi_add_hook(func_HandleMenu_ChooseTeam, "Hook_HandleMenu_ChooseTeam", true);
}

public Hook_HandleMenu_ChooseTeam(player, newTeam)
{
    // This function may get called even if the team change wasn't successful. The function returns TRUE if the change was successful.
    if(okapi_get_orig_return())
        server_print("Team changed! Player: %d New Team: %d", player, newTeam);
} 


[Depresie]

What i meant was if it is possible to detect when cs_set_user_team is called, but i guess i will just do a work around..

[safetymoose]

If you're trying to prevent the spectator bug, i'd recommend ReGameDLL_CS.

[siriusmd99]

Originally Posted by Depresie What i meant was if it is possible to detect when cs_set_user_team is called, but i guess i will just do a work around..

Only way is to recompile cstrike module by making a forward for cs_set_user_team native.

[Depresie]

Too tired to do such things.. and if i do that, then i will want to start doing more.. and in that way i will never finish my project

[klippy]

Use Orpheu to hook that native, kek.

[Depresie]

Nah, i got a nice workaround method already, i need to create some new natives for my csex API plugin which is an extension of natives for cstrike.. i will handle there and this..

I don't have the required knowledge to use orpheu, and atm i don't have the required time to learn
And if it were to do this, i would rather modify amxx, and i don't want to get into that, because i will want to modify more and more and more and i will never finish my project lol

[Bugsy]

Edit: Updated per Arkshine & Klippy's comments.

Signature created using cstrike module from 1.8.3 dev+4748

I only tested this on Windows.

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <orpheu>
#include <orpheu_memory>

new const Version[] = "0.2";

const CellSizeBytes = ( cellbits / 8 );

#define GetParams(%1,%2)    (%1 + (%2 * CellSizeBytes))

public plugin_init()
{
    register_plugin( "cs_set_user_team hook" , Version , Version );
    
    OrpheuRegisterHook( OrpheuGetFunction( "cs_set_user_team" ) , "Hook_cs_set_user_team" );
    
    register_clcmd( "say test" , "test" );
}

public test( id )
{
    cs_set_user_team( id , CS_TEAM_SPECTATOR , CS_DONTCHANGE );
}

public OrpheuHookReturn:Hook_cs_set_user_team( amx , params )
{
    //From cstrike module: CstrikeNatives.cpp
    //  static cell AMX_NATIVE_CALL cs_set_user_team(AMX *amx, cell *params) // cs_set_user_team(index, team, model = 0); = 3 params
    //  {
          // params[1] = user index
          // params[2] = team
          // params[3] = model = 0
        
    new iPlayer = OrpheuMemoryGetAtAddress( GetParams( params , 1 ) , "int" );
    new iTeam = OrpheuMemoryGetAtAddress( GetParams( params , 2 ) , "int" );
    new iModel = OrpheuMemoryGetAtAddress( GetParams( params , 3 ) , "int" );
    
    client_print( iPlayer , print_chat , "cs_set_user_team was called: id=%d Team=%d Model=%d" , iPlayer , iTeam , iModel );
} 


Output:

cs_set_user_team : id=1 Team=3 Model=0

File: amxmodx\configs\orpheu\functions\cs_set_user_ team

{
    "name" : "cs_set_user_team",
    "library" : "cstrike",
    "arguments" :
    [
        {
            "type" : "int"
        },
        {
            "type" : "int"
        }
    ],
    "identifiers":
    [
        {
            "os" : "windows",
            "mod" : "cstrike",
            "value" : [0x55,0x8B,"*",0x83,"*","*",0xA1,0xB8,"*","*","*",0x33,0xC5,0x89,0x45,"*",0x56,0x8B,"*","*",0x8B,0x46,"*",0x57,0x8B,"*","*",0x83,0xF8]
        },
        {
            "os"    : "linux",
            "mod"   : "cstrike",
            "value" : "cs_set_user_team"
        }
    ]
}

File: amxmodx\configs\orpheu\memory\int

{
    "name"        : "int",
    "type"        : "int",
    "memoryType"  : "data",
    "identifiers" :
    [
        {
            "os"    : "windows",
            "value" : 0
        },
        {
            "os"    : "linux",
            "value" : 0
        }
    ]
}

[Bos93]

new iTeam = OrpheuMemoryGetAtAddress( params + 4 , "int" );
new iModel = OrpheuMemoryGetAtAddress( params + 8 , "int" );

Why did you add these numbers?