|
Veteran Member
|
03-26-2010
, 07:59
[CON y SIN ZP] Crear Cuentas y guardado de Datos.
|
#1
|
ATENCIÓN: No doy más soporte a esto y probablemente esté desactualizado y genere errores!
Aprendizaje necesario: Básico sobre algunas Funciones.
Aprendizaje extra: Aprenderse el Include del FVault que está posteado en este Post.
Bueno, no hay nada mas que decir, esta todo explicado en el Codigo.
¡ Sin ZombiePlague !
PHP Code:
#include < amxmodx >
#include < fakemeta >
#include < fvault >
#include < cstrike >
// Creamos variables globales
new SZ_Password[ 192 ]
new SZ_Password_T[ 33 ][ 192 ]
new Registrado[ 33 ]
new BadPassword[ 33 ]
new const Vault[] = "_Datos" // Nombre del Archivo donde se guardaran los Datos.
public plugin_init( )
{
register_plugin( "Tutorial", "1.0", "Kiske" )
register_forward( FM_ClientUserInfoChanged, "FWClientUserInfoChanged" ) // Si no me equivoco esta forward se llama cuando el usuario cambia algo de su setinfo.
register_clcmd( "say /registrarse", "CMDRegistrarse" )
register_clcmd( "IntroducirContrasenia", "CMDIntroducirContrasenia" )
}
public client_disconnect( Index )
Save( Index ) // Esta función ponganla en todos los lugares donde quieren que se guarden sus cosas.
public client_putinserver( Index )
{
Registrado[ Index ] = 0
BadPassword[ Index ] = 0
Load( Index )
}
public CMDRegistrarse( Index )
{
if( Registrado[ Index ] || BadPassword[ Index ] )
return PLUGIN_HANDLED;
client_cmd( Index, "messagemode IntroducirContrasenia" )
return PLUGIN_CONTINUE;
}
public CMDIntroducirContrasenia( Index )
{
read_args( SZ_Password, 191 ) // Ponemos en la Variable SZ_Password lo que escribió como Contraseña
remove_quotes( SZ_Password ) // Analiza lo que escribimos
trim( SZ_Password ) // Esta opción es para remover los ESPACIOS ( si es que puso ) al principio y al final de lo que escribió
if( equal( SZ_Password, "" ) || contain( SZ_Password, " ") != -1) // En la primer parte, verificamos si lo que ingresó contiene algo......y en la segunda parte verificamos si lo que ingresó tiene espacios, si coincide alguna de las dos cosas, no se lo aceptamos.
return PLUGIN_HANDLED;
else // Si se llama esta parte, quiere decir que lo que ingresó contiene algo y no tiene espacios.
{
client_cmd( Index, "setinfo _pass ^"%s^"", SZ_Password ) // Creamos una Setinfo al jugador con el prefijo _pass y la contraseña que ingresó. Ustedes si quieren cambienle el prefijo.
Registrado[ Index ] = 1
// Guardamos el Nombre, ls Password y el Dinero actual
static SZ_Name[ 32 ], SZ_Data[ 512 ]
get_user_name( Index, SZ_Name, 31 )
// Si quieren agregar mas Datos solo vayan aumentando el Parametro y las Variables.
formatex( SZ_Data, charsmax( SZ_Data ), "%s %d", SZ_Password, cs_get_user_money( Index ) )
// Esta función del FVault sirve para setear datos ( Recomiendo: Que lean el Include del FVault que está posteado al final de este Post )
fvault_set_data( Vault, SZ_Name, SZ_Data )
// Fixeamos un Error ya que si es la Primera vez que se registra, cuando llame al Save no aparecerá ninguna Password, esto lo Fixea.
SZ_Password_T[ Index ] = SZ_Password
return PLUGIN_HANDLED;
}
return PLUGIN_CONTINUE;
}
public Save( Index )
{
if( !Registrado[ Index ] || BadPassword[ Index ] ) // Si NO esta registrado, o si tiene la Contraseña Incorrecta, no le guardamos nada.
return PLUGIN_HANDLED;
// Voy a dar un Ejemplo en el caso de que quieran guardar Dinero o lo que sea.
static SZ_Data[ 512 ], SZ_Name[ 32 ]
formatex( SZ_Data, charsmax( SZ_Data ), "%s %d", SZ_Password_T[ Index ], cs_get_user_money( Index ) )
get_user_name( Index, SZ_Name, 31 )
fvault_set_data( Vault, SZ_Name, SZ_Data )
return PLUGIN_CONTINUE;
}
public Load( Index )
{
static SZ_Data[ 512 ], SZ_Name[ 32 ], SETINFO_Password[ 191 ], VAULT_Password[ 191 ], Dinero[ 11 ]
get_user_name( Index, SZ_Name, 31 )
get_user_info( Index, "_pass", SETINFO_Password, 190 ) // Seteamos en SETINFO_Password lo que tiene como Setinfo con el prefijo _pass
if( !fvault_get_data( Vault, SZ_Name, SZ_Data, charsmax( SZ_Data ) ) ) // Detectamos si NO existe su Nombre y Data en el Vault. En ese caso, les dejo a su Creatividad para que piensen.
return 0;
Registrado[ Index ] = 1
// El Nombre y la Password JAMÁS la cargen.
// Voy a dar un Ejemplo en el caso de que quieran cargar Dinero o lo que sea.
parse( SZ_Data, VAULT_Password, 190, Dinero, 10 ) // La función PARSE, separa los Datos 1 por 1. Si guardamos la Password primero, y el Dinero despues, entonces este Parse está bien, obviamente tiene que seguir el Orden en el que se guardó.
if( equal( SETINFO_Password, VAULT_Password ) ) // Si la Contraseña del Jugador coincide con la Registrada de su Nick, cargamos sus Datos.
{
// Fixeamos un Error para que no reemplaze la Password Registrada por alguna que puede llegar a cambiar el adentro del Server.
SZ_Password_T[ Index ] = SETINFO_Password
// Cargamos el Dinero. ( Numero )
cs_set_user_money( Index, str_to_num( Dinero ) )
// Si cargan una Variable es así:
// Money = str_to_num( Dinero )
// Y si cargan una Native como en el caso de cs_set_user_money, bueno ya esta puesto arriba.
// Ejemplo de: Cargar un Float
// Variable_De_Float[ Index ] = str_to_float( Float )
return 2;
}
else // Si la Contraseña del Jugador NO coincide con la Registrada de su Nick, podemos Kickearlo, mandarlo a Spect, un menú, les dejo su creatividad...
{
BadPassword[ Index ] = 1
//....
}
return 1;
}
public FWClientUserInfoChanged( Index, Buffer )
{
if( !is_user_connected( Index ) )
return FMRES_IGNORED;
static NickName[32], NickOld[32]; get_user_name( Index, NickOld, 31 )
engfunc( EngFunc_InfoKeyValue, Buffer, "name", NickName, 31 ) // Si tampoco me confundo, esto obtiene el valor "name" de su setinfo.
if( equal( NickName, NickOld ) )
return FMRES_IGNORED;
engfunc( EngFunc_SetClientKeyValue, Index, Buffer, "name", NickOld ) // Le volvemos a poner el nick viejo para que no se lo pueda cambiar.
client_cmd( Index, "name ^"%s^"; setinfo name ^"%s^"", NickOld, NickOld )
return FMRES_SUPERCEDE;
}
Datos Extras:
- Una vez que te Registraste, no te podes volver a Registrar CON el mismo NICK.
- Si tenes la Password incorrecta, les dejo a su creatividad lo que quieran hacer, ahi ya dice donde es que le da la Password incorrecta, obviamente no te podes volver a Registrar.
- Cuando se te guardan los Datos por primera vez es algo asi: "Kiske" "PendejoAlcahuete 800"
- Cuando me desconecte, que se guardan los Datos, se me guardaron así: "Kiske" "PendejoAlcahuete 4600", obviamente porque gane Dinero.
- Testee todos los Bugs posibles, y 0 errores.
¡ Con ZombiePlague y con Menú de Registro y Logeo !
PHP Code:
#include < fvault >
// Creamos variables globales
new SZ_Password[ 33 ][ 192 ]
new SZ_Password_T[ 33 ][ 192 ]
new Registrado[ 33 ]
new BadPassword[ 33 ]
new const Vault[] = "_Datos" // Nombre del Archivo donde se guardaran los Datos.
public plugin_init( )
{
register_clcmd( "say /registrarse", "CMDRegistrarse" )
register_clcmd( "IntroducirContrasenia", "CMDIntroducirContrasenia" )
}
public client_disconnect( Index )
Save( Index ) // Esta función ponganla en todos los lugares donde quieren que se guarden sus cosas.
public client_putinserver( Index )
{
Registrado[ Index ] = 0
BadPassword[ Index ] = 0
set_task( 0.1, "clcmd_changeteam", Index ) // Les va a aparecer el Menú igual por más que tengan MOTD y esas mierdas.
// Esta función ponganla abajo del reset_vars y abajo del statssave.
Load( Index )
}
// ATENCIÓN ACA !!:
// En la Función que se llama: clcmd_changeteam(id) van a reemplazar todo lo que tengan por esto, a continuacion les explico:
public clcmd_changeteam( Index )
{
static Team; Team = get_user_team( Index )
if( ( Team == 0 || Team == 3 ) && !BadPassword[ Index ] && Registrado[ Index ] ) // Si esta en el Team UNNASIGNED o SPECTATOR, si tiene bien la Password y si está Registrado...
return PLUGIN_CONTINUE; // ... le muestra el Menú de Teams.
else if( !Registrado[ Index ] || BadPassword[ Index ] ) // Si no está Registrado o tiene mal la Password, le mostramos el Menú de Registro y Login.
{
static Menu, SZ_Items[ 32 ]
Menu = menu_create( "\yTitulo", "MenuBadPassword" )
formatex( SZ_Items, 31, "%s", !Registrado[ Index ] ? "Registrar nueva Cuenta" : "Ingresar Contraseña" )
menu_additem( Menu, SZ_Items, "1" ) //* Si no está Registrado la Opción esta será: "Registrar nueva Cuenta", de lo contrario será: "Ingresar Contraseña".
menu_setprop( Menu, MPROP_EXITNAME, "Salir" )
menu_display( Index, Menu, 0 )
return PLUGIN_HANDLED;
}
else
show_menu_game( Index ) // Si le cambiaron el nombre a esta función, también deben cambiarselo acá.
return PLUGIN_HANDLED;
}
public CMDRegistrarse( Index )
{
if( Registrado[ Index ] || BadPassword[ Index ] )
return PLUGIN_HANDLED;
client_cmd( Index, "messagemode IntroducirContrasenia" )
return PLUGIN_CONTINUE;
}
public CMDIntroducirContrasenia( Index )
{
read_args( SZ_Password[ Index ], charsmax( SZ_Password[ ] ) ) // Ponemos en la Variable SZ_Password lo que escribió como Contraseña
remove_quotes( SZ_Password[ Index ] ) // Analiza lo que escribimos
trim( SZ_Password[ Index ] ) // Esta opción es para remover los ESPACIOS ( si es que puso ) al principio y al final de lo que escribió
if( equal( SZ_Password[ Index ], "" ) || contain( SZ_Password[ Index ], " ") != -1) // En la primer parte, verificamos si lo que ingresó contiene algo......y en la segunda parte verificamos si lo que ingresó tiene espacios, si coincide alguna de las dos cosas, no se lo aceptamos.
return PLUGIN_HANDLED;
else if( BadPassword[ Index ] ) // Si se llama esta parte, quiere decir que lo que ingresó contiene algo y no tiene espacios, pero también quiere decir que está Introduciendo la Contraseña para Logearse.
{
static SZ_Data[ 512 ], SZ_Name[ 32 ], VAULT_Password[ 191 ]
get_user_name( Index, SZ_Name, 31 )
if( !fvault_get_data( Vault, SZ_Name, SZ_Data, charsmax( SZ_Data ) ) )
return 0;
parse( SZ_Data, VAULT_Password, 190 )
if( equal( SZ_Password[ Index ], VAULT_Password ) ) // Si lo que Ingreso coincide con la Password Registrada, lo mandamos a la Selección de Teams.
{
client_cmd( Index, "setinfo _pass ^"%s^"", SZ_Password[ Index ] )
BadPassword[ Index ] = 0
Load( Index )
// Fixeamos un Error ya que si es la Primera vez que se registra, cuando llame al Save no aparecerá ninguna Password, esto lo Fixea.
SZ_Password_T[ Index ] = SZ_Password[ Index ]
return PLUGIN_HANDLED;
}
return PLUGIN_HANDLED;
}
else // Si se llama esta parte, quiere decir que lo que ingresó contiene algo y no tiene espacios.
{
client_cmd( Index, "setinfo _pass ^"%s^"", SZ_Password[ Index ] ) // Creamos una Setinfo al jugador con el prefijo _pass y la contraseña que ingresó. Ustedes si quieren cambienle el prefijo.
Registrado[ Index ] = 1
// Guardamos el Nombre, ls Password y los AmmoPacks actuales
static SZ_Name[ 32 ], SZ_Data[ 512 ]
get_user_name( Index, SZ_Name, 31 )
// Si quieren agregar mas Datos solo vayan aumentando los parametros con su respectiva variable.
formatex( SZ_Data, charsmax( SZ_Data ), "%s %d", SZ_Password[ Index ], g_ammopacks[Index] )
// Esta función del FVault sirve para setear datos ( Recomiendo: Que lean el Include del FVault que está posteado al final de este Post )
fvault_set_data( Vault, SZ_Name, SZ_Data )
// Fixeamos un Error ya que si es la Primera vez que se registra, cuando llame al Save no aparecerá ninguna Password, esto lo Fixea.
SZ_Password_T[ Index ] = SZ_Password[ Index ]
return PLUGIN_HANDLED;
}
return PLUGIN_CONTINUE;
}
public Save( Index )
{
if( !Registrado[ Index ] || BadPassword[ Index ] ) // Si NO esta registrado, o si tiene la Contraseña Incorrecta, no le guardamos nada.
return PLUGIN_HANDLED;
static SZ_Data[ 512 ], SZ_Name[ 32 ]
// Guardamos la Data.
formatex( SZ_Data, charsmax( SZ_Data ), "%s %d", SZ_Password_T[ Index ], g_ammopacks[Index] )
get_user_name( Index, SZ_Name, 31 )
fvault_set_data( Vault, SZ_Name, SZ_Data )
return PLUGIN_CONTINUE;
}
Load( Index )
{
static SZ_Data[ 512 ], SZ_Name[ 32 ], SETINFO_Password[ 191 ], VAULT_Password[ 191 ], APs[ 11 ]
get_user_name( Index, SZ_Name, 31 )
get_user_info( Index, "_pass", SETINFO_Password, 190 ) // Seteamos en SETINFO_Password lo que tiene como Setinfo con el prefijo _pass
if( !fvault_get_data( Vault, SZ_Name, SZ_Data, charsmax( SZ_Data ) ) ) // Detectamos si NO existe su Nombre y Data en el Vault. En ese caso, yo puse que lo mande al Menu de Teams ( Donde le pusimos que se Registre ).
{
set_task( 0.1, "clcmd_changeteam", Index ) // Si le cambiaron el nombre a esta función, también deben cambiarselo acá. Si no les aparece el Menú de Teams cuando hacen esto, usen set_task de 0.2
return 0;
}
Registrado[ Index ] = 1
// El Nombre y la Password JAMÁS la cargen.
parse( SZ_Data, VAULT_Password, 190, APs, 10 ) // La función PARSE, separa los Datos 1 por 1. Si guardamos la Password primero, y los AmmoPacks despues, entonces este Parse está bien, obviamente tiene que seguir el Orden en el que se guardó.
if( equal( SETINFO_Password, VAULT_Password ) ) // Si la Contraseña del Jugador coincide con la Registrada de su Nick, cargamos sus Datos.
{
// Fixeamos un Error para que no reemplaze la Password Registrada por alguna que puede llegar a cambiar el adentro del Server.
SZ_Password_T[ Index ] = SETINFO_Password
// Cargamos los AmmoPacks. ( Numero )
g_ammopacks[Index] = str_to_num( APs )
set_task( 0.1, "clcmd_changeteam", Index ) // Si le cambiaron el nombre a esta función, también deben cambiarselo acá. Si no les aparece el Menú de Teams cuando hacen esto, usen set_task de 0.2
// Ejemplo de: Cargar un Float
// Variable_De_Float[Index] = str_to_float( Float )
return 2;
}
else // Si la Contraseña del Jugador NO coincide con la Registrada de su Nick, podemos Kickearlo, mandarlo a Spect, un menú, etc..
{
BadPassword[ Index ] = 1
// Yo le voy a poner que si tiene mal la Password lo mande a Spect y el Menú de Ingresar la Password.
set_task( 0.1, "clcmd_changeteam", Index ) // Si le cambiaron el nombre a esta función, también deben cambiarselo acá. Si no les aparece el Menú de Teams cuando hacen esto, usen set_task de 0.2.
//....
}
return 1;
}
public MenuBadPassword( Index, Menu, Item )
{
if( Item == MENU_EXIT )
{
menu_destroy( Menu )
return PLUGIN_HANDLED;
}
static Access, Data[6], iName[64], CallBack
menu_item_getinfo( Menu, Item, Access, Data, 5, iName, 63, CallBack )
switch( str_to_num( Data ) )
{
case 1:
{
if( !Registrado[ Index ] )
CMDRegistrarse( Index )
else
client_cmd( Index, "messagemode IntroducirContrasenia" )
}
}
menu_destroy( Menu )
return PLUGIN_HANDLED;
}
Datos Extras:
- Una vez que te Registraste, no te podes volver a Registrar CON el mismo NICK.
- Si tenes la Password incorrecta, los manda a un Menú de Logeo.
- Cuando se te guardan los Datos por primera vez es algo asi: "Kiske" "PendejoAlcahuete 800"
- Cuando me desconecte, que se guardan los Datos, se me guardaron así: "Kiske" "PendejoAlcahuete 4600", obviamente porque gane AmmoPacks.
- No testee nada asi que si encuentran algún POSIBLE Bug, me lo hacen saber.
- Algo que también quiero aclarar, es que para prohibir el CAMBIO de NICK, se fijen la primera parte SIN ZombiePlague, y fijense la Forward: register_forward( FM_ClientUserInfoChanged, "FWClientUserInfoChanged" ) que les va a servir para que no causen Bugs con los Nicks.
Bugs Encontrados:
- Cuando te aparece el Menu de Registro / Login, si entras a otro Menú, se bugea y te deja entrar de CT y / o TT.
- SOLUCIÓN: La única que logré hacer yo y efectiva, es bloqueando que entre a otros Menúes si Registrado[ Index ] era igual a 0 y / o si BadPassword[ Index ] era igual a 1.
¿ Como bloquear un Menú para que no pueda acceder a el si esas Variables están mal. ?Todos los Menúes accesibles por SAY y / o CONSOLA, van a hacer que se bugeen, la solución es poner donde se llama la Función que se crea el MENÚ, el siguiente código:
PHP Code:
if( !Registrado[ Index ] || BadPassword[ Index] )
return;
Este pequeño cógido, deben ponerlo en todos los Menúes que se pueda acceder a traves de SAY y / o CONSOLA.
__________________
Last edited by Kiske; 03-02-2014 at 09:02.
|
|
Linear Mode
