[xPaw]

CvarToColor

.: Description :.

I saw many plugins where coders getting colors from cvar, but some coders dont know how to do that, so i dedicated to make this simple stock

.: Usage :.

PHP Code:

    new szColorCvar[ 10 ], iColor[ 3 ];
    get_pcvar_string( g_Cvar_mycolors, szColorCvar, charsmax( szColorCvar ) );
    
    CvarToColor( szColorCvar, iColor );

    /*******
     *  Output:
     *     
     *     iColor[ 0 ] - RED
     *     iColor[ 1 ] - GREEN
     *     iColor[ 2 ] - BLUE
     *******/ 


.: Example :.

PHP Code:

Cvar        | Stock
255103204   | 255, 103, 204
255 0 100   | 255, 0, 100
000 020 255 | 0, 20, 255 


.: Stock :.

PHP Code:

/*******
 *  Example usage:
 *
 *     new szColorCvar[ 10 ], iColor[ 3 ];
 *     get_pcvar_string( g_Cvar_mycolors, szColorCvar, charsmax( szColorCvar ) );
 *
 *     CvarToColor( szColorCvar, iColor );
*******
 *  Output:
 *     
 *     iColor[ 0 ] - RED
 *     iColor[ 1 ] - GREEN
 *     iColor[ 2 ] - BLUE
 *******/
stock CvarToColor( szColor[ 13 ], iColorsOut[ 3 ] ) {
    if( ContainSpaces( szColor ) ) {
        new szRGB[ 3 ][ 4 ];
        parse( szColor, szRGB[ 0 ], 3, szRGB[ 1 ], 3, szRGB[ 2 ], 3 );
        
        iColorsOut[ 0 ] = clamp( str_to_num( szRGB[ 0 ] ), 0, 255 );
        iColorsOut[ 1 ] = clamp( str_to_num( szRGB[ 1 ] ), 0, 255 );
        iColorsOut[ 2 ] = clamp( str_to_num( szRGB[ 2 ] ), 0, 255 );
        
        return 1;
    } else {
        new iColor = str_to_num( szColor );
        
        // Credits goes to jim_yang
        iColorsOut[ 0 ] = clamp( ( iColor / 1000000 ), 0, 255 );
        iColor %= 1000000;
        iColorsOut[ 1 ] = clamp( ( iColor / 1000 ), 0, 255 );
        iColorsOut[ 2 ] = clamp( ( iColor % 1000 ), 0, 255 );
        
        return 1;
    }
    
    return 0;
}

bool:ContainSpaces( szString[ 13 ] ) {
    new iLen = strlen( szString );
    
    for( new i = 0; i < iLen; i++ )
        if( szString[ i ] == ' ' )
            return true;
    
    return false;
} 


[zacky]

Nice xpaw. +karma

[alan_el_more]

Awesome Work xPaw
I need this so much!
+karma

[ConnorMcLeod]

I would stick with jim_yang method as it calls less natives than the spaced one.
Also, you could save clamp native call.

Here a way using 1 native instead of 4 in your example (haven't cound get_pcvar since your code doesn't integrate it.

PHP Code:

stock clamp_byte( iByte )
{
    if( iByte < 0 )
    {
        return 0
    }
    else if( iByte > 0xFF )
    {
        return 0xFF
    }
    return iByte
}

stock CvarPointerToColor(pPointer)
{
    static szColors[10], iTemp, iColor[3]
    get_pcvar_string(pPointer, szColors, charsmax(szColors))
    iTemp = str_to_num(szColors)

    iColor[0] = clamp_byte( iTemp / 1000000 )
    iTemp %= 1000000
    iColor[1] = clamp_byte( iTemp / 1000 )
    iColor[Blue] = clamp_byte( iTemp % 1000 )

    return iColor
} 


Then you use it easily :

PHP Code:

new g_pCvarColor

public plugin_init()
{
    g_pCvarColor = register_cvar("my_color_cvar", "255180030")
}

public function_using_color()
{
    new iColors[3] = CvarPointerToColor( g_pCvarColor )
} 


[xPaw]

Connor is right what jim's way is calls less natives, but with spaces its more friendly for server owners ;)

[Arkshine]

Credit is for jim_yang not Connor. Also what is the advantage to use 0xFF instead of 255 ? 255 is more readable and 'understable'.

[ConnorMcLeod]

Originally Posted by arkshine Credit is for jim_yang not Connor.

I have never taken any credit for this, copied it from grenade trail plugin.

Originally Posted by arkshine Also what is the advantage to use 0xFF instead of 255 ? 255 is more readable and 'understable'.

Your point.

[Arkshine]

I have never taken any credit for this, copied it from grenade trail plugin.

I was not talking to you but xPawn so to correct it in its code above.

Your point.

It doesn't anwser to the question to know the advantage of the hex notation instead of classic but well known integer. ( more friendly for a tuto )

[ConnorMcLeod]

clamp byte was from me, but everyone could have made it

[fysiks]

I think that I would make it more like the get_(p)cvar_* commands (for continuity ).

get_cvar_color(pointer, iColor[3])

and

get_pcvar_color(pointer, iColor[3])