[CrazY.]

Hello, I'm trying to create [func|info]_bomb_target on all maps (except maps "de_" because it already has). I did some tests and the entity is being created, but I'm not able to plant the C4.

public plugin_precache()
{
if (!find_ent_by_class(-1, "[func|info]_bomb_target")
create_entity("[func|info]_bomb_target");
}

[HamletEagle]

You need origin and size and other stuff.

[CrazY.]

I don't need origin exactly because I will use fake_touch.

What do you are meaning with "other stuff"?

[HamletEagle]

What do you want to? Plant c4 everywhere on any map?

[CrazY.]

It's the self destruct device of the predators

[HamletEagle]

Originally Posted by HamletEagle What do you want to? Plant c4 everywhere on any map?

You answered nothing.

[CrazY.]

Yes, I need to plant the C4 anywhere on any map, no restrictions.

[CrazY.]

I tried that, but I still couldn't use that entity with the fake_touch.

    if (!find_ent_by_class(-1, CLASS_FUNC_BOMB_TARGET))
    {
        new entity = create_entity(CLASS_FUNC_BOMB_TARGET);
        entity_set_int(entity, EV_INT_solid, SOLID_TRIGGER);

        new Float:origin[3]; // 0.0 0.0 0.0
        entity_set_origin(entity, origin);

        new Float:mins[3] = { -1729.0, 2495.0, -1.0 };
        new Float:maxs[3] = { -1343.0, 2881.0, 97.0 };
        entity_set_size(entity, mins, maxs);
    }

[HamletEagle]

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

const m_flState        = 235
const m_fClientMapZone = 234
const XoPlayer         = 5

const SIGNAL_BOMB            = 1<<1
const CS_MAPZONE_BOMBTARGET  = (1<<1) 

public plugin_init()
{
    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_c4", "CC4_PrimaryAttackPre", false)
    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_c4", "CC4_PrimaryAttackPost", true)
}

public CC4_PrimaryAttackPre(const C4Entity)
{
    if(pev_valid(C4Entity))
    {
        new id = pev(C4Entity, pev_owner)
        if(!(get_pdata_int(id, m_fClientMapZone, XoPlayer) & CS_MAPZONE_BOMBTARGET))
        {
            set_pdata_int(id, m_flState, SIGNAL_BOMB, XoPlayer)
            client_print(id, print_chat, "PLANT")
        }
    }
}

public CC4_PrimaryAttackPost(const C4Entity)
{
    if(pev_valid(C4Entity))
    {
        new id = pev(C4Entity, pev_owner)
        new SignalState = get_pdata_int(id, m_flState, XoPlayer)
        
        if(!(get_pdata_int(id, m_fClientMapZone, XoPlayer) & CS_MAPZONE_BOMBTARGET))
        {
            SignalState &= ~SIGNAL_BOMB
            set_pdata_int(id, m_flState, SignalState, XoPlayer)
        }
    }
} 


Use this, works in all maps. You just have to give a weapon_c4 to the player in non bomb maps.
I did not want to rely on func_bomb_target entity because on some maps it's not present and as you can see here if there is no func_bomb_target(if (!CSGameRules()->m_bMapHasBuyZone)) game will check 200 units around spawpoint and consider that a bomb zone.

[CrazY.]

Thanks Hamlet, it's working perfectly!