[Psyk0tik]

Hello, I'd like to know if it's possible to filter maps or gamemodes by using cvars.

Let's say I want a plugin to only work on l4d2 finale maps, I'd have something like this as a cvar:

l4d2_filter_maps "c1m4_atrium,c2m5_concert"

If this is possible, please show me exactly how to implement this. I'm asking if this is possible because I'd like to implement an easier and shorter way to disable the different systems in my Anti-Speedrunner System on certain maps.

Thanks!

[Lux]

Maybe you looking for this?

https://sm.alliedmods.net/new-api/string/ExplodeString

[midnight9]

You could use boolean, example:

public OnMapStart() {
	decl String:Map[64];
	GetCurrentMap(Map, sizeof(Map));
	if(StrEqual(Map, "c2m5_concert"))
	{
		EnablePlugin = true;
	}

[Psyk0tik]

Originally Posted by midnight9 You could use boolean, example: public OnMapStart() { decl String:Map[64]; GetCurrentMap(Map, sizeof(Map)); if(StrEqual(Map, "c2m5_concert")) { EnablePlugin = true; }

That's actually the current method I'm using. I made this thread in hopes that there can be a shorter way.

[Timocop]

Only finale maps?

PHP Code:

bool IsFinaleMap()
{
    return (FindEntityByClassname(-1, "trigger_finale") != -1);
} 


otherwise use ExplodeString() and split the cvar string (with the map names) into a string array.

PHP Code:

#define MAX_MAPS 64

//Get the current map
char sCurrentMap[128];
GetCurrentMap(sCurrentMap, sizeof(sCurrentMap));

//Split cvar string into string array
char[] sCvarStr = "ds_map1;ds_map2;ds_map3";

char sMaps[MAX_MAPS][128];
ExplodeString(sCvarStr, ";", sMaps, sizeof(sMaps), sizeof(sMaps[]));

//Check for map
bool bEnabled = false;

for(int i = 0; i < sizeof(sMaps); i++) {
    if(StrEqual(sCurrentMap, sMaps[i], false)) {
        bEnabled = true;
        break;
    }
}

//... 


[Psyk0tik]

Originally Posted by Timocop Only finale maps? PHP Code: bool IsFinaleMap() {     return (FindEntityByClassname(-1, "trigger_finale") != -1); }  otherwise use ExplodeString() and split the cvar string (with the map names) into a string array. PHP Code: #define MAX_MAPS 64 //Get the current map char sCurrentMap[128]; GetCurrentMap(sCurrentMap, sizeof(sCurrentMap)); //Split cvar string into string array char[] sCvarStr = "ds_map1;ds_map2;ds_map3"; char sMaps[MAX_MAPS][128]; ExplodeString(sCvarStr, ";", sMaps, sizeof(sMaps), sizeof(sMaps[])); //Check for map bool bEnabled = false; for(int i = 0; i < sizeof(sMaps); i++) {     if(StrEqual(sCurrentMap, sMaps[i], false)) {         bEnabled = true;         break;     } } //...

How can I incorporate a public cvar into this? I'd like users to have the freedom to choose which maps they want certain systems to be disabled in. This would allow for multiple combinations as my Anti-Speedrunner System plugin consists of 5 systems in 1. The main reason for this cvar is to allow support for custom campaigns. If I set the maps within the plugin, there will be way more maps that won't be supported.

[Timocop]

https://sm.alliedmods.net/new-api/co...etConVarString

Edit:
You want to save settings per map right? Why not use config files like for example stripper does.
I dont think cvars are the best way to store configs. Use KeyValues and parse them from files.
https://sm.alliedmods.net/new-api/keyvalues

ds_map1.cfg

"Systems"
{
    "AntiRush"      "1"
    "AntiSpam"     "0"
}

[Psyk0tik]

Thanks to everyone on this thread for your help and NgBUCKWANGS (author of ABM) for the following code.

I have decided to use this:

PHP Code:

char MapName[128]; //Use 128 in case of really long map names

public void OnPluginStart()
{
    HookEvent("round_end", RoundEnd);
    HookEvent("finale_win", FinaleWin);
}

public void OnConfigsExecuted()
{
    GetCurrentMap(MapName, sizeof(MapName));
    Format(MapName, sizeof(MapName), "cfg/sourcemod/l4d_anti-speedrunner/%s.cfg", MapName); //Specifies the path that the plugin will check for custom map configs
    if(FileExists(MapName, true))
    {
        strcopy(MapName, sizeof(MapName), MapName[4]);
        ServerCommand("exec \"%s\"", MapName); //Executes map config if found
    }

    else if(FileExists("cfg/sourcemod/l4d_anti-speedrunner.cfg", true))
    {
        ServerCommand("exec \"sourcemod/l4d_anti-speedrunner.cfg\""); //Executes the plugin's config if map config isn't found
    }
}

public Action RoundEnd(Handle event, const char[] name, bool dontBroadcast)
{
    ServerCommand("exec \"sourcemod/l4d_anti-speedrunner.cfg\""); //Executes the plugin's config so cvars don't break on the next map
}

public Action FinaleWin(Handle event, const char[] name, bool dontBroadcast)
{
    ServerCommand("exec \"sourcemod/l4d_anti-speedrunner.cfg\""); //Executes the plugin's config so cvars don't break on the next campaign
} 


This allows users to just create mapname.cfg files in cfg/sourcemod/l4d_anti-speedrunner folder. In those mapname.cfg files, users can just specify the values they want for certain cvars.

Example:
cfg/sourcemod/l4d_anti-speedrunner/c1m4_atrium.cfg

l4d_ass_incap_required "7"
l4d_ass_punish_enable "0"
l4d_ass_punish_incap "1"
l4d_ass_teleport_enable "0"
l4d_ass_teleport_incap "1"