[Natsheh]

I can give you a more proper way just give me a bit time.


Here's the First Part of creating the zone.

PHP Code:

function(id)
{
    new Float:flMaxBS[3], Float:flMinBS[3], Float:fOrigin[3];
    pev(id, pev_origin, fOrigin);
    CreateBoundingBoxAroundEntities("info_player_start", flMaxBS, flMinBS);
    SCAN_Zone_Visuality(fOrigin, flMaxBS, flMinBS);
}

CreateBoundingBoxAroundEntities(const szEntClassName[32], Float:flMaxBS[3], Float:flMinBS[3])
{
    new ent = -1, Float:fEntMaxBS[3], Float:fEntMinBS[3];
    // find the max/mins coords of the zone.
    while( (ent = find_ent_by_class(ent, szEntClassName)) > 0)
    {
        pev(ent, pev_absmax, fEntMaxBS);
        pev(ent, pev_absmin, fEntMinBS);

        flMaxBS[0] = floatmax(fEntMaxBS[0], flMaxBS[0]);
        flMaxBS[1] = floatmax(fEntMaxBS[1], flMaxBS[1]);
        flMaxBS[2] = floatmax(fEntMaxBS[2], flMaxBS[2]);

        flMinBS[0] = floatmin(fEntMinBS[0], flMinBS[0]);
        flMinBS[1] = floatmin(fEntMinBS[1], flMinBS[1]);
        flMinBS[2] = floatmin(fEntMinBS[2], flMinBS[2]);
    }

    return 0;
} 


Here's the second part...

PHP Code:

SCAN_Zone_Visuality(const Float:fvPOVOrigin[3], const Float:fMaxBS[3], const Float:fMinBS[3])
{
    new Float:fvPOVAngle[3], Float:fAngle[3], Float:fVector[3], Float:fMidPoint[3], Float:fLen, Float:flFraction, iTr2 = create_tr2();
    xs_vec_sub(fMaxBS, fMinBS, fMidPoint);
    xs_vec_mul_scalar(fMidPoint, 0.5, fMidPoint);
    xs_vec_sub(fMidPoint, fvPOVOrigin, fVector);
    xs_vec_normalize(fVector, fVector);
    vector_to_angle(fVector, fvPOVAngle);

    new Float:fDistance = get_distance_f(fvPOVOrigin, fMidPoint);

    for(new Float:fXShift = 60.0, Float:fYShift; fXShift >= -60.0; fXShift += -1.0)
    {
        xs_vec_copy(fvPOVAngle, fAngle);
        fAngle[0] += fXShift;

        for(fYShift = 60.0; fYShift >= -60.0; fYShift += -1.0)
        {
            fAngle[1] += fYShift;

            angle_vector(fAngle, ANGLEVECTOR_FORWARD, fVector);
            fLen = fDistance / floatmax( floatcos( xs_vec_angle(fMidPoint, fVector), degrees ), 1.0 );
            xs_vec_mul_scalar(fVector, fLen, fVector);
            xs_vec_add(fvPOVOrigin, fVector, fVector);

            engfunc(EngFunc_TraceLine, fvPOVOrigin, fVector, IGNORE_MONSTERS|IGNORE_GLASS|IGNORE_GLASS, 0, iTr2);

            get_tr2(iTr2, TR_Fraction, flFraction);

            if(flFraction >= 0.90)
            {
                free_tr2(iTr2);
                return 1;
            }
        }
    }

    free_tr2(iTr2);
    return 0;
} 


Here the function do a scan unit by unit and the function will return 1 when there's a potential view of the zone!

[sebxx4]

Thank you, I'll try both.
Btw, will it check both buying zones?

[artist]

To begin with, it is worth understanding that a traceline can only be drawn to a certain point.

You can get the coordinates of all points at the start and draw lines to them in a cycle.

Here is a plugin that displays all points.

PHP Code:

#include <amxmodx>
#include <fakemeta>
 
new hook_ent_spawn
new Float:ct_origin[32][3], ct_num
new Float:t_origin[32][3], t_num
new sprite
 
public plugin_init()
{
        register_clcmd("say /", "create")
        unregister_forward(FM_Spawn, hook_ent_spawn)
}
public plugin_precache()
{
        hook_ent_spawn = register_forward(FM_Spawn, "ent_spawn")
        sprite = precache_model("sprites/laserbeam.spr")
}
public ent_spawn(ent)
{
        if(!pev_valid(ent)) return FMRES_IGNORED
        
        static classname[33]; pev(ent, pev_classname, classname, charsmax(classname))
        
        if(equal(classname, "info_player_start") && ct_num < sizeof(ct_origin))
        {
                pev(ent, pev_origin, ct_origin[ct_num++])
                server_print("entid %i %s %i", ent, classname, ct_num)
        }
        else if(equal(classname, "info_player_deathmatch") && t_num < sizeof(t_origin))
        {
                pev(ent, pev_origin, t_origin[t_num++])
                server_print("entid %i %s %i", ent, classname, t_num)
        }
        return FMRES_IGNORED
}
public create(id)
{
        for(new a = 0; a < ct_num; a++) create_line(ct_origin[a], 1)
        for(new b = 0; b < t_num; b++) create_line(t_origin[b], 0)
        client_print(id, print_chat, "spawn t = %i", t_num)
        client_print(id, print_chat, "spawn ct = %i", ct_num)
}
public create_line(Float:orign[3], color)
{
        message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
        write_byte(TE_BEAMPOINTS)
        engfunc(EngFunc_WriteCoord, orign[0])   //Стартовая точка x
        engfunc(EngFunc_WriteCoord, orign[1])   //Стартовая точка y
        engfunc(EngFunc_WriteCoord, orign[2]+20)//Стартовая точка z
        engfunc(EngFunc_WriteCoord, orign[0])   //Конечная точка x
        engfunc(EngFunc_WriteCoord, orign[1])   //Конечная точка y
        engfunc(EngFunc_WriteCoord, orign[2]-40)//Конечная точка z
        write_short(sprite)                     //Индекс спрайта
        write_byte(0)                           //Стартовый кадр
        write_byte(1)                           //Скорость анимации
        write_byte(0)                           //Время существования
        write_byte(10)                          //Толщина луча
        write_byte(0)                           //Искажение
        if(color)
        {
                write_byte(0)                   //Цвет красный
                write_byte(0)                   //Цвет зелёный
                write_byte(255)                 //Цвет синий
        }
        else
        {
                write_byte(255)                 //Цвет красный
                write_byte(0)                   //Цвет зелёный
                write_byte(0)                   //Цвет синий
        }
        write_byte(255)                         //Яркость
        write_byte(0)                           //Флаг
        message_end()
} 


[sebxx4]

For now I tried Natsheh's plugin, but it seems to work wierd :/

https://www.youtube.com/watch?v=tK3_nPU4se0

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <engine>
#include <xs>

#define PLUGIN "test"
#define VERSION "1.0"
#define AUTHOR "sebxx"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("say /test", "check_bzs");
}

public check_bzs(id)
{
    new Float:flMaxBS[3], Float:flMinBS[3], Float:fOrigin[3];
    pev(id, pev_origin, fOrigin);
    CreateBoundingBoxAroundEntities("info_player_start", flMaxBS, flMinBS);

    if ( SCAN_Zone_Visuality(fOrigin, flMaxBS, flMinBS) )
        client_print(id, print_center, "I see buying zone!");
    else
        client_print(id, print_center, "I don't see buying zone!");
}

public CreateBoundingBoxAroundEntities(const szEntClassName[32], Float:flMaxBS[3], Float:flMinBS[3])
{
    new ent = -1, Float:fEntMaxBS[3], Float:fEntMinBS[3];
    // find the max/mins coords of the zone.
    while( (ent = find_ent_by_class(ent, szEntClassName)) > 0)
    {
        pev(ent, pev_absmax, fEntMaxBS);
        pev(ent, pev_absmin, fEntMinBS);

        flMaxBS[0] = floatmax(fEntMaxBS[0], flMaxBS[0]);
        flMaxBS[1] = floatmax(fEntMaxBS[1], flMaxBS[1]);
        flMaxBS[2] = floatmax(fEntMaxBS[2], flMaxBS[2]);

        flMinBS[0] = floatmin(fEntMinBS[0], flMinBS[0]);
        flMinBS[1] = floatmin(fEntMinBS[1], flMinBS[1]);
        flMinBS[2] = floatmin(fEntMinBS[2], flMinBS[2]);
    }

    return 0;
} 

public SCAN_Zone_Visuality(const Float:fvPOVOrigin[3], const Float:fMaxBS[3], const Float:fMinBS[3])
{
    new Float:fvPOVAngle[3], Float:fAngle[3], Float:fVector[3], Float:fMidPoint[3], Float:fLen, Float:flFraction, iTr2 = create_tr2();
    xs_vec_sub(fMaxBS, fMinBS, fMidPoint);
    xs_vec_mul_scalar(fMidPoint, 0.5, fMidPoint);
    xs_vec_sub(fMidPoint, fvPOVOrigin, fVector);
    xs_vec_normalize(fVector, fVector);
    vector_to_angle(fVector, fvPOVAngle);

    new Float:fDistance = get_distance_f(fvPOVOrigin, fMidPoint);

    for(new Float:fXShift = 60.0, Float:fYShift; fXShift >= -60.0; fXShift += -1.0)
    {
        xs_vec_copy(fvPOVAngle, fAngle);
        fAngle[0] += fXShift;

        for(fYShift = 60.0; fYShift >= -60.0; fYShift += -1.0)
        {
            fAngle[1] += fYShift;

            angle_vector(fAngle, ANGLEVECTOR_FORWARD, fVector);
            fLen = fDistance / floatmax( floatcos( xs_vec_angle(fMidPoint, fVector), degrees ), 1.0 );
            xs_vec_mul_scalar(fVector, fLen, fVector);
            xs_vec_add(fvPOVOrigin, fVector, fVector);

            engfunc(EngFunc_TraceLine, fvPOVOrigin, fVector, IGNORE_MONSTERS|IGNORE_GLASS|IGNORE_GLASS, 0, iTr2);

            get_tr2(iTr2, TR_Fraction, flFraction);

            if(flFraction >= 0.90)
            {
                free_tr2(iTr2);
                return 1;
            }
        }
    }

    free_tr2(iTr2);

    return 0;
} 


[sebxx4]

I also tried to merge artist's and Bugsy's code. The first one looks for spawn spots, and the second one check trace. But it shows all the time like there are no obstacles on the way from player to any spawn spot (displays "I see respawn!").

PHP Code:

#include <amxmodx>
#include <fakemeta>
 
new hook_ent_spawn;
new Float:ct_origin[32][3], ct_num;
new Float:t_origin[32][3], t_num;
 
public plugin_init()
{
    register_clcmd("say /test", "check_respzone");
    unregister_forward(FM_Spawn, hook_ent_spawn);
}

public plugin_precache()
    hook_ent_spawn = register_forward(FM_Spawn, "ent_spawn");

public ent_spawn(ent)
{
    if( !pev_valid(ent) ) 
        return FMRES_IGNORED;
        
    static classname[33];

    pev(ent, pev_classname, classname, charsmax(classname));
        
    if ( equal(classname, "info_player_start") && ct_num < sizeof(ct_origin) )
        pev(ent, pev_origin, ct_origin[ct_num++]);
    else if ( equal(classname, "info_player_deathmatch") && t_num < sizeof(t_origin) )
        pev(ent, pev_origin, t_origin[t_num++]);

    return FMRES_IGNORED;
}

public check_respzone(id)
{
    new bool:block = false;
    new Float:player_origin[3];

    pev(id, pev_origin, player_origin);

    for ( new a = 0; a < ct_num; a++ )
    {
        new tlTrace, Float:fFraction;

        engfunc(EngFunc_TraceLine, player_origin, ct_origin[a], IGNORE_MONSTERS, 0, tlTrace);
        get_tr2(tlTrace, TR_flFraction, fFraction);
        
        if ( fFraction != 1.0 )
        {
            block = true;
            break;
        }
    }

    if ( !block )
    {
        for ( new b = 0; b < t_num; b++ ) 
        {
            new tlTrace, Float:fFraction;
            
            engfunc(EngFunc_TraceLine, player_origin, t_origin[b], IGNORE_MONSTERS, 0, tlTrace);
            get_tr2(tlTrace, TR_flFraction, fFraction);
            
            if ( fFraction != 1.0 )
            {
                block = true;
                break;
            }
        }
    }

    if ( block )
        client_print(id, print_center, "I see respawn!");
    else
        client_print(id, print_center, "I dont see respawn!");
} 


[Natsheh]

You need to add the player view ofs to the origin, the code itself needs a bit testing, also you need to change the check where checking if the fraction greater than 90% to check if the point Vector is between the Zone boundaries.

[Natsheh]

Originally Posted by sebxx4 Thank you, I'll try both. Btw, will it check both buying zones?

No it will check only CT spawn AKA ( info_player_start )


T Spawn is info_player_deathmatch

[sebxx4]

Originally Posted by Natsheh you need to change the check where checking if the fraction greater than 90%

Thanks, now it seems to work fine

[Natsheh]

Originally Posted by sebxx4 Thanks, now it seems to work fine

There it should work better here...

Spoiler

PHP Code:

/* Sublime AMXX Editor v2.2 */

#include <amxmodx>
#include <xs>
#include <engine>
#include <fakemeta>

#define PLUGIN  "New Plug-In"
#define VERSION "1.0"
#define AUTHOR  "Author"

new g_sprite, Float:g_fSpot[3];

public plugin_precache()
{
    g_sprite = precache_model("sprites/laserbeam.spr");
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("say /test1", "check_bzs");
    register_clcmd("say /test2", "check_spot");
}

public check_spot(id)
{
    engfunc(EngFunc_SetOrigin, id, g_fSpot);
}

public check_bzs(id)
{
    new Float:flMaxBS[3], Float:flMinBS[3], Float:fOrigin[3], Float:fVOFS[3];
    pev(id, pev_origin, fOrigin);
    pev(id, pev_view_ofs, fVOFS);
    xs_vec_add(fOrigin, fVOFS, fOrigin);
    CreateBoundingBoxAroundEntities(get_user_team(id) == 2 ? "info_player_deathmatch":"info_player_start", flMaxBS, flMinBS);

    if ( SCAN_Zone_Visuality(fOrigin, flMaxBS, flMinBS) )
        client_print(id, print_center, "I see buying zone!");
    else
        client_print(id, print_center, "I don't see buying zone!");

    return PLUGIN_HANDLED;
}


CreateBoundingBoxAroundEntities(const szEntClassName[32], Float:flMaxBS[3], Float:flMinBS[3])
{
    new ent = -1, Float:fEntMaxBS[3], Float:fEntMinBS[3];
    // find the max/mins coords of the zone.
    while( (ent = find_ent_by_class(ent, szEntClassName)) > 0)
    {
        pev(ent, pev_absmax, fEntMaxBS);
        pev(ent, pev_absmin, fEntMinBS);

        flMaxBS[0] = floatmax(fEntMaxBS[0], flMaxBS[0]);
        flMaxBS[1] = floatmax(fEntMaxBS[1], flMaxBS[1]);
        flMaxBS[2] = floatmax(fEntMaxBS[2], flMaxBS[2]);

        flMinBS[0] = floatmin(fEntMinBS[0], flMinBS[0]);
        flMinBS[1] = floatmin(fEntMinBS[1], flMinBS[1]);
        flMinBS[2] = floatmin(fEntMinBS[2], flMinBS[2]);
    }

    return 0;
}

SCAN_Zone_Visuality(const Float:fvPOVOrigin[3], const Float:fMaxBS[3], const Float:fMinBS[3])
{
    if(IsPointInsideZone(fvPOVOrigin, fMaxBS, fMinBS))
    {
        xs_vec_copy(fvPOVOrigin, g_fSpot);
        client_print(0, print_chat, "POV INSIDE ZONE # %.2f %.2f %.2f", fvPOVOrigin[0], fvPOVOrigin[1], fvPOVOrigin[2]);
        return 1;
    }

    new Float:fvPOVAngle[3], Float:fAngle[3], Float:fVector[3], Float:fMidPoint[3], Float:fLen, iTr2 = create_tr2();
    xs_vec_add(fMaxBS, fMinBS, fMidPoint);
    xs_vec_mul_scalar(fMidPoint, 0.5, fMidPoint);
    xs_vec_sub(fMidPoint, fvPOVOrigin, fVector);
    xs_vec_normalize(fVector, fVector);
    vector_to_angle(fVector, fvPOVAngle);

    new Float:fDistance = get_distance_f(fvPOVOrigin, fMidPoint);

    for(new Float:fXShift = 60.0, Float:fYShift; fXShift >= -60.0; fXShift += -1.0)
    {
        xs_vec_copy(fvPOVAngle, fAngle);
        fAngle[0] += fXShift;

        for(fYShift = 60.0; fYShift >= -60.0; fYShift += -1.0)
        {
            fAngle[1] += fYShift;

            angle_vector(fAngle, ANGLEVECTOR_FORWARD, fVector);
            fLen = fDistance / floatmax( floatcos( xs_vec_angle(fMidPoint, fVector), degrees ), 1.0 );
            xs_vec_mul_scalar(fVector, fLen, fVector);
            xs_vec_add(fvPOVOrigin, fVector, fVector);

            engfunc(EngFunc_TraceLine, fvPOVOrigin, fVector, IGNORE_MONSTERS|IGNORE_GLASS|IGNORE_GLASS, -1, iTr2);

            get_tr2(iTr2, TR_EndPos, fVector);

            if(IsPointInsideZone(fVector, fMaxBS, fMinBS))
            {
                //create_line(fvPOVOrigin, fVector, g_sprite)
                xs_vec_copy(fVector, g_fSpot);
                client_print(0, print_chat, "%.2f %.2f %.2f", fVector[0], fVector[1], fVector[2]);
                free_tr2(iTr2);
                return 1;
            }
        }
    }

    free_tr2(iTr2);
    return 0;
}

bool:IsPointInsideZone(const Float:fPoint[3], const Float:fMaxBS[3], const Float:fMinBS[3])
{
    if( (fMinBS[0] <= fPoint[0] <= fMaxBS[0]) &&
    (fMinBS[1] <= fPoint[1] <= fMaxBS[1]) &&
    (fMinBS[2] <= fPoint[2] <= fMaxBS[2]) )
    {
        return true;
    }

    return false;
}

create_line(const Float:fStart[3], const Float:fEnd[3], sprite)
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
    write_byte(TE_BEAMPOINTS)
    engfunc(EngFunc_WriteCoord, fStart[0]);
    engfunc(EngFunc_WriteCoord, fStart[1]);
    engfunc(EngFunc_WriteCoord, fStart[2]);
    engfunc(EngFunc_WriteCoord, fEnd[0]);
    engfunc(EngFunc_WriteCoord, fEnd[1]);
    engfunc(EngFunc_WriteCoord, fEnd[2]);
    write_short(sprite)
    write_byte(0) // starting frame
    write_byte(10) // frame rate
    write_byte(30); // life 3 seconds = 30
    write_byte(10) // width in 0.1
    write_byte(1) // noise in 0.01
    write_byte(0) // red
    write_byte(255) // green
    write_byte(0) // blue
    write_byte(255) // brightness
    write_byte(1) // scroll speed in 0.1
    message_end()
} 


[sebxx4]

Thanks, I'll give it a try