[backwards]

This Plugin Allow Players to Buy new Riot Shields for $5000 by typing !buyshield in chat.

*Updated to version 1.2.





Change Log:
v1.2 - Fixed an issue reported by wolvez04.
v1.1 - Adding only buying in spawn zone & mp_buytime.

[TheDS1337]

You got it working, nice!

PS: was it just after today's little update that it worked? because I tried the same before and it didn't.

[backwards]

Originally Posted by TheDS1337 You got it working, nice! PS: was it just after today's little update that it worked? because I tried the same before and it didn't.

They enabled it with the update, I never figured out why it wasn't working prior. I speculate the entity wasn't fully embeded into the game yet although the entity type existed.

[wolvez04]

Seems to be a bug when dropping your shield which can crash the server

When you drop your shield it still shows in your inventory but glitching out. Tried to pickup but couldn't and within seconds crash
CLagCompensationManager::StartLagCompensation with NULL CUserCmd!!!

[backwards]

Originally Posted by wolvez04 Seems to be a bug when dropping your shield which can crash the server When you drop your shield it still shows in your inventory but glitching out. Tried to pickup but couldn't and within seconds crash CLagCompensationManager::StartLagCompensation with NULL CUserCmd!!!

Thanks for the report, problem resolved in the latest version 1.2.

[arcticx2]

Originally Posted by 1337norway Thanks for the report, problem resolved in the latest version 1.2.

small issue : put "ShieldCost" into the text as well ,

PHP Code:

PrintToChat(client, "Sorry you don't have $5000 to buy the shield."); 


i changed & i used new syntax

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma newdecls required

public Plugin myinfo =
{
    name = "BuyShield",
    author = "backwards",
    description = "Allows players to buy shields by typing !buyshield.",
    version = SOURCEMOD_VERSION,
    url = "http://www.steamcommunity.com/id/mypassword"
}

int ShieldCost = 5000
bool RequireBuyZone = true;
Handle BuyStartRoundTimer;

public void OnPluginStart()
{
    RegConsoleCmd("sm_buyshield", BuyShieldCMD);
    HookEvent("round_prestart", Event_RoundPreStart);
}

public Action BuyShieldCMD(int client, int args) 
{
    if(RequireBuyZone)
    {
        bool InBuyZone = view_as<bool>(GetEntProp(client, Prop_Send, "m_bInBuyZone"));
        if(!InBuyZone)
        {
            PrintToChat(client, "Sorry You're Not In a Buy Zone.");
            return Plugin_Handled;
        }
        if (BuyStartRoundTimer == null)
        {
            PrintToChat(client, "The Buy Time Has Expired For This Round.")
            return Plugin_Handled;
        }
    }
    
    int account = GetEntProp(client, Prop_Send, "m_iAccount");
    if(account < ShieldCost)
    {
        PrintToChat(client, "Sorry you don't have $%i to buy the shield." , ShieldCost);
        return Plugin_Handled;
    }
    
    int weaponIdx = GetPlayerWeaponSlot(client, 11);
    
    if(weaponIdx != -1)
    {
        if(IsValidEdict(weaponIdx) && IsValidEntity(weaponIdx))
        {
            char className[128];
            GetEntityClassname(weaponIdx, className, sizeof(className));
            
            if(StrEqual("weapon_shield", className))
            {
                PrintToChat(client, "You are already carrying a shield.");
                return Plugin_Handled;
            }
        }
    }
    
    SetEntProp(client, Prop_Send, "m_iAccount", account - ShieldCost);
    GivePlayerItem(client, "weapon_shield");
    PrintToChat(client, "You've bought a shield.");
    
    return Plugin_Handled;
}

public void Event_RoundPreStart(Handle event, char[] name, bool dontBroadcast)
{
    float BuyTime = 45.0;
    ConVar cvarBuyTime = FindConVar("mp_buytime");
    
    if(cvarBuyTime != null)
        BuyTime = float(cvarBuyTime.IntValue);
        
    if (BuyStartRoundTimer != null)
    {
        KillTimer(BuyStartRoundTimer);
        BuyStartRoundTimer = null;
    }
    
    BuyStartRoundTimer = CreateTimer(BuyTime, StopBuying);
}


public Action StopBuying(Handle timer, any client)
{
    BuyStartRoundTimer = null;
    
    return Plugin_Stop;
} 


[Enrory]

Thanks for this

[Eren]

How to add more durability to the shield?

[NitroN]

niceeee broooow! 100% work.. ty!

[Ilusion9]

Originally Posted by Eren How to add more durability to the shield?

100% this entity has a netprop called m_iHealth, you can start with this.