[ssproxima]

I want a little modification in this following code, the plugin works perfect but what I want is suppose a player after connecting to the server changes the name to one of the # or % exploit the plugin should remove the symbol in his name and also if he tries to use command say/say_team the player should be kicked from server with a message "Server Crasher Exploit Detected"

Source

https://forums.alliedmods.net/showpo...6&postcount=26

#include <amxmodx>

new const gBlockcmd[][]= 
{
      "%",
      "#",
      "#1Cstike"
}

public client_putinserver(id)
{
    if (is_user_connected(id))
    {
        new szName[32];
        get_user_name(id, szName, 31);
        for(new i = 0; i < sizeof(gBlockcmd); i++) {
            if(containi(szName, gBlockcmd[i]) != -1) {
                server_cmd("kick #%d ^"Cheat Detected^"", get_user_userid(id));
                return 1;
            }
        }
        
    }
    return 0;
}

[indraraj striker]

use this to get rid of #cstrike_lablel and %s
https://forums.alliedmods.net/showpo...7&postcount=28

[ssproxima]

Originally Posted by indraraj striker use this to get rid of #cstrike_lablel and %s https://forums.alliedmods.net/showpo...7&postcount=28

I had used it but when we use HLStatsx:CE plugin the server still crashes.

[Bugsy]

So if the players name has those characters, you want them replaced with blank spaces or what?

If the player says any of those values in chat, you want them kicked?

[ssproxima]

Originally Posted by Bugsy So if the players name has those characters, you want them replaced with blank spaces or what? If the player says any of those values in chat, you want them kicked?

Absolutely you got it right....
Not only in chat but also using console say/say_team command

[Bugsy]

PHP Code:

#include <amxmodx>
#include <fakemeta>

new const Version[] = "0.3";

enum BlockAction
{
    baKick,
    baReplace
}

new const gBlockcmd[][]= 
{
    "#1Cstike",
    "d #Spec_Help_Text #Spec_Duck",
    "%",
    "#"
};

new const gReplaceWith[] = "X";

public plugin_init()
{
    register_plugin( "Exploit Detector" , "bugsy" , Version );
    
    register_forward( FM_ClientUserInfoChanged , "ClientUserInfoChanged" );
    
    register_clcmd( "say" , "CheckSay" );
    register_clcmd( "say_team" , "CheckSay" );
}

public client_disconnect( id )
{
    remove_task( id );
}

public ClientUserInfoChanged(id)
{
    static const name[] = "name";
    new szOldName[ 32 ] , szNewName[ 32 ];
    
    pev( id , pev_netname , szOldName , charsmax( szOldName ) );
    
    if ( szOldName[ 0 ] )
    {
        get_user_info( id , name , szNewName , charsmax( szNewName ) );
        
        if ( !equal( szOldName , szNewName ) )
        {
            if ( CheckForBlockCmd( id , szNewName , charsmax( szNewName ) , baReplace , false ) )
                return FMRES_HANDLED;
        }
    }
    else if ( get_user_info( id , name , szNewName , charsmax( szNewName ) ) )
    {
        if ( CheckForBlockCmd( id , szNewName , charsmax( szNewName ) , baKick , true ) )
            return FMRES_HANDLED;
    }
    
    return FMRES_IGNORED;
}

public CheckSay( id )
{
    static szMsg[ 128 ];
    
    read_args( szMsg , charsmax( szMsg ) );
    CheckForBlockCmd( id , szMsg , charsmax( szMsg ) , baKick , false);
}

public CheckForBlockCmd( id , szMsg[] , iMaxChars , BlockAction:baAction , bool:bDelayKick )
{
    new bool:bFound;
    
    for( new i = 0 ; i < sizeof( gBlockcmd ) ; i++ ) 
    {
        if ( containi( szMsg , gBlockcmd[ i ] ) != -1 ) 
        {
            switch ( baAction )
            {
                case baKick:
                {
                    if ( bDelayKick == true )
                    {
                        set_task( 3.0 , "KickPlayer" , id  );
                    }
                    else
                    {
                        KickPlayer( id );
                    }
                    break;
                }
                case baReplace:
                {
                    replace_all( szMsg , iMaxChars , gBlockcmd[ i ] , gReplaceWith );
                    bFound = true;
                }
            }
        }
    }
    
    if ( bFound )
        set_user_info( id , "name" , szMsg );
        
    return bFound;
}

public KickPlayer( id )
{
    server_cmd( "kick #%d ^"Cheat Detected^"" , get_user_userid( id ) );
} 


[ssproxima]

Thank you very much it is working fine now but the only thing that is missing is why is it not kicking the player having #,% etc. in name while connecting instead of changing the characters to "X". Could you please make it possible and I think this plugin should be included in amxmodx basic package as this exploit is common and every one faces it.

[Bugsy]

Code is updated, try now.

[ssproxima]

nop its not working and now it is also not replacing characters with X but say command kick works fine

[Bugsy]

Ok, I will fix when I get home.