[HarryPotter]

director_no_death_check 1 is enough as little_froy said,
It disabled survivor team death ending scenario.

try

PHP Code:

sm_cvar director_no_death_check 1
sm_cvar sb_all_bot_game 1
sm_cvar allow_all_bot_survivor_team 1 


[kewie]

Originally Posted by HarryPotter director_no_death_check 1 is enough as little_froy said, It disabled survivor team death ending scenario. try PHP Code: sm_cvar director_no_death_check 1 sm_cvar sb_all_bot_game 1 sm_cvar allow_all_bot_survivor_team 1

It worked! The game continues as expected, but the respawn plugin displays a message "couldn't respawn at the moment"

https://github.com/fbef0102/L4D1_2-P...rvivor_Respawn

the plugin by @101 worked, the player respawns after 5 seconds. it doesn't have the options to randomize respawn items :c

-----
its possible to use it on maps without needing to activate cheats? This only worked on the map loaded by the command.

[HarryPotter]

Originally Posted by kewie It worked! The game continues as expected, but the respawn plugin displays a message "couldn't respawn at the moment" https://github.com/fbef0102/L4D1_2-P...rvivor_Respawn

If there are no any alive survivors on the map. The plugin stop respawning dead players.

its possible to use it on maps without needing to activate cheats? This only worked on the map loaded by the command.

You can use sm_cvar without cheats active, just write in cfg/server.cfg

PHP Code:

sm_cvar director_no_death_check 1
sm_cvar sb_all_bot_game 1
sm_cvar allow_all_bot_survivor_team 1 


[kewie]

Thanks, just one more question, is there any line I can edit so the plugin continues respawning?

[little_froy]

Originally Posted by kewie Thanks, just one more question, is there any line I can edit so the plugin continues respawning?

it's hard to find respawn point that valid and good compatibility with mechanism if no survivor alive.

[101]

Originally Posted by kewie the plugin by @101 worked, the player respawns after 5 seconds. it doesn't have the options to randomize respawn items :c

easy .. but I felt that this mod doesn't make sense without managing players actions [awards/penalties]
this is a simple structure of a new l4d-mode with a bad experience 'Unluckily' :

Spoiler

PHP Code:

#include <sdktools>

Handle Plugin_Handle[6];
float LastValidPos[3],slot_range[5];
int i_TimeCounter;

char X_Weapons[40][] =
{
    "rifle",
    "autoshotgun",
    "hunting_rifle",
    "pumpshotgun",
    "smg",
    "rifle_ak47",
    "rifle_sg552",
    "rifle_desert",
    "shotgun_spas",
    "shotgun_chrome",
    "smg_silenced",
    "smg_mp5",
    "sniper_awp",
    "sniper_military",
    "sniper_scout",
    "rifle_m60",
    "grenade_launcher",
    "pistol",
    "pistol_magnum",
    "Knife",
    "baseball_bat",
    "katana",
    "tonfa",
    "shovel",
    "cricket_bat",
    "golfclub",
    "crowbar",
    "fireaxe",
    "frying_pan",
    "electric_guitar",
    "machete",
    "pitchfork",
    "chainsaw",
    "vomitjar",
    "molotov",
    "pipe_bomb",
    "defibrillator",
    "first_aid_kit",
    "pain_pills",
    "adrenaline"
};

public APLRes AskPluginLoad2(Handle yourself, bool late, char[] error, int err_max) {
    CreateNative("GetRemainingTime", GetRemainingTime);
    CreateNative("ExtendRoundTime", ExtendRoundTime);
    return APLRes_Success;
}

public int GetRemainingTime(Handle plugin, int parameter) {    // usage from other plugins example : int x = GetRemainingTime();    
    return GetConVarBool(Plugin_Handle[1]) ? i_TimeCounter : -1;    // if returned value was -1 : Plugin is disabled
}

public int ExtendRoundTime(Handle plugin, int parameter) {    // usage from other plugins : ExtendRoundTime(30 , "Killing a tank"); or  ExtendRoundTime(-10 , "Death Penalty");
    static char Reason[128];
    if ( GetConVarBool(Plugin_Handle[1]) ){
        GetNativeString(2, Reason, 128);
        ExtendCurrentRound( GetNativeCell(1) , Reason);
        return i_TimeCounter;
    }
    return -1;
}

ExtendCurrentRound( int value , char[] reason){
    if (!value)    return;
    i_TimeCounter += value;
    PrintToChatAll("Round time was %s by %d seconds [%s] .\nRemaining Time : %d seconds ." , value < 0 ? "Shortened" : "Extended" , value , reason , i_TimeCounter);
}

public OnPluginStart(){
    switch ( GetEngineVersion() ){
        case Engine_Left4Dead : slot_range = { 0.04 , 17.17 , 34.35 , 37.37 , 38.38 };
        case Engine_Left4Dead2 :slot_range = { 0.16 , 17.32 , 33.35 , 36.37 , 38.39 };
        default : SetFailState("Made 4 L4D");
    }

    Plugin_Handle[1] = FindConVar("director_no_death_check");

    HookConVarChange(Plugin_Handle[1] , On_Death_Check_Changed);
    if (GetConVarBool(Plugin_Handle[1]))
        CheckCvar(true);
}

public On_Death_Check_Changed(ConVar convar, const char[] oldValue, const char[] newValue){
    if (StringToInt(newValue) && !StringToInt(oldValue))
        CheckCvar(true);
    if (!StringToInt(newValue) && StringToInt(oldValue))
        CheckCvar(false);    
}

CheckCvar(bool Enable){
    if (Enable){
        Plugin_Handle[2] = CreateConVar("director_no_death_respawn_time", "5.0", "time in seconds before re-spawn", FCVAR_NONE , true, 0.1);
        Plugin_Handle[3] = CreateConVar("director_no_death_round_time", "300.0", "round time limit in seconds", FCVAR_NONE , true, 60.0);
        Plugin_Handle[4] = CreateConVar("director_no_death_respawn_health", "70.0", "set survivors health after respawn", FCVAR_NONE , true, 1.0);
        Plugin_Handle[5] = CreateConVar("director_no_death_respawn_items", "1", "number of random items given to players", FCVAR_NONE , true, 0.0 ,true, 5.0);
        HookEvent("round_start", event_round_start);
        HookEvent("player_activate",event_activate);
        HookEvent("player_spawn", event_player_spawn);
        HookEvent("player_death", event_player_death);
        RestartRound(true);
    }
    else{
        UnhookEvent("round_start",event_round_start);
        UnhookEvent("player_activate", event_activate);
        UnhookEvent("player_spawn", event_player_spawn);
        UnhookEvent("player_death", event_player_death);
        LastValidPos = {0.0 , 0.0 , 0.0};
        delete Plugin_Handle[2];
        delete Plugin_Handle[3];
        delete Plugin_Handle[4];
        delete Plugin_Handle[5];
        CheckTimer(false);
    }
}

CheckTimer(bool start_timer){
    if (IsValidHandle(Plugin_Handle[0]))
        KillTimer(Plugin_Handle[0]);
    if (start_timer)
        Plugin_Handle[0] = CreateTimer(1.0 ,Timer_round_end ,_,TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action Timer_round_end(Handle Timer){
    if (--i_TimeCounter > 0){
        if (i_TimeCounter < 31)
            PrintHintTextToAll("remaining time %d",i_TimeCounter);
        return Plugin_Continue;
    }
    RestartRound(false);
    return Plugin_Stop;
}

RestartRound(bool Start){
    if (Start)
        ServerCommand("sm_cvar mp_restartgame 1");
    else{
        char command[16];
        FormatEx(command , 16 , GetEngineVersion() == Engine_Left4Dead ? "endround" : "scenario_end");
        int Flags = GetCommandFlags(command);
        SetCommandFlags(command, 0);
        ServerCommand(command);
        ServerExecute();
        SetCommandFlags(command, Flags);
    }
}

public event_round_start(Handle event, char[] event_name, bool dontBroadcast){
    LastValidPos = {0.0 , 0.0 , 0.0};
    i_TimeCounter = GetConVarInt(Plugin_Handle[3]);
    PrintToChatAll("you have %d seconds to finish this round" , i_TimeCounter);
    CheckTimer(true);
}

public event_activate(Handle event, char[] event_name, bool dontBroadcast){
    CreateTimer( GetConVarFloat(Plugin_Handle[2]) ,Timer_Respawn , GetClientOfUserId(GetEventInt(event, "userid")) );
}

public event_player_spawn(Handle event, char[] event_name, bool dontBroadcast){
    CreateTimer( 2.0 ,Timer_GetValidPoint , GetClientOfUserId(GetEventInt(event, "userid")) );
}

public event_player_death(Handle event, char[] event_name, bool dontBroadcast){
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    if (client && GetClientTeam(client) == 2){
        if ( GetEntityFlags(client) & FL_ONGROUND || !(GetEventInt(event, "type") & 1048608) ){ 
            //  1048608 : DMG_FALL|DMG_CHOKE (no much exp in l4d so you can add more filters)
            GetClientAbsOrigin(client, LastValidPos);
        }
        CreateTimer( GetConVarFloat(Plugin_Handle[2]) ,Timer_Respawn ,client);
    }
}

public Action Timer_GetValidPoint(Handle timer, any client){
    if (!LastValidPos[0] && client && IsClientInGame(client))
        GetClientAbsOrigin(client, LastValidPos);
     return Plugin_Handled;
}

public Action Timer_Respawn(Handle timer, any client){
    if (client && IsClientInGame(client) && GetClientTeam(client) == 2 && !IsPlayerAlive(client)){    // for an Unknown reason events sometimes pass client with 0 index (Invalid User Id)! 
        int ent = CreateEntityByName("info_survivor_rescue");
        if (ent != -1){
            DispatchKeyValueVector(ent, "origin", LastValidPos);
            DispatchSpawn(ent);
            SetEntPropEnt(ent, Prop_Send, "m_survivor",client);
            AcceptEntityInput(ent, "Rescue");
        }
        SetEntityHealth(client, GetConVarInt(Plugin_Handle[4]));
        int slot = -1 , Items = GetConVarInt(Plugin_Handle[5]);
        int Flags = GetCommandFlags("give");
        SetCommandFlags("give", Flags & ~FCVAR_CHEAT);
        while (++slot < Items){
            FakeClientCommand(client,"give %s" , X_Weapons[ GetRandomInt( RoundToFloor(slot_range[slot]) , RoundToNearest(FloatFraction(slot_range[slot]) * 100.0) ) ] );
        }
        SetCommandFlags("give",Flags);
    }
    return Plugin_Handled;
} 


* Notes :
- its a beta version and it will be the final version .
- I've replaced first-spawn method of sdkcall by rescue-spawn method , so the survivors stats of the current round won't be destroyed. FFS .
- I couldn't find a better way to end round in l4d1 [I missed scenario_end effects] .
- I couldn't find a function that display the remaining time on the top corner of screen . [I know that there is a complex one for l4d2 , but I prefer a standard one that supports both games] .
- Plugin has two natives , so you can manage Round time limit from another plugin [extend/shortened] the round time based on game events and players actions , example :

plugin_test.sp

Spoiler

PHP Code:

public OnPluginStart(){
    HookEvent("tank_spawn",event_tank_spawn , EventHookMode_Post);
    HookEvent("tank_killed",event_tank_killed, EventHookMode_Post);
    HookEvent("player_death",event_player_death , EventHookMode_Post);
}

public event_player_death(Handle event, char[] event_name, bool dontBroadcast){
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    if (client && GetClientTeam(client) == 2){
        ExtendRoundTime(-10 , "Death Penalty");
    }
}

public event_tank_spawn(Handle event, char[] event_name, bool dontBroadcast){
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    int MaxHealth = GetEntProp(client ,Prop_Data,"m_iMaxHealth");
    ExtendRoundTime(  MaxHealth  / 100 , "Tank Spawn");
}

public event_tank_killed(Handle event, char[] event_name, bool dontBroadcast){
    ExtendRoundTime( 10 , "Tank Killed");
}

// include :
native int GetRemainingTime();
native int ExtendRoundTime(int Value , const char[] Reason);