[~Ice*shOt]

It is possible to detect if someone touches this? Or in any other way?

PHP Code:

 message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
 write_byte(TE_BLOODSTREAM)
 write_coord(Origin[0])
 write_coord(Origin[1])
 write_coord(Origin[2])
 write_coord(Velocity[3])
 write_coord(Velocity[4])
 write_coord(Velocity[5])
 write_byte(125)
 write_byte(160)
 message_end() 


[Arkshine]

Most likely not possible. Such temporary entity is fully handled on the client. Now, maybe there is some tricky way to visually detect or something. Maybe calculating if blood will be near of player. No idea.

[~Ice*shOt]

Hmm I want to create something like "blood shoot", maybe someone can give ideas. It should be like

PHP Code:

public shot(id)
{
    new iOrigin[3], Float: flOrigin[3], Float: Velocity[3]
    // pev(id, pev_origin, Origin);

    get_user_origin(id, iOrigin, 1)

    entity_get_vector(id, EV_VEC_velocity,  Velocity)

    new Ent = create_entity("info_target") // env_sprite?

    entity_set_string(Ent, EV_SZ_classname, "shot")

    entity_set_model(Ent, g_MyModel) // TE_BLOODSTREAM

    new Float: Mins[3] = { -2.5, -2.5, 0.0 }
    new Float: Maxs[3] = { 2.5, 2.5, 2.0 }
    entity_set_size(Ent, Mins, Maxs)

    IVecFVec(iOrigin, flOrigin)
    entity_set_vector(Ent, EV_VEC_origin, flOrigin)

    entity_set_int(Ent, EV_INT_movetype, MOVETYPE_TOSS)
    entity_set_int(Ent, EV_INT_solid, SOLID_TRIGGER)

    entity_set_edict(Ent, EV_ENT_owner, id)

    velocity_by_aim(id, get_pcvar_num(Cvar_Force), Velocity)
    entity_set_vector(Ent, EV_VEC_velocity, Velocity)
} 


instead of model use TE_BLOODSTREAM, maybe it's possible then?

[Black Rose]

The best idea I have is to create an entity to fall along with the bloodstream and detect touching.
It depends on how much the blood effect varies though. Too much variation can't be covered obviously.

I don't think you can use bloodstream as a model because it's more of a particle effect. But I'm not very good at entities.

[~Ice*shOt]

to create an entity to fall along with the bloodstream

But how?

[Black Rose]

This is the best method I've got...
This one is just an example. You can fine-tune it and add the second, smaller, arced stream as well.

#include <amxmodx>
#include <engine>

public plugin_init() {
    register_plugin("Test Plugin 3", "", "[ --{-@ ]");
    register_touch("blood", "player", "icky");
    
    set_task(1.0, "test", _, _, _, "b");
}

public icky(toucher, touched) {
    server_print("%d touched %d, that's gonna leave a stain", toucher, touched);
}

public plugin_precache() {
    precache_model("models/head.mdl");
}

public test() {
    
    new Float:flOrigin[3] = { 0.0, -3300.0, -200.0 };
    new iOrigin[3] = { 0, -3300, -200 };
    
    new Float:flVelocity[3] = { 100.0, 100.0, 0.0 };
    new iVelocity[3] = { 100, 100, 0 };
    
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
    write_byte(TE_BLOODSTREAM)
    write_coord(iOrigin[0])
    write_coord(iOrigin[1])
    write_coord(iOrigin[2])
    write_coord(iVelocity[0])
    write_coord(iVelocity[1])
    write_coord(iVelocity[2])
    write_byte(125)
    write_byte(160)
    message_end()
    
    for ( new i ; i < 10 ; i++ ) {
        
        new ent = create_entity("info_target");
        
        entity_set_string(ent, EV_SZ_classname, "blood");
        
        entity_set_model(ent, "models/head.mdl");
        
        new Float:flMins[3] = { -2.5, -2.5, 0.0 };
        new Float:flMaxs[3] = { 2.5, 2.5, 2.0 };
        entity_set_size(ent, flMins, flMaxs);
        
        entity_set_vector(ent, EV_VEC_origin, flOrigin);
        
        entity_set_int(ent, EV_INT_movetype, MOVETYPE_TOSS);
        entity_set_int(ent, EV_INT_solid, SOLID_TRIGGER);
        
        flVelocity[0] = float(iVelocity[0]) * ( 0.2 * i );
        flVelocity[1] = float(iVelocity[1]) * ( 0.2 * i );
        entity_set_vector(ent, EV_VEC_velocity, flVelocity)
        
        entity_set_float(ent, EV_FL_gravity, 0.22);
        
        set_task(3.0, "killme", ent);
    }
}

public killme(ent) {
    remove_entity(ent);
}

[Fr33m@n]

if you know what sprite is used, it's better for you to reproduce it with an entity env_sprite.

https://github.com/ValveSoftware/sou...loodstream.cpp
This may help you.

[~Ice*shOt]

Thank you both