[Kashinoda]

I have a plugin that gives players a specific number of decoy grenades when the round starts.

Is there a way to do this without looping or timers? Currently I have this, which works fine:

PHP Code:

public void EquipPlayersDecoy(Event event, const char[] name, bool dontBroadcast)
{
   for (int iClient = 1; iClient <= MaxClients; iClient++)
    {
        if (IsClientConnected(iClient) && IsClientInGame(iClient))
        {
            Client_RemoveWeapon(iClient, "weapon_decoy");
            test[iClient][1] = 0;
            CreateTimer(0.1, GiveDecoys, iClient, TIMER_REPEAT); 
        }
    }
}

public Action GiveDecoys(Handle timer, any client)
{   
    if (test[client][1] == iDecoyAmount)
    {    
        return Plugin_Stop;
    }
    GivePlayerItem(client, "weapon_decoy", 0);
    test[client][1] ++;
    return Plugin_Continue;
} 


I did try a standard for loop but the server times out with large values.

[Wyon]

public void OnPluginStart()
{
	HookEvent("player_spawn", Event_PlayerSpawn);
}

public Action Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
	CreateTimer(0.5, GiveGrenades, event.GetInt("userid"));
}

public Action GiveGrenades(Handle timer, any data)
{
	int iClient = GetClientOfUserId(data);
	if (IsClientInGame(iClient) && IsPlayerAlive(iClient))
	{
		GivePlayerItem(iClient, "weapon_decoy");
		SetEntProp(iClient, Prop_Send, "m_iAmmo", 25, _, 18);
	}
}

[Kashinoda]

Originally Posted by Wyon public void OnPluginStart() { HookEvent("player_spawn", Event_PlayerSpawn); } public Action Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast) { CreateTimer(0.5, GiveGrenades, event.GetInt("userid")); } public Action GiveGrenades(Handle timer, any data) { int iClient = GetClientOfUserId(data); if (IsClientInGame(iClient) && IsPlayerAlive(iClient)) { GivePlayerItem(iClient, "weapon_decoy"); SetEntProp(iClient, Prop_Send, "m_iAmmo", 25, _, 18); } }

Didn't consider using SetEntProp, thank you!

Works great, what is the 18 doing here? (the Element)

[Wyon]

Works great, what is the 18 doing here? (the Element)

It's index in m_iAmmo table, all player ammunition count is stored in that property

[Kashinoda]

Originally Posted by Wyon It's index in m_iAmmo table, all player ammunition count is stored in that property

Thank you!

HE Grenade 14
Smoke 16
Molotov 17
Decoy 18
Snowball 25
Flashbang 15
Tag 22
Health Shot 21

How I found grenade offsets/indexes:

PHP Code:

#include <sourcemod>
#include <smlib>

char sItems[][][] = 
{
    { "weapon_snowball", "Snowball:" },
    { "weapon_hegrenade", "HE Grenade:" },
    { "weapon_smokegrenade", "Smoke:" },
    { "weapon_flashbang", "Flashbang:" },
    { "weapon_tagrenade", "Tag Grenade:" },
    { "weapon_decoy", "Decoy:" },
    { "weapon_molotov", "Molotov:" },
    { "weapon_healthshot", "Healthshot:" },
};

public void OnPluginStart()
{
    RegConsoleCmd("g_index", test, "Show Grenade Index");
}

public Action test(int client, int args)
{
for (int i = 0; i < sizeof(sItems); i++)
{
    GivePlayerItem(client, sItems[i][0], 0);
    for (int iOffsetLookup = 0; iOffsetLookup < 29; iOffsetLookup++)
    {
        int iAmmo = GetEntProp(client, Prop_Send, "m_iAmmo", _, iOffsetLookup);
        if (iAmmo > 0)
            {
                PrintToChat(client, "%s %i", sItems[i][1], iOffsetLookup );
                SetEntProp(client, Prop_Send, "m_iAmmo", 0, _, iOffsetLookup);
                Client_RemoveWeapon(client, sItems[i][0]);
            }                
        }
    }        
}