[HarryPotter]

Simple, basically I want to force witch to fly away, like car flying.
How to do that.

I have tried

PHP Code:

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", TEST);
}

public Action TEST(int client, int args)
{
    if(client == 0) return Plugin_Handled;

    float ff[3];
    ff[0] = 1000.0; 
    ff[1] = 1000.0; 
    ff[2] = 1000.0; 
    int entity = -1;
    while ( ((entity = FindEntityByClassname(entity, "witch")) != -1) )
    {
        if(!IsValidEntity(entity)) continue;

        PrintToChatAll("witch fly:%d", entity);
        SetEntityMoveType( entity, MOVETYPE_FLY );
        TeleportEntity(entity,NULL_VECTOR,NULL_VECTOR,ff); //not working
        SetEntPropVector(entity, Prop_Data, "m_vecVelocity", ff);  //not working
        SetEntPropVector(entity, Prop_Data, "m_vecBaseVelocity", ff); //not working
        SetEntPropVector(entity, Prop_Data, "m_vecAbsVelocity", ff); //not working
        SetEntPropVector(entity, Prop_Data, "m_vecAngVelocity", ff); //not working
    }

    TeleportEntity(client,NULL_VECTOR,NULL_VECTOR,ff);

    return Plugin_Handled;
} 


Edited:
Solved by BHaType,
Only works when witch is walking, runing and falling
L4D2

L4D1

Spoiler

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
#include <sdktools>
#include <sdkhooks>

Handle g_hNextBotPointer, g_hGetLocomotion, g_hJump;

public void OnPluginStart()
{    
    StartPrepSDKCall(SDKCall_Entity);
    PrepSDKCall_SetVirtual(71); // 72 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hNextBotPointer = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(42); // 43 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hGetLocomotion = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(43); // 44 - linux
    g_hJump = EndPrepSDKCall();
    
    RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT);
}

public Action sm_witchesfly( int client, int args )
{
    int witch = MaxClients + 1;
    
    while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )
    {
        float vVelocity[3];
        vVelocity[2] = 450.0;
       
        ForceWitchJump(witch, vVelocity, true);
    }
    
    return Plugin_Handled;
}

void ForceWitchJump( int witch, const float vVelocity[3], bool add = false )
{
    Address locomotion = GetLocomotion(witch);
    
    if ( !locomotion )
        return;
    
    float vVec[3];
    
    if ( add )
        GetWitchVelocity(locomotion, vVec);

    AddVectors(vVec, vVelocity, vVec);
    
    Jump(witch, locomotion);
    SetWitchVelocity(locomotion, vVec);
}

void Jump( int witch, Address locomotion )
{
    SetEntPropEnt(witch, Prop_Data, "m_hGroundEntity", 0);

    StoreToAddress(locomotion + view_as<Address>(0xB4), 0, NumberType_Int8);
    
    SDKCall(g_hJump, locomotion);
}

void GetWitchVelocity( Address locomotion, float out[3] )
{
    for (int i; i <= 2; i++)
        out[i] = view_as<float>(LoadFromAddress(locomotion + view_as<Address>(0x60 + i * 4), NumberType_Int32));
}

void SetWitchVelocity( Address locomotion, const float vVelocity[3] )
{
    for (int i; i <= 2; i++)
        StoreToAddress(locomotion + view_as<Address>(0x60 + i * 4), vVelocity[i], NumberType_Int32);
}

Address GetLocomotion( int entity )
{
    Address nextbot = GetNextBotPointer(entity);
    
    if ( !nextbot )
        return Address_Null;

    return GetLocomotionPointer(nextbot);
}

Address GetNextBotPointer( int entity )
{
    return SDKCall(g_hNextBotPointer, entity);
}

Address GetLocomotionPointer( Address nextbot )
{
    return SDKCall(g_hGetLocomotion, nextbot);
} 


[BHaType]

Infected and witches velocity is controlled by their inherited locomotion interfaces so you should use them too

Spoiler

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
#include <sdktools>
#include <sdkhooks>

Handle g_hNextBotPointer, g_hGetLocomotion, g_hSetAcceleration;

public void OnPluginStart()
{    
    StartPrepSDKCall(SDKCall_Entity);
    PrepSDKCall_SetVirtual(81); // 82 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hNextBotPointer = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(47); // 48 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hGetLocomotion = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(97); // 98 - linux
    PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);
    g_hSetAcceleration = EndPrepSDKCall();
    
    RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT);
}

public Action sm_witchesfly( int client, int args )
{
    int witch = MaxClients + 1;
    
    while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )
    {
        float vVelocity[3];
        
        vVelocity[0] = GetRandomFloat(-300.0, 300.0);
        vVelocity[1] = GetRandomFloat(-300.0, 300.0);
        vVelocity[2] = 5000.0;
        
        /* A way to say that witch should fly */
        /* Not necessary */
        SetEntPropEnt(witch, Prop_Data, "m_hGroundEntity", -1);
        
        if ( SetInfectedVelocity(witch, vVelocity) )
        {
            PrintToChatAll("yes");
        }
    }
    
    return Plugin_Handled;
}

bool SetInfectedVelocity( int entity, const float vVelocity[3] )
{
    Address nextbot = GetNextBotPointer(entity);
    
    if ( !nextbot )
        return false;
        
    Address locomotion = GetLocomotionPointer(nextbot);
    
    if ( !locomotion )
        return false;
        
    SetVelocity(locomotion, vVelocity);
    return true;
}

void SetVelocity( Address locomotion, const float vVelocity[3] )
{
    /* It's probably not necessary but... */
    /* Game has to handle that itself but i am not sure about it so we force the use of Z motion */
    /* 0x54 - offset to activity type */
    /* 0x0002 - MOTION_CONTROLLED_Z */
    
    StoreToAddress(locomotion + view_as<Address>(0x54), LoadFromAddress(locomotion + view_as<Address>(0x54), NumberType_Int32) | 0x0002, NumberType_Int32);
    
    /* Instead of velocity we use acceleration the game will do the rest by itself */
    
    SDKCall(g_hSetAcceleration, locomotion, vVelocity);
}

Address GetNextBotPointer( int entity )
{
    return SDKCall(g_hNextBotPointer, entity);
}

Address GetLocomotionPointer( Address nextbot )
{
    return SDKCall(g_hGetLocomotion, nextbot);
} 


[HarryPotter]

Originally Posted by BHaType Infected and witches velocity is controlled by their inherited locomotion interfaces so you should use them too

Hmm... I copy and past your code.
It's not working..
the chat prints yes, but not see witch flying

L4D2 Windows server

[BHaType]

Originally Posted by HarryPotter Hmm... I copy and past your code. It's not working.. the chat prints yes, but not see witch flying L4D2 Windows server

... ¯\_(ツ)_/¯

[HarryPotter]

Originally Posted by BHaType ... ¯\_(ツ)_/¯

....No clue

sm plugins list

PHP Code:

[SM] Listing 17 plugins:
  01 "Admin File Reader" (1.10.0.6502) by AlliedModders LLC
  02 "Admin Help" (1.10.0.6502) by AlliedModders LLC
  03 "Admin Menu" (1.10.0.6502) by AlliedModders LLC
  04 "Anti-Flood" (1.10.0.6502) by AlliedModders LLC
  05 "Basic Ban Commands" (1.10.0.6502) by AlliedModders LLC
  06 "Basic Chat" (1.10.0.6502) by AlliedModders LLC
  07 "Basic Comm Control" (1.10.0.6502) by AlliedModders LLC
  08 "Basic Commands" (1.10.0.6502) by AlliedModders LLC
  09 "Basic Info Triggers" (1.10.0.6502) by AlliedModders LLC
  10 "Basic Votes" (1.10.0.6502) by AlliedModders LLC
  11 "Client Preferences" (1.10.0.6502) by AlliedModders LLC
  12 "Fun Commands" (1.10.0.6502) by AlliedModders LLC
  13 "Fun Votes" (1.10.0.6502) by AlliedModders LLC
  14 "Player Commands" (1.10.0.6502) by AlliedModders LLC
  15 "Reserved Slots" (1.10.0.6502) by AlliedModders LLC
  16 "Sound Commands" (1.10.0.6502) by AlliedModders LLC
  17 "test.smx" 


[BHaType]

Added velocity call. You can also try to use !witchesfly when a witch is not on ground
If still doesn't work then i can't help

Spoiler

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
#include <sdktools>
#include <sdkhooks>

Handle g_hNextBotPointer, g_hGetLocomotion, g_hSetAcceleration, g_hSetVelocity;

public void OnPluginStart()
{    
    StartPrepSDKCall(SDKCall_Entity);
    PrepSDKCall_SetVirtual(81); // 82 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hNextBotPointer = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(47); // 48 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hGetLocomotion = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(97); // 98 - linux
    PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);
    g_hSetAcceleration = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(98); // 99 - linux
    PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);
    g_hSetVelocity = EndPrepSDKCall();
    
    RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT);
}

public Action sm_witchesfly( int client, int args )
{
    int witch = MaxClients + 1;
    
    while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )
    {
        float vVelocity[3];
        
        vVelocity[2] = 5000.0;
       
        if ( SetInfectedVelocity(witch, vVelocity) )
        {
            PrintToChatAll("123");
        }
    }
    
    return Plugin_Handled;
}

bool SetInfectedVelocity( int entity, const float vVelocity[3] )
{
    Address nextbot = GetNextBotPointer(entity);
    
    if ( !nextbot )
        return false;
        
    Address locomotion = GetLocomotionPointer(nextbot);
    
    if ( !locomotion )
        return false;
        
    SetVelocity(locomotion, vVelocity);
    return true;
}

void SetVelocity( Address locomotion, const float vVelocity[3] )
{
    SDKCall(g_hSetVelocity, locomotion, vVelocity);
    SDKCall(g_hSetAcceleration, locomotion, vVelocity);
}

Address GetNextBotPointer( int entity )
{
    return SDKCall(g_hNextBotPointer, entity);
}

Address GetLocomotionPointer( Address nextbot )
{
    return SDKCall(g_hGetLocomotion, nextbot);
} 


[HarryPotter]

Originally Posted by BHaType Added velocity call. You can also try to use !witchesfly when a witch is not on ground If still doesn't work then i can't help Spoiler PHP Code: #pragma semicolon 1 #pragma newdecls required   #include <sdktools> #include <sdkhooks> Handle g_hNextBotPointer, g_hGetLocomotion, g_hSetAcceleration, g_hSetVelocity; public void OnPluginStart() {         StartPrepSDKCall(SDKCall_Entity);     PrepSDKCall_SetVirtual(81); // 82 - linux     PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);     g_hNextBotPointer = EndPrepSDKCall();          StartPrepSDKCall(SDKCall_Raw);     PrepSDKCall_SetVirtual(47); // 48 - linux     PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);     g_hGetLocomotion = EndPrepSDKCall();          StartPrepSDKCall(SDKCall_Raw);     PrepSDKCall_SetVirtual(97); // 98 - linux     PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);     g_hSetAcceleration = EndPrepSDKCall();          StartPrepSDKCall(SDKCall_Raw);     PrepSDKCall_SetVirtual(98); // 99 - linux     PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);     g_hSetVelocity = EndPrepSDKCall();          RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT); } public Action sm_witchesfly( int client, int args ) {     int witch = MaxClients + 1;          while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )     {         float vVelocity[3];                  vVelocity[2] = 5000.0;                 if ( SetInfectedVelocity(witch, vVelocity) )         {             PrintToChatAll("123");         }     }          return Plugin_Handled; } bool SetInfectedVelocity( int entity, const float vVelocity[3] ) {     Address nextbot = GetNextBotPointer(entity);          if ( !nextbot )         return false;              Address locomotion = GetLocomotionPointer(nextbot);          if ( !locomotion )         return false;              SetVelocity(locomotion, vVelocity);     return true; } void SetVelocity( Address locomotion, const float vVelocity[3] ) {     SDKCall(g_hSetVelocity, locomotion, vVelocity);     SDKCall(g_hSetAcceleration, locomotion, vVelocity); } Address GetNextBotPointer( int entity ) {     return SDKCall(g_hNextBotPointer, entity); } Address GetLocomotionPointer( Address nextbot ) {     return SDKCall(g_hGetLocomotion, nextbot); }

Thank you for replying , this works only when witch is falling.
If I teleport witch on air, can't force witch to fly.
The witch must be falling on air

Still thanks for your work

[BHaType]

Originally Posted by HarryPotter Thank you for replying , this works only when witch is falling.

Atleast its working but only when she falls so that means game blocking Z velocity if shes not on ground.

Try this. If it works i will add comments for offsets

Spoiler

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
#include <sdktools>
#include <sdkhooks>

Handle g_hNextBotPointer, g_hGetLocomotion, g_hJump;

public void OnPluginStart()
{    
    StartPrepSDKCall(SDKCall_Entity);
    PrepSDKCall_SetVirtual(81); // 82 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hNextBotPointer = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(47); // 48 - linux
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hGetLocomotion = EndPrepSDKCall();
    
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetVirtual(48); // 49 - linux
    g_hJump = EndPrepSDKCall();
    
    RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT);
}

public Action sm_witchesfly( int client, int args )
{
    int witch = MaxClients + 1;
    
    while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )
    {
        float vVelocity[3];
        vVelocity[2] = 450.0;
       
        ForceWitchJump(witch, vVelocity, true);
    }
    
    return Plugin_Handled;
}

void ForceWitchJump( int witch, const float vVelocity[3], bool add = false )
{
    Address locomotion = GetLocomotion(witch);
    
    if ( !locomotion )
        return;
    
    float vVec[3];
    
    if ( add )
        GetWitchVelocity(locomotion, vVec);

    AddVectors(vVec, vVelocity, vVec);
    
    Jump(witch, locomotion);
    SetWitchVelocity(locomotion, vVec);
}

void Jump( int witch, Address locomotion )
{
    SetEntPropEnt(witch, Prop_Data, "m_hGroundEntity", 0);

    /* 0xC0 - offset to isJumping member */
    StoreToAddress(locomotion + view_as<Address>(0xC0), 0, NumberType_Int8);
    
    SDKCall(g_hJump, locomotion);
}

void GetWitchVelocity( Address locomotion, float out[3] )
{
    /* 0x6C - offset velocity member */

    for (int i; i <= 2; i++)
        out[i] = view_as<float>(LoadFromAddress(locomotion + view_as<Address>(0x6C + i * 4), NumberType_Int32));
}

void SetWitchVelocity( Address locomotion, const float vVelocity[3] )
{
    for (int i; i <= 2; i++)
        StoreToAddress(locomotion + view_as<Address>(0x6C + i * 4), vVelocity[i], NumberType_Int32);
}

Address GetLocomotion( int entity )
{
    Address nextbot = GetNextBotPointer(entity);
    
    if ( !nextbot )
        return Address_Null;

    return GetLocomotionPointer(nextbot);
}

Address GetNextBotPointer( int entity )
{
    return SDKCall(g_hNextBotPointer, entity);
}

Address GetLocomotionPointer( Address nextbot )
{
    return SDKCall(g_hGetLocomotion, nextbot);
} 


[HarryPotter]

Originally Posted by BHaType Atleast its working but only when she falls so that means game blocking Z velocity if shes not on ground. Try this. If it works i will add comments for offsets Spoiler PHP Code: #pragma semicolon 1 #pragma newdecls required   #include <sdktools> #include <sdkhooks> Handle g_hNextBotPointer, g_hGetLocomotion, g_hJump; public void OnPluginStart() {         StartPrepSDKCall(SDKCall_Entity);     PrepSDKCall_SetVirtual(81); // 82 - linux     PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);     g_hNextBotPointer = EndPrepSDKCall();          StartPrepSDKCall(SDKCall_Raw);     PrepSDKCall_SetVirtual(47); // 48 - linux     PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);     g_hGetLocomotion = EndPrepSDKCall();          StartPrepSDKCall(SDKCall_Raw);     PrepSDKCall_SetVirtual(48); // 49 - linux     g_hJump = EndPrepSDKCall();          RegAdminCmd("sm_witchesfly", sm_witchesfly, ADMFLAG_ROOT); } public Action sm_witchesfly( int client, int args ) {     int witch = MaxClients + 1;          while ( (witch = FindEntityByClassname(witch, "witch")) && IsValidEntity(witch) )     {         float vVelocity[3];         vVelocity[2] = 450.0;                 ForceWitchJump(witch, vVelocity, true);     }          return Plugin_Handled; } void ForceWitchJump( int witch, const float vVelocity[3], bool add = false ) {     Address locomotion = GetLocomotion(witch);          if ( !locomotion )         return;          float vVec[3];          if ( add )         GetWitchVelocity(locomotion, vVec);     AddVectors(vVec, vVelocity, vVec);          Jump(witch, locomotion);     SetWitchVelocity(locomotion, vVec); } void Jump( int witch, Address locomotion ) {     SetEntPropEnt(witch, Prop_Data, "m_hGroundEntity", 0);     StoreToAddress(locomotion + view_as<Address>(0xC0), 0, NumberType_Int8);          SDKCall(g_hJump, locomotion); } void GetWitchVelocity( Address locomotion, float out[3] ) {     for (int i; i <= 2; i++)         out[i] = view_as<float>(LoadFromAddress(locomotion + view_as<Address>(0x6C + i * 4), NumberType_Int32)); } void SetWitchVelocity( Address locomotion, const float vVelocity[3] ) {     for (int i; i <= 2; i++)         StoreToAddress(locomotion + view_as<Address>(0x6C + i * 4), vVelocity[i], NumberType_Int32); } Address GetLocomotion( int entity ) {     Address nextbot = GetNextBotPointer(entity);          if ( !nextbot )         return Address_Null;     return GetLocomotionPointer(nextbot); } Address GetNextBotPointer( int entity ) {     return SDKCall(g_hNextBotPointer, entity); } Address GetLocomotionPointer( Address nextbot ) {     return SDKCall(g_hGetLocomotion, nextbot); }

This works perfect on standing witch !!
Even witch is on the ground, you can set her fly!!

But there is a small defect, unable to set "Siting Witch" fly.
If survivors don't wake her, it will not work.
Still almost perfect, thank you.

[azureblue]

So, I was compiled the source into .smx file but it didn't work. Am I missed something?
My game is L4D2 and on linux server.

Well, I hope you can make and publish this idea about witch fly/jumping mod into official plugin release someday. It's kinda funny watching your video review. Thanks !