[SomewhereLost]

Hello,

Im trying to make a special effects when a certain command is used, a thunderclap for example when amx_slay is used on a player, doesnt matter if its used by an admin or a server itself.

Any help appreciated.

[OciXCrom]

This plugin's code can help you - https://forums.alliedmods.net/showthread.php?t=924
PS: if you're asking for help about scripting, you should obviously post in the scripting help section.

[SomewhereLost]

Originally Posted by OciXCrom This plugin's code can help you - https://forums.alliedmods.net/showthread.php?t=924 PS: if you're asking for help about scripting, you should obviously post in the scripting help section.

Sort of, but I havent got anything done yet (correctly) as all the approaches were completely wrong so I posted in requests.

Making a thunder and those effects isnt really an issue, its all about the command used by the server/admin.

[fysiks]

Originally Posted by SomewhereLost Sort of, but I havent got anything done yet (correctly) as all the approaches were completely wrong so I posted in requests.

If you aren't requesting a plugin and you are attempting to write your own code then you should post in the Scripting Help section. Make sure that you post the code that you tried.

Originally Posted by SomewhereLost Making a thunder and those effects isnt really an issue, its all about the command used by the server/admin.

You literally asked for how to make thunder on command and then said that's not really the issue??

[SomewhereLost]

Originally Posted by fysiks If you aren't requesting a plugin and you are attempting to write your own code then you should post in the Scripting Help section. Make sure that you post the code that you tried. You literally asked for how to make thunder on command and then said that's not really the issue??

No offense but I think you lack some logic as everytime I see you post, there is literally 0 help but only "just to post anything" that doesnt even make a slight bit of a sense.

I already mentioned that all my codes were not even close, so if you think about a little, you will get the idea that I am requesting it, if not a full plugin but at least the part of it so I can see how to approach it.

About thunder, I said thunder isnt really an issue because the plugin OciXCrom provided there certainly are those kind of effects I am looking for and I also mentioned that the only problem is the command executed on a player.

Dont get me wrong here, I know you are not obligated to help anyone if you dont want to but you could do me a favor and not post on my threads as long as you do not provide me some help, we already had this kind of a talk last time.

[generalmemer]

Originally Posted by SomewhereLost Hello, Im trying to make a special effects when a certain command is used, a thunderclap for example when amx_slay is used on a player, doesnt matter if its used by an admin or a server itself. Any help appreciated.

Its not hard at all to do. You basically just get player origin and there you go

This will create a small effect when amx_slay is successfully executed to any player, it does not work with amxmodmenu

Note: it has to be above admincmd.amxx in your plugins config (or you can edit this effect inside admincmd.sma)

Tell me if its what you're trying to do or not

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

new g_iShockwave;

public plugin_init() 
{
    register_concmd("amx_slay", "ForwardSlayListener");
}

public plugin_precache()
{
    g_iShockwave = precache_model("sprites/shockwave.spr");
}

public ForwardSlayListener(id)
{
    if( ~get_user_flags(id) & ADMIN_SLAY )
        return PLUGIN_HANDLED;
    
    new sArg[32];
    read_argv(1, sArg, 31);
    
    new iPlayer = cmd_target(id, sArg, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF | CMDTARGET_ONLY_ALIVE);
    
    if (!iPlayer)
        return PLUGIN_HANDLED;
        
    new Float:fOrigin[3];
    pev(iPlayer, pev_origin, fOrigin);
    
    new iOrigin[3];
    iOrigin[0] = floatround( fOrigin[0] );
    iOrigin[1] = floatround( fOrigin[1] );
    iOrigin[2] = floatround( fOrigin[2] );

    message_begin    (MSG_PAS, SVC_TEMPENTITY, iOrigin);
    write_byte    (21);
    write_coord    ( iOrigin[0] );
    write_coord    ( iOrigin[1] );
    write_coord    ( iOrigin[2] + 16 );
    write_coord    ( iOrigin[0] );
    write_coord    ( iOrigin[1] );
    write_coord    ( iOrigin[2] + 16 + 348 );
    write_short    (g_iShockwave);

    write_byte    (0);     //Startframe
    write_byte    (0);     //Framerate
    write_byte    (3);     //Life
    write_byte    (30);     //Width
    write_byte    (0);      //Noise

    write_byte( random_num(0, 250) );
    write_byte( random_num(0, 250) );
    write_byte( random_num(0, 250) );

    write_byte    (255);     //Brightness
    write_byte    (0);     //Speed
    message_end    ();

    message_begin    (MSG_PAS, SVC_TEMPENTITY, iOrigin);
    write_byte    (21);
    write_coord    ( iOrigin[0] );
    write_coord    ( iOrigin[1] );
    write_coord    ( iOrigin[2] + 16 );
    write_coord    ( iOrigin[0] );
    write_coord    ( iOrigin[1] );
    write_coord    ( iOrigin[2] + 16 + (384 / 2) );
    write_short    (g_iShockwave);

    write_byte    (0);     //Startframe
    write_byte    (0);     //Framerate
    write_byte    (3);     //Life
    write_byte    (30);     //Width
    write_byte    (0);     //Noise

    write_byte( 256 - random_num(0, 250) );
    write_byte( 256 - random_num(0, 250) );
    write_byte( 256 - random_num(0, 250) );
        
    write_byte    (255);     //Brightness
    write_byte    (0);     //Speed
    message_end();
    
    return PLUGIN_CONTINUE;
} 


[SomewhereLost]

Yes that is exactly what I was trying, now just few additions like thunder with emit_sound instead of a shockwave but I dont think this would work if the command is executed by the server.

[generalmemer]

Originally Posted by SomewhereLost Yes that is exactly what I was trying, now just few additions like thunder with emit_sound instead of a shockwave but I dont think this would work if the command is executed by the server.

It will work

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>

new g_iThunder;
new const sThunder[] = "ambience/thunder_clap.wav";

public plugin_init() 
{
    register_concmd("amx_slay", "ForwardSlayListener");
}

public plugin_precache()
{
    precache_sound(sThunder);
    g_iThunder = precache_model("sprites/lgtning.spr");
}

public ForwardSlayListener(id)
{
    if( ~get_user_flags(id) & ADMIN_SLAY )
        return PLUGIN_HANDLED;
    
    new sArg[32];
    read_argv(1, sArg, 31);
    
    new iPlayer = cmd_target(id, sArg, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF | CMDTARGET_ONLY_ALIVE);
    
    if (!iPlayer)
        return PLUGIN_HANDLED;
    
    new iOrigin[3], iStart[3];
    get_user_origin(iPlayer, iOrigin);
    
    iOrigin[2] -= 26;
    iStart[0] = iOrigin[0] + 150;
    iStart[1] = iOrigin[1] + 150;
    iStart[2] = iOrigin[2] + 800;

    message_begin(MSG_BROADCAST, SVC_TEMPENTITY); 
    write_byte(TE_BEAMPOINTS); 
    
    write_coord( iStart[0] ); 
    write_coord( iStart[1] ); 
    write_coord( iStart[2] ); 
    write_coord( iOrigin[0] ); 
    write_coord( iOrigin[1] ); 
    write_coord( iOrigin[2] ); 
    
    write_short(g_iThunder); 
    write_byte(1);
    write_byte(5);
    write_byte(7);
    write_byte(20);
    write_byte(30);
    write_byte(200); 
    write_byte(200);
    write_byte(200);
    write_byte(200);
    write_byte(200);
    
    message_end();
    
    message_begin(MSG_PVS, SVC_TEMPENTITY, iOrigin);
    write_byte(TE_SPARKS);
    
    write_coord( iOrigin[0] );
    write_coord( iOrigin[1] );
    write_coord( iOrigin[2] );
    
    message_end();
    
    emit_sound(iPlayer, CHAN_STATIC, sThunder, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
    
    return PLUGIN_CONTINUE;
} 


[generalmemer]

Here is another thunder effect

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>

new g_iThunder;
new const sThunder[] = "ambience/port_suckin1.wav";

public plugin_init() 
{
    register_concmd("amx_slay", "ForwardSlayListener");
}

public plugin_precache()
{
    precache_sound(sThunder);
    g_iThunder = precache_model("sprites/lgtning.spr");
}

public ForwardSlayListener(id)
{
    if( ~get_user_flags(id) & ADMIN_SLAY )
        return PLUGIN_HANDLED;
    
    new sArg[32];
    read_argv(1, sArg, 31);
    
    new iPlayer = cmd_target(id, sArg, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF | CMDTARGET_ONLY_ALIVE);
    
    if (!iPlayer)
        return PLUGIN_HANDLED;

    ForwardThunderEffect(iPlayer);
    emit_sound(iPlayer, CHAN_STATIC, sThunder, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
    
    return PLUGIN_CONTINUE;
}

public ForwardThunderEffect(id)
{
    new iPlayerVec[3];
    get_user_origin(id,iPlayerVec);
    
    for (new k = 0; k < 10; k++)
    {
        for (new i = 0; i < 7; i++)
        {
            new iRandomVec[3];
            new iHighVec[3];
            
            iRandomVec[2] = iPlayerVec[2] - 30;
            iRandomVec[0] = iPlayerVec[0] + ( random_num(-200, 200) );
            iRandomVec[1] = iPlayerVec[1] + ( random_num(-200, 200) );
        
            iHighVec[0] = iRandomVec[0];
            iHighVec[1] = iRandomVec[1];
            iHighVec[2] = iRandomVec[2] + 300;
        
            ForwardBeamPoints(iRandomVec, iHighVec, g_iThunder, 1, 10, 10, 50, 100, 0, 0, 255, 100, 100);
        }
        return PLUGIN_HANDLED
    }
    return PLUGIN_HANDLED
}

public ForwardBeamPoints( iStart[3], iEnd[3], iSprite, iStartFrame, iFramerate, iLife, iWidth, iAmplitude, iRed, iGreen, iBlue, iBrightness, iSpeed )
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
    write_byte(0);
    
    write_coord( iStart[0] );
    write_coord( iStart[1] );
    write_coord( iStart[2] );
    write_coord( iEnd[0] );
    write_coord( iEnd[1] );
    write_coord( iEnd[2] );
    
    write_short(iSprite);
    write_byte(iStartFrame);
    write_byte(iFramerate);
    write_byte(iLife);
    write_byte(iWidth);
    write_byte(iAmplitude);
    write_byte(iRed);
    write_byte(iGreen);
    write_byte(iBlue);
    write_byte(iBrightness);
    write_byte(iSpeed);
    message_end();
} 


[Natsheh]

PHP Code:

if( ~get_user_flags(id) & ADMIN_SLAY ) 
        return PLUGIN_HANDLED 


PHP Code:

if( !(get_user_flags(id) & ADMIN_SLAY) ) 
        return PLUGIN_HANDLED