[TF2] Changing building ownership

Pelipoika · **Author**

Heres a thing for properly changing a buildings ownership:

PHP Code:


			
#include <sdktools>

#pragma newdecls required

Handle g_hSDKRemoveObject;

public Plugin myinfo = 
{
    name = "[TF2] Building Ownage",
    author = "Pelipoika",
    description = "",
    version = "1.0",
    url = "http://www.sourcemod.net/plugins.php?author=Pelipoika&search=1"
};

public void OnPluginStart()
{
    Handle hConfig = LoadGameConfigFile("tf2.setbuilder");

    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(hConfig, SDKConf_Signature, "CTFPlayer::RemoveObject");
    PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);    //CBaseObject
    if ((g_hSDKRemoveObject = EndPrepSDKCall()) == INVALID_HANDLE) SetFailState("Failed To create SDKCall for CTFPlayer::RemoveObject signature");
    
    delete hConfig;
    
    RegAdminCmd("sm_ownaimbuilding", Command_OwnAim, ADMFLAG_ROOT);
}

public Action Command_OwnAim(int client, int args)
{
    int obj = GetClientAimTarget(client, false);
    if(IsValidEntity(obj))
    {
        SetBuilder(obj, client);
        PrintToChat(client, "Building (%i) is now yours %N", obj, client);
    }

    return Plugin_Handled;
}

stock void SetBuilder(int obj, int client)
{
    int iBuilder = GetEntPropEnt(obj, Prop_Send, "m_hBuilder");
    bool bMiniBuilding = GetEntProp(obj, Prop_Send, "m_bMiniBuilding") || GetEntProp(obj, Prop_Send, "m_bDisposableBuilding");

    if(iBuilder > 0 && iBuilder <= MaxClients && IsClientInGame(iBuilder))
        SDKCall(g_hSDKRemoveObject, iBuilder, obj);
    
    SetEntPropEnt(obj, Prop_Send, "m_hBuilder", -1);
    AcceptEntityInput(obj, "SetBuilder", client);
    SetEntPropEnt(obj, Prop_Send, "m_hBuilder", client);
    
    SetVariantInt(GetClientTeam(client));
    AcceptEntityInput(obj, "SetTeam");
    
    SetEntProp(obj, Prop_Send, "m_nSkin", bMiniBuilding ? GetClientTeam(client) : GetClientTeam(client) - 2);
}

tf2.setbuilder.txt

luki1412 · 05-27-2016 , 12:35 Re: [TF2] Changing building ownership

so

Code:

AcceptEntityInput(obj, "SetBuilder", client);

and

Code:

SetEntPropEnt(obj, Prop_Send, "m_hBuilder", client);

are both needed?

Also, where is

Code:

SetEntProp(obj, Prop_Send, "m_iTeamNum", team);

and

Code:

SetVariantInt(team);
AcceptEntityInput(obj, "TeamNum");

?

Pelipoika · 05-27-2016 , 12:50 Re: [TF2] Changing building ownership

Quote:

Originally Posted by luki1412

so

Code:

AcceptEntityInput(obj, "SetBuilder", client);

and

Code:

SetEntPropEnt(obj, Prop_Send, "m_hBuilder", client);

are both needed?
?

Yes

Quote:

Originally Posted by luki1412

Also, where is

Code:

SetEntProp(obj, Prop_Send, "m_iTeamNum", team);

and

Code:

SetVariantInt(team);
AcceptEntityInput(obj, "TeamNum");

?

What?

luki1412 · 05-27-2016 , 12:53 Re: [TF2] Changing building ownership

Quote:

Originally Posted by Pelipoika

What?

The second part should be for setting the team or is it not needed?

Pelipoika · 05-27-2016 , 13:19 Re: [TF2] Changing building ownership

Quote:

Originally Posted by luki1412

The second part should be for setting the team or is it not needed?

The stock has already been tested and it works