[wrecked_]

Originally Posted by drekes ow, you mean learning how they work?

Yeah, just learn the way the data is retrieved from the actual command and what you can do with it.

Originally Posted by drekes btw: can i add you guys in the credits in case this ever gets realised?

Sure.

[drekes]

Originally Posted by wrecked_ Look at the beginning tutorials on the website (1 has a concmd, I think it's the amx_hp one),

I searched every page of the scripting help section but can't find it. although i'm sure i've saw it when i started scripting

[Bugsy]

This will store all steamids entered with amx_addid command in an ini file (playeridfile.ini) found in your amxmodx\data directory. The plugin reads from this file when it loads so you can enter them manually with notepad and then do a mapchange\restart to make it take effect. The plugin does not check the validity of a steamid so make sure it is entered correctly. When a user connects, a chat message will print to all saying whether or not the user was found on the steamid list (just for demonstration).

Console command: amx_addid "STEAM_0:0:12345"
Admin access needed for amx_addid command is AMX_BAN

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <celltrie>

new Trie:g_tSteamIDs;
new g_szFile[ 64 ];

public plugin_init() 
{
    new szData[ 35 ];
    
    g_tSteamIDs = TrieCreate();
    
    copy( g_szFile[ get_localinfo( "amxx_datadir" , g_szFile , charsmax( g_szFile ) ) ] , charsmax( g_szFile ) , "/playeridfile.ini" );
    
    new f = fopen( g_szFile , "rt" );
    
    while( !feof( f ) )
    {
        fgets( f , szData , charsmax( szData ) );
     
        trim( szData );
        
        if( !szData[0] || szData[0] == ';' || szData[0] == '/' && szData[1] == '/' ) 
            continue;
            
        TrieSetCell( g_tSteamIDs , szData , 1 );
    }
    
    fclose( f );
    
    register_concmd( "amx_addid" , "AddID" , ADMIN_BAN , "<SteamID> - Add SteamID to list" );
}

public client_putinserver( id )
{
    new szName[ 33 ] , szSteamID[ 35 ];
    
    get_user_name( id , szName , charsmax( szName ) );
    get_user_authid( id , szSteamID , charsmax( szSteamID ) );

    if ( TrieKeyExists( g_tSteamIDs , szSteamID ) )
    {
        client_print( 0 , print_chat , "* %s has connected and was found on the list!" , szName );
    }
    else
    {
        client_print( 0 , print_chat , "* %s has connected and was NOT found on the list!" , szName );
    }
}

public AddID( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 2 ) )
        return PLUGIN_HANDLED;
        
    new szSteamID[ 35 ];

    if ( read_argv( 1 , szSteamID , charsmax( szSteamID ) ) )
    {
        if ( !TrieKeyExists( g_tSteamIDs , szSteamID ) )
        {
            TrieSetCell( g_tSteamIDs , szSteamID , 1 );
            write_file( g_szFile , szSteamID );
            console_print( id , "* Added SteamID ^"%s^" to list." , szSteamID );
        }
        else
        {
            console_print( id , "* SteamID ^"%s^" already exists in list." , szSteamID );
        }
    }
    
    return PLUGIN_HANDLED;
} 


[fysiks]

Originally Posted by Bugsy Console command: amx_addid "STEAM_0:0:12345"

Must use quotes around a SteamID.

Originally Posted by drekes I searched every page of the scripting help section but can't find it. although i'm sure i've saw it when i started scripting

He is refering to the wiki here.

[drekes]

Thanks bugsy

@ fysiks
Do i have to add the quotes when i add him through console or do i have to change the script?

@wrecked_
I found the amx_hp tutorial thanks to fysiks

[drekes]

Can i make bugsy's addid that you use playername instead of steamid?

i tryed it , will it work or is it wrong?

PHP Code:

{
    if(!cmd_access(id, level, cid, 2))
        return PLUGIN_HANDLED
        
    new Arg1[24]
    new szSteamID[35];
    
    read_argv(1, Arg1, 23)

    new player = cmd_target(id, Arg1, 1)
    
    if (!player)
    {
        console_print(id, "player %s could not be found!", Arg1)
        return PLUGIN_HANDLED
    } 
            
    else 
    {
        get_user_authid(player, szSteamID[34],  charsmax(szSteamID))
    }
    
    // Check steamid list.
    if (!TrieKeyExists(g_tSteamIDs, szSteamID))
    {
        TrieSetCell(g_tSteamIDs, szSteamID, 1);
        write_file(g_szFile, szSteamID);
        console_print(id, "* Added SteamID ^"%s^" to list.", szSteamID);
    }
        
    else
    {
        console_print(id, "* SteamID ^"%s^" already exists in list.", szSteamID);
    }
    return PLUGIN_HANDLED;
} 


[fysiks]

When you put a SteamID in the file you do not use quotes. When you put a SteamID in with a command in the console you must use quotes.

As for your code, the only thing that I see that would make it not work is that you index the szSteamID; remove the index (and brackets) and I think it might work.

Tip: cmd_target already tells you if there target could not be found so there is no reason to do it again as you have.

Here is my version if you are interested:

PHP Code:

public AddID( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 2 ) )
        return PLUGIN_HANDLED;

    new szArg[35];
    read_argv( 1 , szArg , charsmax( szArg ) );
    new iPlayer = cmd_target(id, szArg, CMDTARGET_ALLOW_SELF | CMDTARGET_NO_BOTS);

    if ( iPlayer )
    {
        new szSteamID[ 35 ];
        get_user_authid(iPlayer, szSteamID, charsmax(szSteamID));
        if ( !TrieKeyExists( g_tSteamIDs , szSteamID ) )
        {
            TrieSetCell( g_tSteamIDs , szSteamID , 1 );
            write_file( g_szFile , szSteamID );
            console_print( id , "* Added SteamID ^"%s^" to list." , szSteamID );
        }
        else
        {
            console_print( id , "* SteamID ^"%s^" already exists in list." , szSteamID );
        }
    }

    return PLUGIN_HANDLED;
} 


[drekes]

tnx fysiks, thanks for your notepad ++ highlighting to, it rules.

And can i read the file again once it is updated, like when i add an id? if i do it like this

PHP Code:

public plugin_init()
{
    readfile()
    //stuff
}

public readfile()
{
        new szData[35];
   
    g_tSteamIDs = TrieCreate();
    
    copy( g_szFile[ get_localinfo("amxx_datadir", g_szFile, charsmax(g_szFile))], charsmax(g_szFile), "/ct-banlist.ini");
    
    new f = fopen(g_szFile, "rt");
    
    while(!feof(f))
    {
        fgets( f , szData , charsmax( szData ) );
     
        trim( szData );
        
        if(!szData[0] || szData[0] == ';' || szData[0] == '/' && szData[1] == '/') 
        continue;
            
        TrieSetCell(g_tSteamIDs, szData, 1);
    }
    
    fclose(f);
} 


[Bugsy]

Are there any other plugins reading from writing to the file? If not then there is no reason to reload the file during runtime.

[fysiks]

Originally Posted by Bugsy Are there any other plugins reading from writing to the file? If not then there is no reason to reload the file during runtime.