[Shyloo]

Hello again , i'm looking for a plugin that revives a player from his death place , for example if an player died in the middle of the map i revive him in the same position when he dies not revive him on area T or area CT

[Natsheh]

Why creating a useless thread for something already exist.

Please search before posting.

[Shyloo]

Search what ? , revive from death place is not already exist and it's not usless

[OciXCrom]

Revive when?
Is it for a deathmatch server?
Do you already have a plugin that revives the players?

[Shyloo]

I want the plugin like a command , if the player died in the middlfe of the map , i revive him on his death place , why revive him on Area T if he was T or Area CT if he was CT

[OciXCrom]

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <hamsandwich>

#tryinclude <cromchat>

#if !defined _cromchat_included
    #error "cromchat.inc" is missing in your "scripting/include" folder. Download it from: "https://amxx-bg.info/inc/"
#endif

#if !defined MAX_PLAYERS
const MAX_PLAYERS = 32
#endif

#if !defined MAX_NAME_LENGTH
const MAX_NAME_LENGTH = 32
#endif

new g_iGraveOrigin[MAX_PLAYERS + 1][3]
new bool:g_bGraveSpawn[MAX_PLAYERS + 1]

public plugin_init()
{
    register_plugin("Grave Revive", "1.0", "OciXCrom")
    register_concmd("amx_revive", "Cmd_Revive", ADMIN_BAN, "<player> -- revives a player on his death place")
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
    
    CC_SetPrefix("&x04[Grave Revive]")
}

public client_putinserver(id)
{
    g_bGraveSpawn[id] = false
    arrayset(g_iGraveOrigin[id], 0, sizeof(g_iGraveOrigin[]))
}

public OnPlayerKilled(id)
{
    get_user_origin(id, g_iGraveOrigin[id], 0)
}

public OnPlayerSpawn(id)
{
    if(g_bGraveSpawn[id] && is_user_alive(id))
    {
        g_bGraveSpawn[id] = false

        if(g_iGraveOrigin[id][0] != 0 && g_iGraveOrigin[id][1] != 0 && g_iGraveOrigin[id][2])
        {
            set_user_origin(id, g_iGraveOrigin[id])
        }
    }
}

public Cmd_Revive(id, iLevel, iCid)
{
    if(!cmd_access(id, iLevel, iCid, 2))
    {
        return PLUGIN_HANDLED
    }

    new szPlayer[MAX_NAME_LENGTH]
    read_argv(1, szPlayer, charsmax(szPlayer))

    new iPlayer = cmd_target(id, szPlayer, CMDTARGET_ALLOW_SELF)

    if(!iPlayer)
    {
        return PLUGIN_HANDLED
    }

    get_user_name(iPlayer, szPlayer, charsmax(szPlayer))

    if(is_user_alive(iPlayer))
    {
        console_print(id, "* Player %s is alive!", szPlayer)
        return PLUGIN_HANDLED
    }

    g_bGraveSpawn[iPlayer] = true
    ExecuteHamB(Ham_CS_RoundRespawn, iPlayer)

    new szAdmin[MAX_NAME_LENGTH]
    get_user_name(id, szAdmin, charsmax(szAdmin))

    CC_SendMessage(0, "ADMIN &x03%s &x01revived &x03%s", szAdmin, szPlayer)
    return PLUGIN_HANDLED
}

[Shyloo]

When i try to compile it , it tells me that there is errors or something

[Supremache]

Originally Posted by Shyloo When i try to compile it , it tells me that there is errors or something

#if !defined _cromchat_included #error "cromchat.inc" is missing in your "scripting/include" folder. Download it from: "https://amxx-bg.info/inc/" #endif

[Shyloo]

Yeah i download cromchat and out it on includes

[OciXCrom]

And what is the error?...