[Th3822]

While testing this plugin:

PHP Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>

// random_mod(max): A small function to give a random number from 0 to max-1. Useful for get random values from arrays
#define random_mod(%1) (random_num(0, (100 * (%1)) - 1) % (%1))

new Array:g_aSpawnOrigins, Array:g_aSpawnAngles;
new g_iSpawnsCount;

public plugin_init()
{
    register_plugin("[HL] Random Spawn Sort", "1.0", "Th3-822");

    g_aSpawnOrigins = ArrayCreate(3);
    g_aSpawnAngles = ArrayCreate(3);
}

public plugin_cfg()
{
    loadSpawns();

    if (g_iSpawnsCount > 1)
    {
        RegisterHam(Ham_Spawn, "player", "Ham_Player_Spawn_Post", 1);
    }
}

loadSpawns()
{
    new iEnt = get_maxplayers(), Float:fVector[3];
    while ((iEnt = find_ent_by_class(iEnt, "info_player_deathmatch")))
    {
        entity_get_vector(iEnt, EV_VEC_origin, fVector);
        ArrayPushArray(g_aSpawnOrigins, fVector);

        entity_get_vector(iEnt, EV_VEC_angles, fVector);
        ArrayPushArray(g_aSpawnAngles, fVector);

        g_iSpawnsCount++;
    }
}

is_spawn_valid(id, Float:vOrigin[3])
{
    return (trace_hull(vOrigin, (get_user_flags(id) & FL_DUCKING ? HULL_HEAD : HULL_HUMAN), id, DONT_IGNORE_MONSTERS) & 2) ? 0 : 1;
}

public Ham_Player_Spawn_Post(id)
{
    //if (is_user_alive(id))
    //{
    new iRandomSpawn = random_mod(g_iSpawnsCount), Float:fVector[3];
    entity_get_vector(id, EV_VEC_origin, fVector);
    server_print(" * Player %i spawned @ {%.2f, %.2f, %.2f} : is_user_alive = %i*", id, fVector[0], fVector[1], fVector[2], is_user_alive(id));

    ArrayGetArray(g_aSpawnOrigins, iRandomSpawn, fVector);
    if (is_spawn_valid(id, fVector))
    {
        entity_set_origin(id, fVector);

        ArrayGetArray(g_aSpawnAngles, iRandomSpawn, fVector);
        entity_set_vector(id, EV_VEC_angles, fVector);
        entity_set_int(id, EV_INT_fixangle, 1);

        return HAM_HANDLED;
    }
    //}
    return HAM_IGNORED;
} 


Got the following error while running it on 1.9.0.5249 (Windows):

[ENGINE] Invalid player 1 (not in-game)
[AMXX] Displaying debug trace (plugin "hl_random_spawn_sort.amxx", version "1.0")
[AMXX] Run time error 10: native error (native "trace_hull")
[AMXX]    [0] hl_random_spawn_sort.sma::is_spawn_valid (line 46)
[AMXX]    [1] hl_random_spawn_sort.sma::Ham_Player_Spawn_Post (line 58)

but on 1.8.2 the same plugin works fine, this happens on the first spawn when i join to the server
here are pictures from the console (i was using rehlds when i got the error, so i did had to switch to vanilla hlds to test too)

(Win) HLDS (8196) & AMXX v1.9.0.5249:

(Win) HLDS (8196) & AMXX v1.8.2:


(Win) reHLDS (3.6.0.672-dev) & AMXX v1.9.0.5249:

(Win) reHLDS (3.6.0.672-dev) & AMXX v1.8.2:


the hlds build is a couple of months old (too lazy to update it), but the issue gets noticed on the images with the server version and meta dll too (also tested with other metamod with the same)

also, i wasn't expecting is_user_alive returning 0 in Ham_Spawn_Post, but, as the result is the same as 1.9.0, i will do a workaround for it

--- Edit 1 ---

Forgot to add that, on the 1.9.0 tests, i tested both plugins: Compiled with 1.9.0 and with 1.8.2 and the issue was present on both cases (just in case)

--- Edit 2 ---

Got to test on a linux server too (just with reHLDS 3.7.0.687-dev) and it was the same result

(Linux) reHLDS (3.7.0.687-dev) & AMXX v1.9.0.5249:

(Linux) reHLDS (3.7.0.6872-dev) & AMXX v1.8.2:


--- Edit 3 ---

Solved, the issue was on 1.8.2, more info: https://forums.alliedmods.net/showpo...87&postcount=5
If anybody wants to use the plugin, apply the workaround on the post and uncomment the "if" block

[E1_531G]

You have to always check if user is alive in Ham_Spawn post, bcz Ham_Spawn is got called also when the player join in the server.

[Th3822]

Originally Posted by E1_531G You have to always check if user is alive in Ham_Spawn post, bcz Ham_Spawn is got called also when the player join in the server.

As you can see at the server output it just got called one time on entering, btw, the alive check works fine when respawning, but thats wasn't included on the screenshots

[bad_boy]

Originally Posted by Th3822 As you can see at the server output it just got called one time on entering

That's why you are getting the error. E1_531G is correct.

PHP Code:

if( is_user_alive( id ) && is_spawn_valid(id, fVector)) 


[Th3822]

Originally Posted by bad_boy That's why you are getting the error. E1_531G is correct. PHP Code: if( is_user_alive( id ) && is_spawn_valid(id, fVector))

The player is indeed alive at that moment, but is_user_alive returns 0 because is_user_connected is also returning 0...
Anyways, i'll re-add the user alive check and the "solution" (it's more a workaround) that i got for that

---

I got my own answer after checking and rechecking things, and to notice it better i wrote a small plugin to get this output (on both versions):

PHP Code:

  * client_connect(1) *
 * client_authorized(1) *
 * Ham_Player_Spawn_Pre(1) *
    * is_user_connecting(1): 1 | is_user_connected(1): 0 *
    * pev_valid(1): 2 | is_user_alive(1): 0 *
    * ExecuteHam(Ham_IsAlive, 1): 0 | entity_get_float(1, EV_FL_health): 0.00 *
 * Ham_Player_Spawn_Post(1) *
    * is_user_connecting(1): 1 | is_user_connected(1): 0 *
    * pev_valid(1): 2 | is_user_alive(1): 0 *
    * ExecuteHam(Ham_IsAlive, 1): 1 | entity_get_float(1, EV_FL_health): 100.00 *
 * client_putinserver(1) *
    * is_user_connecting(1): 0 | is_user_connected(1): 1 *
    * pev_valid(1): 2 | is_user_alive(1): 1 *
    * ExecuteHam(Ham_IsAlive, 1): 1 | entity_get_float(1, EV_FL_health): 100.00 * 


AMXX doesn't consider the client fully connected until just before calling the client_putinserver forward... And... As is_user_alive also includes the is_user_connected check, it will return 0

I initially thought that it was an issue on 1.9, but on 1.8.2 lot's of engine functions didn't have safeguard checks for the entity, that's why it was working on 1.8.2.
So getting the error was the correct result, now i have to fix my plugin:

Re-adding the is_user_alive check that was commented on Ham_Player_Spawn_Post will make it work fine, but it won't be called "correctly" with the spawn when user joins, so as solution i will call the hook function on client_putinserver and that is all.

PHP Code:

public client_putinserver(id)
{
    // Workaround for first spawn at join
    Ham_Player_Spawn_Post(id);
} 


Not all things works in the same way as cstrike plugins, i will mark the thread as solved.

[fysiks]

Originally Posted by Th3822 AMXX doesn't consider the client fully connected until just before calling the client_putinserver forward... And... As is_user_alive also includes the is_user_connected check, it will return 0 I initially thought that it was an issue on 1.9, but on 1.8.2 lot's of engine functions didn't have safeguard checks for the entity, that's why it was working on 1.8.2.

Realize that AMX Mod X doesn't do much, if any, of this logic. For example, Ham_Spawn is a function in the actual game and AMX Mod X simply allows you to hook it. If the original developers of the game decided to use that function in ways that you don't expect, it's just something that you have to deal with. E.g. it has always been a necessity (afaik) to have an alive check in a Ham_Spawn hook.

I'm not sure why you think you wouldn't need an alive check in any version of AMX Mod X. Also, I didn't really understand why you are calling your Ham_Spawn post function at client_putinserver(). Ham_Spawn will occur when you spawn.

Also, you can't be alive is you are not yet in the server.

[AmXDusT]

Just for curiosity

PHP Code:

// random_mod(max): A small function to give a random number from 0 to max-1. Useful for get random values from arrays
#define random_mod(%1) (random_num(0, (100 * (%1)) - 1) % (%1)) 


Is there any use of getting random that way instead of simply "random_num( 0, (%1) - 1 )"?

[Th3822]

Originally Posted by AmXDusT Just for curiosity PHP Code: // random_mod(max): A small function to give a random number from 0 to max-1. Useful for get random values from arrays #define random_mod(%1) (random_num(0, (100 * (%1)) - 1) % (%1))  Is there any use of getting random that way instead of simply "random_num( 0, (%1) - 1 )"?

This one i can reply right away (i will answer the other one, when i get home from work):

I always disliked how random_num gives results that looks "not so random" when using small numbers, so i make a big random number and apply modulo on it to get a value from 0-(%1 - 1)

Of course, this is just personal opinion... But i have noticed the differences while using it and i'm happy with it.

[Th3822]

Originally Posted by fysiks Realize that AMX Mod X doesn't do much, if any, of this logic. For example, Ham_Spawn is a function in the actual game and AMX Mod X simply allows you to hook it. If the original developers of the game decided to use that function in ways that you don't expect, it's just something that you have to deal with. E.g. it has always been a necessity (afaik) to have an alive check in a Ham_Spawn hook. I'm not sure why you think you wouldn't need an alive check in any version of AMX Mod X. Also, I didn't really understand why you are calling your Ham_Spawn post function at client_putinserver(). Ham_Spawn will occur when you spawn. Also, you can't be alive is you are not yet in the server.

Players always spawns alive at PutInServer, but on cstrike gets switched to spec until teamselect, then CGameRules manages it's respawn. (That was a lot of links XD)

In HL there is no team/class select on connect, so you spawn directly at PutInServer as there is no need to defer the (alive) spawn...
But, on that first spawn (hooked with HAM), is_user_alive returns false because AMXX's PutInServer_Post hook (from meta) hasn't been called yet...
It's something a little bit like this issue.

So, i have 2 options for doing the stuff i need to do on that first spawn when is_user_alive (and _connected) are true and can run functions on the player:

• Do the stuff on the player on the next hookable action ( that it's just client_putinserver(id) )
• Detect the "first spawn" (!is_user_alive(id) && is_user_connecting(id)) at my hook and set a task for doing it "later"

The first one it's the best option, so that's why there is a call to the Spawn_Post hook at there.