[loiraolhosazul]

I didn't find anything in the forum about 'force the plant of c4' I found a function in reapi 'rg_plant_bomb' but I don't want to use it, how would this function be using the standard modules, fakemeta, engine etc ..

I want to force the plant

[Bugsy]

Is this when the last player alive has the bomb? Does the player need to be teleported to the bomb site?

Or do you only want to know how to initiate a force-plant when at the bombsite?

[loiraolhosazul]

Originally Posted by Bugsy Is this when the last player alive has the bomb? Does the player need to be teleported to the bomb site? Or do you only want to know how to initiate a force-plant when at the bombsite?

what I want to do is, if there are 50 seconds left and the bomb has not been planted I will force the bomb plant but the player does not need to be with it, just plant

[Bugsy]

This will send the player to the site and plant, not thoroughly tested and there may be better ways to do it.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <cstrike>

new const Version[] = "0.1";

const MAX_SUPPORTED_BOMBSITES = 5;

enum BombSites
{
    EntityID,
    Float:EntityOrigin[ 3 ]
}

new bool:g_bPlanted , g_iPlayerWithBomb , g_iSitesFound;
new g_BombSites[ MAX_SUPPORTED_BOMBSITES ][ BombSites ];

public plugin_init() 
{
    register_plugin( "Force C4 Plant Random Site" , Version , "bugsy" );
    
    if ( FindBombSites() )
    {
        register_event( "WeapPickup" , "PlayerWithBomb" , "be" , "1=6" ); 
        register_event( "HLTV", "NewRound" , "a" , "1=0" , "2=0" );
        register_logevent( "BombPlanted" , 3 , "2=Planted_The_Bomb" );
        
        register_clcmd( "say c4" , "PlantC4" );
    }
}

public PlantC4( id )
{
    new iRandomSite , iEntity;

    if ( g_bPlanted == false )
    {
        iRandomSite = random( g_iSitesFound );
        g_BombSites[ iRandomSite ][ EntityOrigin ][ 2 ] += 75.0;
        set_pev( g_iPlayerWithBomb , pev_origin , g_BombSites[ iRandomSite ][ EntityOrigin ] );
        
        if( ( iEntity = create_entity( "weapon_c4" ) ) )
        {
            cs_set_user_bpammo( g_iPlayerWithBomb , CSW_C4 , 0 );
            cs_set_user_plant( g_iPlayerWithBomb , 0 );
        
            DispatchKeyValue( iEntity , "detonatedelay" , "50" );
            DispatchSpawn( iEntity );
            g_BombSites[ iRandomSite ][ EntityOrigin ][ 0 ] += 20.0;
            set_pev( iEntity , pev_origin , g_BombSites[ iRandomSite ][ EntityOrigin ] );
            force_use( iEntity , iEntity ); 
            
            g_bPlanted = true;
        }
    }
    else
    {
        console_print( id , "The bomb was already planted." );
    }
}

public PlayerWithBomb( id )
{
    g_iPlayerWithBomb = id;
}

public BombPlanted()
{
    g_bPlanted = true;
}

public NewRound()
{
    g_bPlanted = false;
}

FindBombSites()
{
    new Float:fOrigin[ 3 ] , iEntity = -1;

    while ( ( iEntity = engfunc( EngFunc_FindEntityByString , iEntity , "classname" , "func_bomb_target" ) ) && ( g_iSitesFound < sizeof( g_BombSites ) ) )
    {
        g_BombSites[ g_iSitesFound ][ EntityID ] = iEntity;
        
        get_brush_entity_origin( iEntity , fOrigin );
        g_BombSites[ g_iSitesFound ][ EntityOrigin ][ 0 ] = fOrigin[ 0 ];
        g_BombSites[ g_iSitesFound ][ EntityOrigin ][ 1 ] = fOrigin[ 1 ];
        g_BombSites[ g_iSitesFound ][ EntityOrigin ][ 2 ] = fOrigin[ 2 ];
        
        g_iSitesFound++;
    }
    
    return g_iSitesFound;
} 


[loiraolhosazul]

really, it takes you to the bombsite but planting is not possible, it is as if the area was removed,

what I really needed is the same function as the 'rg_plant_bomb' where you execute the command and the bomb is placed on the origin.

edit: but the cause of not letting it plant is this ' cs_set_user_plant( g_iPlayerWithBomb , 0 );'

[Bugsy]

It works fine for me, when I say c4, it puts the person with the bomb at the bombsite and plants instantly.

[loiraolhosazul]

Originally Posted by Bugsy It works fine for me, when I say c4, it puts the person with the bomb at the bombsite and plants instantly.

what version of your amxmodx?

[Bugsy]

Older 1.9 build..if you dont have it, upgrade.

[loiraolhosazul]

Originally Posted by Bugsy Older 1.9 build..if you dont have it, upgrade.

weird, I'm using 1.10.5413

[Bugsy]

Which map are you testing on?